ANSYS 分析钢结构狗骨节点

wenrouhfut

ANSYS 分析钢结构狗骨节点， 希望对大家能有点帮助
!!单位N,mm
!!建立参数
h_beam=400               !梁高
w_beam=200               !梁宽
tw_beam=8                !梁腹板厚度
tf_beam=12               !梁翼缘

h_colu=450               !柱高
w_colu=300               !柱宽
tw_colu=12               !柱腹板厚度
tf_colu=20              !柱翼缘厚度

l_beam=1000              !梁长
l_colu=1000              !柱长
t_stiff=tf_beam          !加劲肋厚度

exx=2.05e05              !钢材弹性模量


a_bone=175                 !狗骨距离柱翼缘
b_bone=250                 !狗骨长
c_bone=40                  !狗骨深
r_bone=(c_bone*c_bone*4+b_bone*b_bone)/(8*c_bone)                !孔半径

!!!建立梁柱几何模型
/prep7

!!!建立柱模型
block,-h_colu*0.5,-(h_colu*0.5-tf_colu),-l_colu*0.5,l_colu*0.5,-w_colu*0.5,w_colu*0.5
block,-(h_colu*0.5-tf_colu),h_colu*0.5-tf_colu,-l_colu*0.5,l_colu*0.5,-tw_colu*0.5,tw_colu*0.5
block,(h_colu*0.5-tf_colu),h_colu*0.5,-l_colu*0.5,l_colu*0.5,-w_colu*0.5,w_colu*0.5

!!!建立梁模型
block,h_colu*0.5,h_colu*0.5+l_beam,-h_beam*0.5,-(h_beam*0.5-tf_beam),-w_beam*0.5,w_beam*0.5
block,h_colu*0.5,h_colu*0.5+l_beam,-(h_beam*0.5-tf_beam),(h_beam*0.5-tf_beam),-tw_beam*0.5,tw_beam*0.5
block,h_colu*0.5,h_colu*0.5+l_beam,h_beam*0.5,(h_beam*0.5-tf_beam),-w_beam*0.5,w_beam*0.5

!!!建立柱加劲肋
block,-(h_colu*0.5-tf_colu),h_colu*0.5-tf_colu,h_beam*0.5-tf_beam,h_beam*0.5,tw_colu*0.5,w_colu*0.5
block,-(h_colu*0.5-tf_colu),h_colu*0.5-tf_colu,h_beam*0.5-tf_beam,h_beam*0.5,-tw_colu*0.5,-w_colu*0.5
block,-(h_colu*0.5-tf_colu),h_colu*0.5-tf_colu,-(h_beam*0.5-tf_beam),-h_beam*0.5,tw_colu*0.5,w_colu*0.5
block,-(h_colu*0.5-tf_colu),h_colu*0.5-tf_colu,-(h_beam*0.5-tf_beam),-h_beam*0.5,-tw_colu*0.5,-w_colu*0.5

!!!建立梁端加劲肋
block,h_colu*0.5+l_beam-tf_beam,h_colu*0.5+l_beam,-(h_beam*0.5-tf_beam),h_beam*0.5-tf_beam,tw_beam*0.5,w_beam*0.5
block,h_colu*0.5+l_beam-tf_beam,h_colu*0.5+l_beam,-(h_beam*0.5-tf_beam),h_beam*0.5-tf_beam,-w_beam*0.5,-tw_beam*0.5

vglue,all


!!!建立 dog-bone
wpoffs,h_colu*0.5+a_bone+b_bone*0.5,0,w_beam*0.5-c_bone+r_bone
wprota,0,90,0
cylind,0,r_bone,-h_beam,h_beam,0,360
vsbv,all,1
wpcsys,-1,0
wpoffs,h_colu*0.5+a_bone+b_bone*0.5,0,-(w_beam*0.5-c_bone+r_bone)
wprota,0,90,0
cylind,0,r_bone,-h_beam,h_beam,0,360
vsbv,all,1


!切割
wpcsys,-1,0
wpoffs,h_colu*0.5+a_bone*0.5,0,0
wprota,0,0,90
vsbw,all
wpoffs,0,0,b_bone+a_bone
vsbw,all

wpcsys,-1,0
wpoffs,h_colu*0.5+l_beam-tf_beam,0,0
wprota,0,0,90
vsbw,all
wpcsys,-1,0


wpoffs,0,h_beam*0.5+100
wprota,0,90,0
vsbw,all
wpoffs,0,0,h_beam+200
vsbw,all
wpcsys,-1,0

wpoffs,0,0,-tw_beam*0.5
vsbw,all
wpoffs,0,0,tw_beam
vsbw,all

wpcsys,-1,0
wpoffs,0,0,w_beam*0.5
vsbw,all
wpoffs,0,0,-w_beam*0.5*2
vsbw,all

wpcsys,-1,0
wpoffs,0,-h_beam*0.5
wprota,0,90,0
vsbw,all
wpoffs,0,0,-tf_beam
vsbw,all
wpoffs,0,0,-(h_beam-tf_beam*2)
vsbw,all
wpoffs,0,0,-tf_beam
vsbw,all
wpcsys,-1,0

wpcsys,-1,0
wpoffs,h_colu*0.5+a_bone,0,0
wprota,0,0,90
vsbw,all
wpoffs,0,0,b_bone*0.5
vsbw,all
wpoffs,0,0,b_bone*0.5
vsbw,all

!*******************************定义材料和单元属性***********************
!定义材料1，Q235钢材用于梁、柱
et,1,solid45
mp,ex,1,exx
mp,nuxy,1,0.3
tb,mkin,1
tbtemp,,strain
tbdata,,0.001,0.011,0.021
tbtemp,,
tbdata,,0.001*exx,235,400
allsel,all
vatt,1,,1

vsel,s,loc,x,-h_colu*0.5,h_colu*0.5
vsel,u,loc,y,-h_beam*0.5,h_beam*0.5
aslv
lsla
lsel,r,length,,(l_colu-h_beam-200)*0.5
lesize,all,,,5,,,,,1
allsel,all
lsel,r,length,,h_colu-tf_colu*2
lesize,all,,,10,,,,,1


allsel,all
lsel,r,radius,,r_bone
lesize,all,,,20,,,,,1

allsel,all
lsel,r,length,,l_beam-b_bone-a_bone*1.5-tf_beam
lesize,all,,,8,,,,,1


allsel,all
lsel,r,length,,tw_beam
lesize,all,,,1,,,,,1

allsel,all
lsel,r,length,,tf_beam
lesize,all,,,1,,,,,1

allsel,all
lsel,r,length,,tw_colu
lesize,all,,,1,,,,,1

allsel,all
lsel,r,length,,tf_colu
lesize,all,,,1,,,,,1

allsel,all
esize,20
vsweep,all
!!!!!!!!!!!!!!!!!!求解设置!!!!!!!!!!!!!!
/solu                              
lsclear,all                        
antype,0
nlgeom,1                             
allsel,all
auto,on

cnvtol,f,,0.08,2,,
neqit,50
lnsrch,auto                          
pred,1                                                   
!!!!!!!!!!!!!!!!!!设置边界条件!!!!!!!!!!!!!!!
allsel,all
nsel,s,loc,y,-l_colu*0.5
d,all,all,
allsel,all
nsel,s,loc,y,l_colu*0.5
d,all,all,
allsel,all
!******************************************************************
allsel,all
nsel,s,loc,x,h_colu*0.5+l_beam
nsel,r,loc,y,h_beam*0.5
d,all,uy,-100
kbc,0
nsubst,100,0,0
outre,basic,1
allsel,all
solve

inkey

楼主建模功夫了得,学习了!
让我也运算一下看看

wishangtian

一个小建议：最好附上图。

运行了一下，现在附上你模型的图

lh_54482

呵呵，谢谢楼主，正在找这方面的例子，受益匪浅，谢了。

szxueliang

呵呵，谢谢楼主，正在找这方面的例子，受益匪浅，谢了

cx900925cxCX

谢谢楼主！！！好东西

星矢2007

正在做类似的，参考一下，谢谢！

星矢2007

无螺栓啊