超弹性分析------转载

xinhu123

超弹性分析
4.3.1  超弹理论
4.3.1.1  超弹的定义
一般工程材料（例如金属）的应力状态由一条弹塑性响应曲线来描述，而超弹性材料存在一个弹性势能函数，该函数是一个应变或变形张量的标量函数，而该标量函数对应变分量的导数就是相应的应力分量。

上式中：[S]＝第二皮奥拉－克希霍夫应力张量
    W＝单位体积的应变能函数
      [E]＝拉格朗日应变张量
拉格朗日应变可以由下式表达：[E]＝1/2（[C]-I）
其中：[I]是单位矩阵，[C]是有柯西－格林应变张量

其中[F]是变形梯度张量，其表达式为：

x ：变形后的节点位置矢量
X ：初始的节点位置矢量
如果使用主拉伸方向作为变形梯度张量和柯西－格林变形张量的方向，则有：

其中：  J=初始位置与最后位置的体积比
材料在第i个方向的拉伸率
在ANSYS程序中，我们假定超弹材料是各向同性的，在每个方向都有完全相同的材料特性，在这种情况下，我们既可以根据应变不变量写出应变能密度函数，也可以根据主拉伸率写出应变能密度函数。
应变不变量是一种与坐标系无关的应变表示法。使用它们就意味着材料被假定是各向同性的。Mooney－Rivlin和Blatz－Ko应变能密度函数都可以用应变不变量表示，应变不变量可以柯西－格林应变张量和主拉伸率表示出来：



一个根据应量不变量写出来的应变能密度函数如下：

为材料常数，上式是两个常数的Mooney－Rivlin应变能密度函数。
超弹材料可以承受十分大的弹性变形，百分之几百的应变是很普遍的，既然是纯弹性应变，因此超弹性材料的变形是保守行为，与加载路径无关。
4.3.1.2  不可压缩缩性
大多数超弹材料，特别是橡胶和橡胶类材料，都是几乎不可压缩的，泊松比接近于0.5，不可压缩材料在静水压力下不产生变形，几乎不可压缩材料的泊松比一般在0.48至0.5之间（不包含0.5），对这些材料，在单元公式中必须考虑不可压缩条件。在ANSYS程序中，不可压缩超弹单元修改了应变能密度函数，在单元中明确地包含了压力自由度。压力自由度使不可压缩条件得到满足，而不降低求解速度。压力自由度是一种内部自由度，被凝聚在单元内部。
4.3.1.3  超弹单元
有三种单元适合于模拟超弹性材料：
不可压缩单元有HYPE56，58，74和158，这些单元适用于模拟橡胶材料。
可压缩单元有HYPER84和86，HYPER84既可以是4节点矩形也可以是8节点矩形单元，这种单元主要用来模拟泡沫材料。
18X族单元(除LIMK和BEAM单元外，包括SHELL181, PLANE182,PLANE183,SOLID185,SOLID186,和 SOLID187)。18X族单元消除了体积锁定， 既适用于不可压材料，又适用于可压材料。参见《ANSYS Elements Reference》的“Mixed U-P Formulations”。
4.3.2  超弹材料选项
    超弹性可用于分析橡胶类材料(elastomers)，这种材料可承受大应变和大位移，但体积改变极微(不可压缩)。这种分析需用到大应变理论[ NLGEOM ,ON]。 图4-13 是一个例子。

图4-13  超弹性结构
    在ANSYS超弹性模型中，材料响应总是假设各向同性和等温性。由于这一假设，应变能势函数按应变不变量来表示。除非明确指出，超弹性材料还假设为几乎或完全不可压缩材料。材料热膨胀也假定为各向同性的。
    ANSYS在模拟不可压缩或几乎不可压缩超弹性材料时，应变能势函数有几种选项。这些选项均适用于SHELL181,PLANE182, PLANE183, SOLID185, SOLID186, SOLID187 单元。可以通过 TB ,HYPER 命令的 TBOPT 参数进入这些选项。
    其中一个选项，Mooney-Rivhlin 选项，也适用于 HYPER56, HYPER58, HYPER74, HYPER158 单元，以及显式动力分析单元 PLANE162,SHELL163, SOLID164。这一选项可通过 TB ,MOONEY 命令进入。
4.3.2.1  Mooney-Rivlin超弹性选项(TB,HYPER)
    请注意本小节论述应用Mooney-Rivlin 选项与单元 SHELL181, PLANE182, PLANE183, SOLID185, SOLID186, SOLID187。
    如果你想应用Mooney-Rivlin选项于单元HYPER56, HYPER58, HYPER74, HYPER158, PLANE162, SHELL163,SOLID164，则参见§4.3.2.7。
    Mooney-Rivlin选项( TB ,HYPER,,,,MOOMEY)是缺省项，允许用户通过 TB 命令的 NPTS 参数定义2，3，5或9个参数。例如，为了定义5参数模型，用户采用 TB ,HYPER,1,,5,MOONEY。
    2参数Mooney-Rivlin选项，适用于应变大约为100%(拉)和30%(压)的情况。与其他选项相比，较高阶的Mooney-Rivlin选项，对于较大应变的求解，可得到较好的近似。
    下例是3参数Mooney-Rivlin选项的输入实例：
TB,HYPER,1,,3,MOONEY     !Activate 3 parameter Mooney-Rivlin data table
TBDATA,1,0.163498        !Define c10
TBDATA,2,0.125076        !Define c01
TBDATA,3,0.014719        !Define c11
TBDATA,4,6.93063E-5      !Define incompressibility parameter
                         !(as 2/K, K is the bulk modulus)
    对于本选项所需要的材料常数的描述，见《ANSYS Elements Reference》。
4.3.2.2  Ogden选项
    Ogden选项( TB ,HYPER,,,,OGDEN)允许用户通过 TB 命令的 NPTS 参数定义无限参数，例如，应用 TB ,HYPER,1,,3,OGDEN 定义3参数模型。
    与其他选项相比，Ogden选项通常对大应变水平的求解提供最好的近似。可应用的应变水平可达到700%。较高阶的参数可提供更精确的解。但是这样也可能在拟合材料常数时引起数值困难，而且它要求在用户感兴趣的变形范围内要有足够的数据。
    下面是2参数Ogden选项的输入列表:
TB,HYPER,1,,2,OGDEN      !Activate 2 parameter Ogden data table
TBDATA,1,0.326996        !Define μ1
TBDATA,2,2               !Define α1
TBDATA,3,-0.250152       !Define μ2
TBDATA,4,-2              !Define α2
TBDATA,5,6.93063E-5      !Define incompressibility parameter
                         !(as 2/K, K is the bulk modulus)
                         !(Second incompressibility parameter d2 is zero)
    对于这个选项所需要的材料常数的论述，请参见《ANSYS Elements Reference》。
4.3.2.3  Neo-Hookean超弹性选项
    Neo-Hookean选项( TB ,HYPER,,,,NEO)代表应变能势能的最简单形式，可用于应变范围20-30%。下面是Neo-Hookean选项的一个输入列表示例：
TB,HYPER,1,,,NEO         !Activate Neo-Hookean  data table
TBDATA,1,0.577148        !Define incompressibility parameter
                         !(as 2/K, K is the bulk modulus)
    对于这个选项所需要的材料常数的论述，请参见《ANSYS Elements Reference》。
4.3.2.4  多项式超弹性选项
    多项式选项( TB ,HYPER,,,,POLY)允许用户通过 TB 命令的 NPTS 参数定义无限多个参数。例如应用 TB ,HYPER,1,,3,POLY 定义3参数模型。
    与高阶Mooney-Rivlin选项相似，本选项对高应变水平可提供较好的近似。
    在 NPTS =1，常数 =0，这一选项等价于Neo-Hookean选项(用户可参见§4.3.2.3)。在 NPTS =1时，本选项等价于2参数Mooney-Rivlin选项。在 NPTS =2时，来选项等价于5参数Mooney-Rivlin选项。在 NPTS =3时，本选项等价于9参数Mooney-Rivlin选项(参见§4.3.2.1)。对于本选项所要求的材料常数，参见《ANSYS Elements Reference》。
4.3.2.5  Arruda-Boyce超弹性选项
    Arruda-Boyce选项( TB ,HYPER,,,,BOYCE)可用于直到300%的应变水平。下面是本选项的一个例子:
TB,HYPER,1,,,BOYCE      !Activate Arruda-Boyce data table
TBDATA,1,200.0           !Define initial shear modulus
TBDATA,2,5.0             !Define limiting network stretch
TBDATA,3,0.001           !Define incompressibility parameter
                         !(as 2/K, K is the bulk modulus)
    对于本选项所要求的材料常数，参见《ANSYS Elements Reference》。
4.3.2.6  用户定义超弹性选项
    用户定义选项( TB ,HYPER,,,,USER)允许用户应用子程序USERHYPER来定义应变能势对应变不变量的导数，参见《ANSYS Guide to User Programmable Features》。
4.3.2.7  Mooney-Rivlin超弹性选项(TB,MOONEY)
    请注意这一选项适用于HYPER56,HYPER58,HYPER74,HYPER158,PLANE162, SHELL163,SOLID164 等单元。
    如果要应用Mooney-Rivlin选项于SHELL181, PLANE182, PLANE183, SOLID185, SOLID186, SOLID187等单元，请参见§4.3.2.1 。
    ANSYS的单元类型HYPER56,HYPER58,HYPER74,HYPER158，应用直到9个Mooney-Rivlin弹性势能函数。如果用户已知2项、3项、5项或9项Mooney-Rivlin常数的值，则可以通过 TB 族命令直接输入，参见《ANSYS Theory Reference》中的Mooney-Rivlin函数。对于这些单元，用户也可以指定材料函数为用户可编程特性，参见《ANSYS Guide to User Programmable Features》。
    下面是一个示例：
MP,NUXY,1,0.49999   ! NUXY should be almost equal to, but less than 0.5
TB,MOONEY,1,1
TBDATA,1,0.163498
TBDATA,2,0.125076
TBDATA,3,-0.0047583
TBDATA,4,0.014719
TBDATA,6,0.0003882
! (Constants 5, 7, 8, and 9 default to 0.0 in this example)
对于本选项所要求的材料常数，参见《ANSYS Elements Reference》。
    对于任意给定的超弹性材料的Mooney-Rivlin常数，通常在公开文献中查不到。因而，用户可以用 * MOONEY 命令，从一组已知试验数据中自动生成Mooney-Rivlin常数。有时材料制造商可能提供所需的试验数据的一部分或全部，但用户可能发现还需要从试验取得更多的数据。
    超弹性材料行为要比金属材料行为复杂得多。超弹性应力-应变关系，通常在拉伸、压缩和剪切变形中明显不同。因此，应用 * MOONEY 命令来生成一般应用的超弹性材料模型时，需要使用所有可能的三种变形模式，即拉伸、压缩和剪切。参见《ANSYS Theory Reference》中讨论的超弹性测试方法和相应的变形模式。
    如果所得到的是一组不完全的数据(如只有单轴拉伸数据)，程序仍然可以确定出可用的超弹性材料特性。然而，在这种情况下，模型变形特征将只限于与测试特征完全一样的。换句话说，测试数据应该代表计算模型中所有变形模式和响应(应变)范围。
    上面的劝告只是一个简单的说明。如果用户不知道某一个变形模式或应变范围，就不能准确地预测模型中具有这些变形或应变部分的行为。例如，如用户只知道单轴拉伸测试数据，就不能建立那种有很大剪切变形的模型；如只知道应变值为0%-100%之间的测试数据，就不要建立那种有150%应变的模型。如在计算完成之后用户发现所有测试数据不足以表征模型的响应，唯一的改正办法就是获取更多的测试数据。
    用户可用 * MOONEY 命令来自动从实验数据中确定一组Mooney-Rivlin常数。ANSYS确定这些常数以一个数组的形式保存到数据库中。此外，程序还将这些常数以多个 TB 和 TBDATA 命令的格式把Mooney-Rivlin常数写到一个文本文件(Jobrame.TB)中。一旦形成这样的文件，用户就可以在将来的分析用于定义某些相同的Mooney-Rivlin常数。而毋需每次应用 * MOONEY 命令来生成这些常数。
确定和应用Mooney-Rivlin常数
    计算并应用Mooney-Rivlin常数有如下五个步骤：
    第一步：定义数组
    命令：* DIM
    GUI：Utility Menu>Parameters>Array Parameters>Define/Edit
    用户在使用 * MOONEY 命令(GUI：Main Menu> Preprocessor>Material Props>Mooney-Rivlin>Calc Constants)之前，必须定义数组，在绝大多数情况下，需至少定义六个不同的数组(用户可以给这些数组任意合法的参数名，但为了方便我们在这里应用特定的数组名，如STRAIN、SDTRESS等，用户可以用任何喜欢的有效参数名代替之)。它们是STRAIN, STRESS, CONST, CALC, SORTSN, 和SORTSS。
    应变数组(STRAIN) ：这是从材料试验得到的工程应变的数组，分为三列：
    第一列：单轴拉伸和/或压缩数据
    第二列：等双轴拉伸和/或压缩数据
    第三列：剪切数据(平面拉伸和/或压缩数据)
    该数组的大小为 N ×3，其中， N 等于在三列测试中数据点个数的最大值。例如，如果从单轴拉伸/压缩数据得到20个数据点，从剪切试验得到10个数据点，则 N =20。即使只用了一种或两种测试，该数组的大小也必须为 N ×3。虽然以升序输入数据点是较好的，但不是必须的。
    应力数组(STRESS) ：这是从材料试验得到的工程应力的数组。该数组的大小也是 N ×3，应力数据点的输入顺序必须与应变数据点的输入顺序完全一致。
    常数数组(CONST) ：Mooney-Rivlin常数数组的大小为 M ×1， M 为所希望的常数的个数( M 必须为2，5，9三个数之一，如用其它数，则在应用 * MOONEY 命令时，会导致错误信息)。对该数组所作的定义同时就告诉了程序需要生成多少个Mooney-Rivlin常数，* MOONEY 命令自动读取该数组的大小并确定要生成多少个常数，并将其值写入该数组中。
注意 --HYPER84和HYPER86号单元主要是用于模拟可压缩的、泡沫状的高弹体，它们使用Blatz-Ko函数来描述材料特性。将这些单元的KEYOPT(2)设置为1即可选取Blatz-Ko选项，然后用 MP 命令输入合适的 EX 和 NUXY 值，以定义初始的材料剪切模量。对这两种单元来说，不可压缩超弹性材料选项也是可用的，但只限于2项 Mooney-Rivlin 公式，通常应使用HYPER56、HYPER58、HYPER74、HYPER158(而不是 HYPER84 或 HYPER86)来计算所有的不可压缩超弹性材料。
    用超弹性单元作分析时可能对载荷施加的快慢很敏感。在大多数情况下，应缓慢地施加载荷，以避免在收敛过程中，使单元发生过度变形。求解过程中所遇到的每一个问题，都可能是独特的，需要特殊考虑。在加载过程中的不同时间点有时会发生分叉解问题，亦即两个或多个不同的几何外形都具有相同的最小势能，此时可用具有二分的自动时间步长功能[ AUTOTS ，ON]来尽量避免之。
4.3.3  超弹分析实例
4.3.3.1  问题描述
一个由铁板和橡胶体所构成的物体（ 图4.17 ），其底面固定，顶面受一垂直向下的均匀位移，分析所需要提供的外力与顶面位移的变化关系。由于结构和载荷都是轴对称的，因此我们取一截面，对它进行轴对称分析。由于结构变形很大，橡胶体与铁板之间可能发生接触，因此在分析中应考虑到接触。
4.3.3.2  问题详细说明
铁板材料特性：
Ex=2e5
(泊松比)＝0.3
橡胶体材料特性：
(泊松比)＝0.499
单轴压缩时的实验数据：

应变	-0.45	-0.4	-0.35	-0.3	-0.25	-0.2	-0.15	-0.1	-0.05
应力	-256	-128	-64	-32	-16	-8	-4	-2	-1

单轴拉伸时的实验数据：

应变	0.0	0.1	0.2	0.3	0.4	0.5	0.6	0.7	0.8	0.9
应力	0.0	1	1.5	2.0	2.9	3.6	5	7.5	9.7	17

图4-17  问题描述图
4.3.3.3  分析过程（GUI方法）
步骤一：建立计算所需要的模型
在这一步中，建立计算分析所需要的模型，包括定义单元类型，创建结点和单元，并将数据库保存为“hypelastic.db”，在此对这一过程不再详细。
步骤二：恢复数据库文件 “ hypelastic.db ”
Utility menu：file>Resume from
步骤三：定义材料性质
1、选“Main Menu>Preprocessor>Material Props>Material Models”。出现“Define Material Model Behavior”对话框，选择Material Model Number 1。
2、在“Material Models Available”窗口，双击“Structural->Linear->Elastic-> Isotropic”。出现一个对话框。
1、对泊松比（NUXY）键入0.499。
2、单击OK。
3、在“Define Material Model Behavior”对话框的菜单中，选择Material->New Model，弹出对话框，在Define Material ID中输入2，然后单击OK。 出现Material Model Number 2。
4、对弹性模量（EX）键入2e5
5、对泊松比（NUXY）键入0.3
6、单击ＯＫ。
步骤四：定义数组并输入相应的实验数据。
1、择菜单路径：utility menu>Parameters,在其下拉菜单中，将鼠标指向Array Parameters, Array Parameters的下拉菜单出现。
2、Define/Edit,对话框出现。
3、在对话框中单击Add，另一对话框出现。
4、指定Parameter name 为strn 。
5、对No. of rows,cols,planes,依次输入19，3，1
6、单击Apply,结束此对话框的输入，另一相同的对话框出现。
7、在对话框中指定Parameter name 为strss 。
8、对No. of rows,cols,planes,依次输入19，3，1
9、单击OK,结束此对话框的输入，回到Array Parameters对话框。
10、选择数组strn，然后单击Edit,给数组赋值的对话框出现。
11、在数组的第一列依次输入单轴压缩与拉伸的实验应变数据，然后选择菜单路径File>Apply/Quit,结束应变实验数据的输入。
12、在Array Parameters对话框中选择数组strss，然后单击Edit,给数组赋值的对话框出现。
13、在数组的第一列依次输入单轴压缩与拉伸的实验应力数据，然后选择菜单路径File>Apply/Quit,结束应力实验数据的输入。
步骤五：计算MOONEY常数
1、选择菜单路径Main Menu>Preprocessor>Material Props>Mooney-Rivlin> Define Table对话框出现。
2、在Material reference number（材料参考号）中，键入1, 在Number of tempratures中，键入1，然后单击OK。
3、择菜单路径Main Menu>Preprocessor>Material props>Mooney-Rivlin> Calculate constant 。对话框出现。
4、Number of Mooney-Rivlin const，选择5。
5、定strain data array 为strn, 指定stress data array 为strss。
6、单击OK。
步骤六：进入求解器
选择菜单路径Main Menu>Solution
步骤七：加载
根据所给条件，施加适当的约束和载荷。在此不作详述，参考命令流文件。
步骤八：定义分析类型和分析选项：
1、选择菜单路径Main Menu>Solution>-Analysis Type-New Analysis.
2、单击“Static”来选中它然后单击OK。
3、择菜单路径Main Menu>Solution>Unabridged Menu>Analysis Options。 Analysis Options对话框出现。
4、单击Large deform effects option(大变形效应选项）使之为ON， 然后单击OK。
步骤九：设置输出控制选项
1、选择菜单路径：Main Menu > Solution>Unabridged Menu >Load step opts-Output ctrls > Solu Printout。对话框出现
2、在“Item”中，选择“all items”
3、对“FREQ”,选择“Every Substep”
4、单击OK
5、选择菜单路径：Main Menu > Solution>Unabridged Menu >Load step opts-Output ctrls > DB/Resuls File：对话框出现
6、在“Item”中，选择“all items”
7、对“FREQ”,选择“Every Substep”
8、单击OK
步骤十：设置载荷步选项
1、选择菜单路径Main Menu> Solution>Unabridged Menu>Load step opts-Time/Frequenc> Time and substps。对话框出现。
2、对time at end of load step（载荷步终止时间）键入1
3、对“DELTIM”(Time step size) 输入0.03
4、将“AUTOTS”(automatic time stepping)设置为ON
5、对 Mininim time step size 输入0.01
6、对 Maxinum time step of size 输入0.3
步骤十一：打开时间步长预测器
1、选择菜单路径Main Menu> Solution>Unabridged Menu>Load step opts-Nonlinear> Predictor。
2、将predictor的状态设置为“ON”。
步骤十二：打开线性搜索
1、选择菜单路径Main Menu> Solution>Unabridged Menu>Load step opts-Nonlinear> Line Search。
2、将LNSRCH的状态设置为“ON”。
步骤十三：设置收敛性控制
1、选择菜单路径Main Menu> Solution>Unabridged Menu>Load step opts-Nonlinear> Convergence Crit，对话框出现。
2、单击Add,下一级对话框出现。
3、对“TOLER”，输入0.2
4、对“MINREF”，输入200
5、单击OK。
步骤十四：进行求解
步骤十五：进行后处理
4.3.3.4  分析过程（命令流方法）
fini
/cle
r=180
l1=185
l2=74
h1=6
h2=50
h3=182
r1=10
d=50
/prep7
et,1,56,,,1
et,2,42,,,1
et,3,48,,1
et,4,58
et,5,45
et,6,49,,1
keyopt,6,7,1
keyopt,3,7,1
r,1,10000,,0.5
rect,0,l1,0,h1
rect,0,l2,0,h2
cyl4,0,h3,r,-90,,0
aovlap,all
asel,s,loc,y,0,h1
asel,r,loc,x,0,l2
aadd,all
alls
asel,s,loc,y,h1,h3
aadd,all
alls
lsel,s,loc,x,0
lsel,r,loc,y,0,h1
lcom,all
alls
lsel,s,loc,x,0
lsel,r,loc,y,h1,h3
lcom,all
alls
lsel,s,loc,y,h1
lsel,r,loc,x,0,l2
lcom,all
alls
lsel,s,loc,y,h1,h2
lsel,r,loc,x,l2
*get,line1,line,,num,max
alls
lsel,s,loc,x,l2,l1
lsel,r,loc,y,h2,h3
*get,line2,line,,num,max
alls
lfillt,line1,line2,r1
alls
al,1,4,3
asel,s,loc,y,h1,h3
aadd,all
alls
lsel,s,loc,x,l2,l1
lsel,r,loc,y,h1+0.1,h3-0.1
lcom,all
alls
lsel,s,loc,x,l2,l1
lsel,r,loc,y,h1+0.1,h3-0.1
*get,line3,line,,num,max
alls
kl,line3,0.12
lsel,s,loc,x,0
lsel,r,loc,y,h1,h3
*get,line4,line,,num,max
kl,line4,0.4
kl,line4,0.7
alls
lstr,5,7
lstr,13,8
asel,s,loc,y,h1,h3
lsel,s,,,3,4
asbl,all,all
alls
asel,s,loc,y,h1,h3
aatt,1,1,1
asel,s,loc,y,0,h1
aatt,2,1,2
alls
lesize,3,,,10
lesize,8,,,12,2
lesize,7,,,6
lesize,12,,,1
lesize,19,,,8
mshkey,1
amesh,5
amesh,3
amesh,2
amesh,1
amesh,6
alls
lsel,s,,,19
nsll,s,1
cm,targ,node
alls
lsel,s,,,6
nsll,s,1
cm,cont1,node
lsel,s,,,8
nsll,s,1
nsel,r,loc,y,h1,130
cm,cont2,node
alls
cmsel,s,cont1
cmsel,a,cont2
!cmsel,a,cont3
cm,cont,node
alls
type,3
mat,1
real,1
gcgen,cont,targ
alls
save,hypelastic,db
resume,hypelastic,db
mp,nuxy,1,0.499
mp,ex,2,2e5
mp,nuxy,2,0.3
*dim,strn,,19,3
*dim,strss,,19,3
*dim,const,,5
*dim,calc,,19,3
*dim,sortss,,19,3
*dim,sortsn,,19,3
*dim,ecalc,table,100
*dim,xval,table,100
strn(1,1)=-0.45,-0.4,-0.35,-0.3,-0.25,-0.2,-0.15,-0.1,-0.05
strss(1,1)=-256,-128,-64,-32,-16,-8,-4,-2,-1
strn(10,1)=0.0,0.1,0.2,0.3,0.4,0.5,0.6,0.7,0.8,0.9
strss(10,1)=0.0,1,1.5,2.0,2.9,3.6,5,7.5,9.7,17
tb,mooney,,,,1
  *mooney,strn(1,1),strss(1,1),,const(1),calc(1,1),sortsn(1,1),sortss(1,1)
*eval,1,1,const(1),-0.2,0,xval(1),ecalc(1)   
*vplot,xval(1),ecalc(1)
fini
/solu
alls
nsel,s,loc,y,0
d,all,all,0
alls
nsel,s,loc,x,0
d,all,ux,0
d,all,uz,0
alls
nsel,s,loc,y,h3
d,all,ux,0
d,all,uz,0
d,all,uy,-d
alls
antype,static
nlgeom,on
nropt,,,on
outpr,all,all
outres,all,all
autots,on
time,1
deltim,0.03,0.01,0.3
cnvtol,f,,0.02,2
lnsrch,on
pred,on
alls
solve
fini

qiang_ge

谢谢分享！

李春红

很详细！遗憾的是实验数据那块怎么是黑色的，没有这个数据就难以对比啊

t1314j2003

超弹性分析
4.3.1  超弹理论
4.3.1.1  超弹的定义
一般工程材料（例如金属）的应力状态由一条弹塑性响应曲线来描述，而超弹性材料存在一个弹性势能函数，该函数是一个应变或变形张量的标量函数，而该标量函数对应 ...
xinhu123 发表于 2010-5-30 09:56

请问LZ ，关于超弹性材料的一些知识，应用，有没有哪本书讲过的？烦请推荐一下，谢谢！