【寻高手解答】MFS二维和三维流固耦合中验证固体反力的问题?

jslx2000

在ANSYS11.0 MFS的二维和三维流固耦合计算中发现：

（1）二维流固耦合固体的约束反力FX与流体的速度VX方向相反；
上侧外表面反力FX=-1.3989N，FY=-4.8438N
下侧外表面反力FX=-1.3989N，FY=4.8438N

（2）而三维流固耦合固体的约束反力FX与流体的速度VX方向一致。
上侧外表面反力FX=1.3989E-2N，FY=-4.8437E-2N
下侧外表面反力FX=1.3989E-2N，FY=4.8437E-2N

实际情况是:不管是二维还是三维流固耦合问题，由流体剪应力引起的固体约束反力FX与流体的速度VX方向相反。

我已经求助了ANSYS公司的工程师，一直还没有给我答复。这里有哪位高手能帮我解决这个问题？

以下是这两道例题的命令流。

[ 本帖最后由 jslx2000 于 2007-5-16 11:13 编辑 ]

jslx2000

!*****************************************************************************************
!问题描述：长为0.1m、宽度为0.03m的流体，在压差为100Pa的压力作用下流体作一维层流流动；
!          在流体两侧有长为0.1m、宽度为0.005m的固体，固体外表面全固体。单位采用国际单位制。
!          求固体的约束反力？
!计算结果：
! （1）上侧外表面反力FX=-1.3989N，FY=-4.8438N
! （2）下侧外表面反力FX=-1.3989N，FY=4.8438N
!*****************************************************************************************
L=100E-3                        ! 长度,m
d1=30E-3                        ! 流体宽度,m
d2=40E-3                        ! 固体上下侧外表面之间的距离,m
modx=2.1E11                   ! 固体弹性模量
nust=0.3                          ! 固体伯松比
denw=1.0E3                      ! 流体的密度
visw=1                              ! 流体的黏度
deltp=100                          ! 压差,Pa
!-------------------------------------------------------
/FILNAME,MFS_2D,1
/PREP7
ET,1,FLUID141                     ! 流体单元
ET,2,PLANE42                      ! 固体单元

/VIEW,1,1,1,1
RECTNG,0,L,-d1/2,d1/2          ! 流体
RECTNG,0,L,-d2/2,-d1/2         ! 下侧固体
RECTNG,0,L,d1/2,d2/2           ! 上侧固体

ASEL,S,LOC,Y,-d1/2,d1/2        ! 流体
AATT,1,,1
TYPE,1
ASEL,INVERT                         ! 固体
AATT,2,2,2
TYPE,2

LSEL,S,LENGTH,,L
LESIZE,ALL, , ,10, , , , ,1
LSEL,S,LENGTH,,d1
LESIZE,ALL, , ,12,-4, , , ,1
LSEL,S,LENGTH,,(d2-d1)/2
LESIZE,ALL, , ,1, , , , ,1
ALLSEL,ALL
AMESH,ALL
!-----------------------------------固体边界
ASEL,S,TYPE,,2
ALLSEL,BELOW,AREA           ! 界面1
LSEL,R,LOC,Y,-d1/2
NSLL,S,1
SF,ALL,FSIN,1
ALLSEL,BELOW,AREA           ! 界面2
LSEL,R,LOC,Y,d1/2
NSLL,S,1
SF,ALL,FSIN,2
ALLSEL,BELOW,AREA           ! 固体外壁固定
LSEL,R,LOC,Y,-d2/2
LSEL,A,LOC,Y,d2/2
NSLL,S,1
!NSEL,R,LOC,X,L
D,ALL,UX
D,ALL,UY
!----------------------------------液体边界
LSEL,S,LOC,X,0
LSEL,R,LOC,Y,0
NSLL,S,1
D,ALL,VY                               ! 进口边界
d,ALL,pres,deltp,1
LSEL,S,LOC,X,L
LSEL,R,LOC,Y,0
NSLL,S,1
d,ALL,pres,0,1                        ! 出口边界
ASEL,S,TYPE,,1                       ! 界面1
ALLSEL,BELOW,AREA
LSEL,R,LOC,Y,-d1/2
NSLL,S,1
SF,ALL,FSIN,1
D,ALL,VX
D,ALL,VY
ALLSEL,BELOW,AREA                ! 界面2
LSEL,R,LOC,Y,d1/2
NSLL,S,1
SF,ALL,FSIN,2
D,ALL,VX
D,ALL,VY
!---------------------------------------------------------------------------------
ALLSEL,ALL
flda,solu,flow,1
flda,solu,turb,0
flda,advm,mome,supg
flda,advm,turb,supg
flda,iter,exec,100
flda,outp,sumf,10
FLDATA5,OUTP,TAUW,1
FLDATA34,MIR,MOME,0.1

flda,prot,dens,constant
flda,prot,visc,constant
flda,nomi,dens,denw
flda,nomi,visc,visw
flda,conv,pres,1.E-9

MP,EX,2,modx
MP,NUXY,2,nust
!=============================================================
/solu
mfan,on                   ! Activate MFS analysis与MFAN,ON,MFSC等同
MFEL,1,1                 ! Field #1: fluid依次为流体物理场编号，单元类型编号
MFFN,1,fluid1           ! Field #1 filename流体物理场文件名fluid1
mfel,2,2                  ! Field #2: Structure依次为结构物理场编号，单元类型编号
mffn,2,struc2           ! Field #2 filename结构物理场文件名struc2
mfor,1,2                  ! Field order (fluid, structure)物理场求解顺序，可以定义20个物理场
MFSU,1,1,FORC,2     ! surface load transfer (fluid to structure) 界面标签1，流体，力，结构
MFSU,1,2,DISP,1      ! surface load transfer (structure to fluid) 界面标签1，结构，位移，流体
MFSU,2,1,FORC,2     ! surface load transfer (fluid to structure) 界面标签2，流体，力，结构
MFSU,2,2,DISP,1      ! surface load transfer (structure to fluid) 界面标签2，结构，位移，流体
mfti,1                      ! Time at end of analysis设置分析终止时间
mfdt,1                     ! One field loop within a stagger载荷步长
mfit,5                      ! Max 20 stagger loops迭代次数
mfre,all,0.5             ! Field transfer relaxation parameter载荷传递的松弛因子为0.5
antyp,stat               ! 设置流体分析类型：静态分析
mfcm,1                  ! Write fluid analysis options写流体分析选项到文件fluid1.cmd
antype,static           ! 设置结构分析类型：静态分析     
mfcm,2                  ! Write structure analysis options写结构分析选项到文件field2.cmd
solve
save
finish
!=============================================================
FINISH
/POST1
INRES,ALL
FILE,'fluid1','rfl','.'          ! 调入流体结果文件
SET,LAST
ALLSEL,ALL
/EFACET,1
PLNSOL, V,X, 0              ! 最大速度为0.112499m/s
/EFACET,1   
PLNSOL, TAUW,, 0         ! 壁面剪应力为14.44Pa
!---------------------------------------------------------
FINISH
/POST1
INRES,ALL
FILE,'struc2','rst','.'               ! 调入固体结果文件
SET,LAST
/VSCALE,1,4,0

ASEL,S,LOC,Y,d1/2,d2/2
ALLSEL,BELOW,AREA            ! 上侧外表面反力FX=-1.3989N
PRRSOL,                              ! 上侧外表面反力FY=-4.8438N

ASEL,S,LOC,Y,-d2/2,-d1/2
ALLSEL,BELOW,AREA            ! 下侧外表面反力FX=-1.3989EN
PRRSOL,                              ! 下侧外表面反力FY=4.8438EN

[ 本帖最后由 jslx2000 于 2007-5-16 10:23 编辑 ]

jslx2000

!*****************************************************************************************
!问题描述：长为0.1m、宽度为0.03m、厚度为0.01m的流体，在压差为100Pa的压力作用下流体作一维层流流动；
!        在流体两侧有长为0.1m、宽度为0.005m、厚度为0.01m的固体，固体外表面全固体。单位采用国际单位制。
!         求固体的约束反力？

!计算结果：
! （1）上侧外表面反力FX=1.3989E-2N，FY=-4.8437E-2N
! （2）下侧外表面反力FX=1.3989E-2N，FY=4.8437E-2N
!*****************************************************************************************

L=100E-3            ! 长度,m
d1=30E-3            ! 流体宽度,m
d2=40E-3            ! 固体上下侧外表面之间的距离,m
B=10E-3             ! 流体和固体的厚度,m

modx=2.1E11      ! 固体弹性模量
nust=0.3             ! 固体伯松比

denw=1.0E3       ! 流体的密度
visw=1               ! 流体的黏度
deltp=100           ! 压差,Pa
!-------------------------------------------------------
/FILNAME,MFS_3D,1
/PREP7
ET,1,FLUID142
ET,2,SOLID45

/VIEW,1,1,1,1
BLOCK,0,L,-d1/2,d1/2,0,B        ! 流体
BLOCK,0,L,-d2/2,-d1/2,0,B       ! 下侧固体
BLOCK,0,L,d1/2,d2/2,0,B         ! 上侧固体

LSEL,S,LENGTH,,L
LESIZE,ALL, , ,10, , , , ,1

LSEL,S,LENGTH,,d1
LESIZE,ALL, , ,12,-4, , , ,1

LSEL,S,LENGTH,,(d2-d1)/2
LESIZE,ALL, , ,1, , , , ,1

LSEL,S,LENGTH,,B
LESIZE,ALL, , ,1, , , , ,1

VSEL,S,LOC,Y,-d1/2,d1/2
TYPE,1
MSHAPE,0,3D
VMESH,ALL

VSEL,INVE
TYPE,2
VMESH,ALL
!-----------------------------------固体边界
VSEL,S,TYPE,,2
ALLSEL,BELOW,VOLU           ! 界面1
ASEL,R,LOC,Y,-d1/2
NSLA,S,1
SF,ALL,FSIN,1

ALLSEL,BELOW,VOLU           ! 界面2
ASEL,R,LOC,Y,d1/2
NSLA,S,1
SF,ALL,FSIN,2

ALLSEL,BELOW,VOLU           ! 固体外壁固定
ASEL,R,LOC,Y,-d2/2
ASEL,A,LOC,Y,d2/2
NSLA,S,1
D,ALL,UX
D,ALL,UY
D,ALL,UZ
!----------------------------------液体边界
VSEL,S,TYPE,,1
ALLSEL,BELOW,VOLU
ASEL,R,LOC,X,0
ASEL,R,LOC,Y,0
NSLA,S,1
D,ALL,VY                          ! 进口边界
D,ALL,VZ
d,ALL,pres,deltp,1

ALLSEL,BELOW,VOLU
ASEL,R,LOC,X,L
ASEL,R,LOC,Y,0
NSLA,S,1
d,ALL,pres,0,1                   ! 出口边界

ALLSEL,BELOW,VOLU         ! 界面1
ASEL,R,LOC,Y,-d1/2
NSLA,S,1
SF,ALL,FSIN,1
D,ALL,VX
D,ALL,VY
D,ALL,VZ

ALLSEL,BELOW,VOLU         ! 界面2
ASEL,R,LOC,Y,d1/2
NSLA,S,1
SF,ALL,FSIN,2
D,ALL,VX
D,ALL,VY
D,ALL,VZ
!---------------------------------------------------------------------------------
ALLSEL,ALL

flda,solu,flow,1
flda,solu,turb,0
flda,advm,mome,supg
flda,advm,turb,supg
flda,iter,exec,100
flda,outp,sumf,10

FLDATA5,OUTP,TAUW,1
FLDATA34,MIR,MOME,0.1

flda,prot,dens,constant
flda,prot,visc,constant
flda,nomi,dens,denw
flda,nomi,visc,visw
flda,conv,pres,1.E-9

MP,EX,1,modx
MP,NUXY,1,nust

!========================================================
/solu
mfan,on                 ! Activate MFS analysis与MFAN,ON,MFSC等同

MFEL,1,1                ! Field #1: fluid依次为流体物理场编号，单元类型编号
MFFN,1,fluid1           ! Field #1 filename流体物理场文件名fluid1
mfel,2,2                ! Field #2: Structure依次为结构物理场编号，单元类型编号
mffn,2,struc2           ! Field #2 filename结构物理场文件名struc2
mfor,1,2                ! Field order (fluid, structure)物理场求解顺序，可以定义20个物理场

MFSU,1,1,FORC,2         ! surface load transfer (fluid to structure) 界面标签1，流体，力，结构
MFSU,1,2,DISP,1         ! surface load transfer (structure to fluid) 界面标签1，结构，位移，流体

MFSU,2,1,FORC,2         ! surface load transfer (fluid to structure) 界面标签2，流体，力，结构
MFSU,2,2,DISP,1         ! surface load transfer (structure to fluid) 界面标签2，结构，位移，流体

mfti,1                  ! Time at end of analysis设置分析终止时间
mfdt,1                  ! One field loop within a stagger载荷步长
mfit,5                 ! Max 20 stagger loops迭代次数

mfre,all,0.5            ! Field transfer relaxation parameter载荷传递的松弛因子为0.5

antyp,stat              ! 设置流体分析类型：静态分析
mfcm,1                  ! Write fluid analysis options写流体分析选项到文件fluid1.cmd

antype,static           ! 设置结构分析类型：静态分析     
mfcm,2                  ! Write structure analysis options写结构分析选项到文件field2.cmd

solve
save
finish
!========================================================
FINISH
/POST1
INRES,ALL
FILE,'fluid1','rfl','.'          ! 调入流体结果文件
SET,LAST

ALLSEL,ALL
/EFACET,1
PLNSOL, V,X, 0               ! 最大速度为0.112499m/s

/EFACET,1   
PLNSOL, TAUW,, 0            ! 壁面剪应力为14.44Pa
!---------------------------------------------------------
FINISH
/POST1
INRES,ALL
FILE,'struc2','rst','.'              ! 调入固体结果文件
SET,LAST
/VSCALE,1,4,0

VSEL,S,LOC,Y,d1/2,d2/2
ALLSEL,BELOW,VOLU            ! 上侧外表面反力FX=1.3989E-2N
PRRSOL,                             ! 上侧外表面反力FY=-4.8437E-2N

VSEL,S,LOC,Y,-d2/2,-d1/2
ALLSEL,BELOW,VOLU            ! 下侧外表面反力FX=1.3989E-2N
PRRSOL,                              ! 下侧外表面反力FY=4.8437E-2N

[ 本帖最后由 jslx2000 于 2007-5-16 10:57 编辑 ]