- 积分
- 18
- 注册时间
- 2008-4-9
- 仿真币
-
- 最后登录
- 1970-1-1
|
本帖最后由 shifang157300 于 2017-4-16 17:31 编辑
我的帖子汇总:
这是本人写的一个ANSYS跌落分析的模板,其中CAD模型可由文件导入(此处模型为ANSYS 9.0自带的container.inp,通过APDL编写的),希望对新手有所帮助。以下是命令流,命令流文件及cad模型文件在附件中。
finish
/clear
/FILNAME,drop_test_simple_case,1
/prep7
/Titie,CUMT,SHI Fang,Drop test simple case,November 16,2013
/DSCALE,ALL,1
/eshape,on
!-------------------------Read Input CAD File--------------------
/INPUT,'box','inp',,, 0
!---------------------------Parameters---------------------------
!
thickness = 0.1
MsSizeBox = 20
MsSizeFloor = 12
InitialV = -10
TotalTime = 10
ResFileOutFreq = 50
HisFileOutFreq = 50
!
!----------------Element type and real constants-----------------
et,1,163
KEYOPT,1,1,7
R,1, ,2,thickness, , , ,
!-----------------------------Materials--------------------------
!
!---1:Floor---
EDMP,RIGI,1,7,7
MP,DENS,1,7900
MPDE,EX,1
MP,EX,1,2.1E+011
MP,NUXY,1,0.3
!
!---2:BOx---
MP,DENS,2,7900
MP,EX,2,2.1E+011
MP,NUXY,2,0.3
TB,BKIN,2,,,,
TBDAT,1,500e4,20e9
!----------------------------Mesh the box------------------------
!
allsel,all
aatt,2,1,1,,
allsel,all
lesize,all,,,MsSizeBox,,1,,,1,
amesh,all
!------------------Create the Floor by key points----------------
!
k,101,-50,-20,-50
k,102,-50,-20,50
k,103,50,-20,50
k,104,50,-20,-50
a,101,102,103,104
!---------------
/VIEW,1,1,1,1
aplot
!---------------
allsel
lsel,s,,,13,16,1,
lesize,all,,,MsSizeFloor,,1,,,1,
allsel
asel,s,,,4
aatt,1,1,1,,
amesh,4
allsel
!----------------------Create Contact Pair-----------------------
!---Component BOX---
ESEL,S,MAT,,2
NSLE,R
CM,BOX,NODE
allsel
!---Component FLOOR---
ESEL,S,MAT,,1
NSLE,R
CM,FLOOR,NODE
allsel
!---Auto contact relation---
EDCGEN,ASTS,BOX,FLOOR,0.2,0.2,0,0,0,,,,,0,10000000
!
!-------------Set Initial Velocity for the Box-------------------
!
EDVE,VELO,BOX,0,InitialV,0,0,0,0, , , , , ,
!
!----------------Define Parameter Time & ACCG--------------------
!
*DIM,TIME,ARRAY,2,1,1, , ,
*SET,TIME(2,1,1) , 1
*DIM,ACCG,ARRAY,2,1,1, , ,
*SET,ACCG(1,1,1) , 9.8
*SET,ACCG(2,1,1) , 9.8
!----------------------Apply acceleration------------------------
!
EDLOAD,ADD,ACLY,0,BOX,TIME,ACCG, 0, , , , ,
!
!----------------------SOLUTION SETTINGS-------------------------
/solu
time,TotalTime
EDRST,ResFileOutFreq, !Set result file output frequency
EDHTIME,HisFileOutFreq, !Set history file output frequency
EDENERGY,1,1,1,1 !turn all energy options on
solve
!
!---------------------------POST Process-------------------------
/post1
set,last
/VIEW,1,,,1
!PLNS,S,EQV
!PLNS,EPPL,EQV
!PLNS,U,Y
PLDI, , !Deformation
ANDATA,0.5, ,0,0,0,1,0,1
跌落变形情况:
|
本帖子中包含更多资源
您需要 登录 才可以下载或查看,没有账号?注册
×
|