基于ANSYS的结构地震分析教程 (静力+模态+反应谱+时程)

shifang157300

基于ANSYS的框架结构地震分析教程

(静力分析+模态分析+反应谱分析+LS-DYNA时程分析)

攥写日期：2016-04-21

Tel: 15996873039

问题探讨：作者 - 师访，QQ - 1549221758，Email- pomato157300@126.com

Research gate：https://www.researchgate.net/profile/Fang_Shi8

仿真论坛：http://home.simwe.com/space-uid-334526.html

个人网站：http://phipsi.top/author.html

本帖子对应的PDF文档：

命令流下载：




地震加速度数据下载：

时程分析关键字文件下载：

我的帖子汇总：

（1）扩展有限元法(XFEM)漫谈（原创_持续更新）：http://forum.simwe.com/thread-1245357-1-1.html

（2）ANSYS UPFs二次开发教程（原创，持续更新）：http://forum.simwe.com/thread-1021888-1-1.html

（3）比特币(Bitcoin)价格波动曲线监控程序_基于Python编写__原创：http://forum.simwe.com/thread-1254734-1-1.html

（4）地震作用下水箱晃动分析（原创，附命令流和K文件）：http://forum.simwe.com/thread-1098856-1-1.html

（5）ANSYS常用单元特性总结及简单实例（原创）：http://forum.simwe.com/thread-1019487-1-1.html

（6）ANSYS计算受压闭合裂纹的应力强度因子实例命令流（原创）：http://forum.simwe.com/thread-1102153-1-1.html

（7）（原创）利用Matlab对ANSYS数据进行后处理实例：http://forum.simwe.com/thread-1094497-1-1.html

（8）（原创）ANSYS跌落分析全命令流模板：http://forum.simwe.com/thread-1093360-1-1.html

（9）钢球入水后反弹CEL流固耦合3D模拟，附CAE文件（原创）:http://forum.simwe.com/thread-1107014-1-1.html

（10）ANSYS16.0新增扩展有限元XFEM裂纹扩展仿真简介（原创）：http://forum.simwe.com/thread-1121373-1-1.html

（11）FEAPpv简介、Linux下的编译及运行方法_原创: http://forum.simwe.com/thread-1136956-1-1.html

（12）基于ANSYS的结构地震分析教程 (静力+模态+反应谱+时程) http://forum.simwe.com/thread-1176187-1-1.html

0 引言

本文用一个简单的例子来介绍采用ANSYS开展地震分析（包括静态分析、模态分析、反应谱分析和LS-DYNA时程分析）的一些概念（详见pdf文档），并给出详细的命令流，希望能够给那些初学者一些启示和帮助。本文命令流在ANSYS15.0下测试通过。本示例模型如下：

图1 本文例子模型示意图

1 建模及静力分析
梁单元选用BEAM188。其余注意事项见命令流:

!****************************************************************
!----      框架结构静力分析                                  ----
!----      Units: SI(m,kg,s)                                 ----
!----      Date:  April 21, 2016                             ----
!----      作者:  师访                                       ----
!----      QQ: 1549221758                                    ----
!----      Website:  phipsi.top                              ----
!****************************************************************
!
!
!****************************************************************      
!----------------------------初始化------------------------------
!****************************************************************
finish
/clear
/FILNAME,ANSYS_Seismic_analysis_Static
/Titie,Seismic analysis of the frame structure         
/PREP7                           !进入前处理器
/DSCALE,ALL,10.0                 !后处理变形缩放系数10倍
/eshape,1                        !显示单元真实形状
/UIS,MSGPOP,3                    !忽略警告信息   
!****************************************************************        
!--------------------------设置白色背景--------------------------
!****************************************************************
/REPLO  
/RGB,INDEX,100,100,100, 0   
/RGB,INDEX, 80, 80, 80,13   
/RGB,INDEX, 60, 60, 60,14   
/RGB,INDEX, 0, 0, 0,15  
!****************************************************************   
!-----------------------------编号设置---------------------------
!****************************************************************
/PNUM,KP,0  
/PNUM,LINE,0
/PNUM,AREA,0
/PNUM,VOLU,0
/PNUM,NODE,0
/PNUM,TABN,0
/PNUM,SVAL,0
/NUMBER,1   
/PNUM,SECT,1
/REPLOT
!****************************************************************
!-------------------------------参数-----------------------------  
!****************************************************************         
mesh_size_HL  = 0.5              !横梁网格划分大小
mesh_size_LZ  = 0.5              !立柱网格划分大小
mesh_size_LB  = 0.2              !楼板网格划分大小
grav_accel    = 9.8              !重力加速度
!---
L             = 5.0              !长
W             = 5.0              !宽
Height_1      = 5.0              !第1层标高
Height_2      = 10.0             !第2层标高
!****************************************************************  
!--------------------------单元类型设置--------------------------
!****************************************************************
ET,1,BEAM188                     !用于模拟框架结构的梁单元
SECTYPE,1, BEAM, RECT, , 0     
SECOFFSET, CENT
SECDATA,400e-3,400e-3,3,3        !400mmx400mm截面梁，立柱(截面号1)
SECTYPE,2, BEAM, RECT, , 0     
SECOFFSET, CENT
SECDATA,250e-3,400e-3,3,3        !250mmx400mm截面梁,横梁(截面号2)
!****************************************************************
!--------------------------材料参数------------------------------  
!****************************************************************  
!1号材料：钢筋混凝土（不区分钢筋和混凝土）  
MP,DENS,1,2600                    
MP,EX,1,30e9                     
MP,NUXY,1,0.25
!****************************************************************           
!---------------------建立框架结构几何模型-----------------------   
!****************************************************************
!顶视图
/VIEW,1,,,1
/ANG,1  
/REP,FAST
!%%%%%%%%%%%%%%%%%%%
!初步建立各层关键点
!%%%%%%%%%%%%%%%%%%%  
!建立地面关键点(关键点编号100+)
k,1,0,0,0
k,2,L,0,0
k,3,L,W,0
k,4,0,W,0
!复制生成1层关键点
kgen,2,1,4,1,,,Height_1,100,1,      
!复制生成2层关键点
kgen,2,1,4,1,,,Height_2,200,1,      

!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%&&
!生成主立柱的全部线(组集iZhu_Main)
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%  
allsel
NUMSTR,LINE, 1
*do,i,1,2
    *do,j,1,4
        l,(i-1)*100+j,(i-1)*100+j+100
    *enddo
*enddo
lsel,all
CM,LiZhu_Main_LINE,LINE   !建立主立柱的线集合(SET)
!给立柱划分网格
k,9999,1000,     0,         0  !远点
lesize,all,mesh_size_LZ
LATT,1,,1, ,9999 , ,1
lmesh,all
allsel

!%%%%%%%%%%%%%%%%%%%%%
!横梁建模并划分网格
!%%%%%%%%%%%%%%%%%%%%%
k,8888,-1,-1,2000   !远点
NUMSTR,LINE, 1001
l,101,102
l,102,103
l,103,104
l,104,101
l,201,202
l,202,203
l,203,204
l,204,201
lsel,s,,,1001,1008,1
LATT,1,,1, ,8888 , ,2
lesize,all,mesh_size_HL
lmesh,all

!****************************************************************      
!-----------------------  边界条件设置  -------------------------
!****************************************************************
!斜视图
/VIEW,  1,  0.317    , -0.850    ,  0.419
/ANG,   1,  -41.55
/REPLO  
allsel
NSEL,S,LOC,Z,0                              
D,all,all
allsel
EPLOT

!****************************************************************     
!                        施加重力加速度     
!****************************************************************
acel,0,0, grav_accel

!****************************************************************
!                          进入求解器
!****************************************************************
/solution
allsel
time,1
OUTRES,ALL,all   
solve
save

!----------------------------------------------------------------
!                          进入后处理器/post1
!----------------------------------------------------------------
/post1
allsel
set,last
!---------全部结构的竖向位移云图
allsel
PLNSOL, U,Z, 0,1.0                                            

图2静力分析-重力作用下的位移云图

2 模态分析

固有频率和模态振型是结构的重要动力特性，对动力荷载下结构的响应分析（反应谱分析）起关键作用，是进行反应谱分析的前提。命令流建模部分与静态分析一致，求解部分有所不同:

!****************************************************************
!----      框架结构模态分析                                  ----
!----      Units: SI(m,kg,s)                                 ----
!----      Date:  April 21, 2016                             ----
!----      作者:  师访                                       ----
!----      QQ: 1549221758                                    ----
!----      Website:  phipsi.top                              ----
!****************************************************************
!
!
!****************************************************************      
!----------------------------初始化------------------------------
!****************************************************************
finish
/clear
/FILNAME,ANSYS_Seismic_analysis_Static
/Titie,Seismic analysis of the frame structure         
/PREP7                           !进入前处理器
/DSCALE,ALL,10.0                 !后处理变形缩放系数10倍
/eshape,1                        !显示单元真实形状
/UIS,MSGPOP,3                    !忽略警告信息   
!****************************************************************        
!--------------------------设置白色背景--------------------------
!****************************************************************
/REPLO  
/RGB,INDEX,100,100,100, 0   
/RGB,INDEX, 80, 80, 80,13   
/RGB,INDEX, 60, 60, 60,14   
/RGB,INDEX, 0, 0, 0,15  
!****************************************************************   
!-----------------------------编号设置---------------------------
!****************************************************************
/PNUM,KP,0  
/PNUM,LINE,0
/PNUM,AREA,0
/PNUM,VOLU,0
/PNUM,NODE,0
/PNUM,TABN,0
/PNUM,SVAL,0
/NUMBER,1   
/PNUM,SECT,1
/REPLOT
!****************************************************************
!-------------------------------参数-----------------------------  
!****************************************************************         
mesh_size_HL  = 0.5              !横梁网格划分大小
mesh_size_LZ  = 0.5              !立柱网格划分大小
mesh_size_LB  = 0.2              !楼板网格划分大小
num_mode      = 5                !振型个数,分析前5阶振型
!---
L             = 5.0              !长
W             = 5.0              !宽
Height_1      = 5.0              !第1层标高
Height_2      = 10.0             !第2层标高
!****************************************************************  
!--------------------------单元类型设置--------------------------
!****************************************************************
ET,1,BEAM188                     !用于模拟框架结构的梁单元
SECTYPE,1, BEAM, RECT, , 0     
SECOFFSET, CENT
SECDATA,400e-3,400e-3,3,3        !400mmx400mm截面梁，立柱(截面号1)
SECTYPE,2, BEAM, RECT, , 0     
SECOFFSET, CENT
SECDATA,250e-3,400e-3,3,3        !250mmx400mm截面梁,横梁(截面号2)
!****************************************************************
!--------------------------材料参数------------------------------  
!****************************************************************  
!1号材料：钢筋混凝土（不区分钢筋和混凝土）  
MP,DENS,1,2600                    
MP,EX,1,30e9                     
MP,NUXY,1,0.25
!****************************************************************           
!---------------------建立框架结构几何模型-----------------------   
!****************************************************************
!顶视图
/VIEW,1,,,1
/ANG,1  
/REP,FAST
!%%%%%%%%%%%%%%%%%%%
!初步建立各层关键点
!%%%%%%%%%%%%%%%%%%%  
!建立地面关键点(关键点编号100+)
k,1,0,0,0
k,2,L,0,0
k,3,L,W,0
k,4,0,W,0
!复制生成1层关键点
kgen,2,1,4,1,,,Height_1,100,1,      
!复制生成2层关键点
kgen,2,1,4,1,,,Height_2,200,1,      

!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%&&
!生成主立柱的全部线(组集:LiZhu_Main)
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%  
allsel
NUMSTR,LINE, 1
*do,i,1,2
    *do,j,1,4
        l,(i-1)*100+j,(i-1)*100+j+100
    *enddo
*enddo
lsel,all
CM,LiZhu_Main_LINE,LINE   !建立主立柱的线集合(SET)
!给立柱划分网格
k,9999,1000,     0,         0  !远点
lesize,all,mesh_size_LZ
LATT,1,,1, ,9999 , ,1
lmesh,all
allsel

!%%%%%%%%%%%%%%%%%%%%%
!横梁建模并划分网格
!%%%%%%%%%%%%%%%%%%%%%
k,8888,-1,-1,2000   !远点
NUMSTR,LINE, 1001
l,101,102
l,102,103
l,103,104
l,104,101
l,201,202
l,202,203
l,203,204
l,204,201
lsel,s,,,1001,1008,1
LATT,1,,1, ,8888 , ,2
lesize,all,mesh_size_HL
lmesh,all

!****************************************************************      
!-----------------------  边界条件设置  -------------------------
!****************************************************************
!斜视图
/VIEW,  1,  0.317    , -0.850    ,  0.419
/ANG,   1,  -41.55
/REPLO  
allsel
NSEL,S,LOC,Z,0                              
D,all,all
allsel

!----------------------------------------------------------------
!                          进入求解器
!----------------------------------------------------------------
/solution
ANTYPE,2       !分析类型为模态分析
allsel
MODOPT,SUBSP,num_mode !子空间法
!MODOPT,LANB,num_mode !分块Lanczos法
MXPAND,num_mode, , ,1   
solve
save

!----------------------------------------------------------------
!                          进入后处理器/post1
!----------------------------------------------------------------
/post1

SET, ,2     !设置这个参数来绘制各阶振型图!!!!!!!!!!!!!!!!!!!!!!比如提取第二阶,则为set,2
PLDISP,2                    

图3 模态分析-一阶振型（频率: 3.16Hz）

3 反应谱分析
反应谱法应用了“结构总响应是各阶振型响应叠加”的原理，将动力问题转化为静力问题来计算。所谓反应谱，是指弹性系统对某个实际地震加速度的最大反应和体系的自振特征（如自振周期）之间的函数关系。反应谱的纵坐标为建筑物的反应，可以是位移、速度和加速度，横坐标为周期。反应谱法首先根据地震波（地震加速度数据）构**应谱，一般利用众多的地震记录算出平均反应谱，称为设计反应谱，再依据设计反应谱计算结构各阶振型的最大响应，然后按照一定的组合原则对各阶振型的地震作用效应进行组合，从而得到多自由度体系的地震作用效应。
反应谱分析命令流:

!****************************************************************
!----      框架结构反应谱分析                                ----
!----      Units: SI(m,kg,s)                                 ----
!----      Date:  April 21, 2016                             ----
!----      作者:  师访                                       ----
!----      QQ: 1549221758                                    ----
!----      Website:  phipsi.top                              ----
!****************************************************************
!
!
!****************************************************************      
!----------------------------初始化------------------------------
!****************************************************************
finish
/clear
/FILNAME,ANSYS_Seismic_analysis_Static
/Titie,Seismic analysis of the frame structure         
/PREP7                           !进入前处理器
/DSCALE,ALL,10.0                 !后处理变形缩放系数10倍
/eshape,1                        !显示单元真实形状
/UIS,MSGPOP,3                    !忽略警告信息   
!****************************************************************        
!--------------------------设置白色背景--------------------------
!****************************************************************
/REPLO  
/RGB,INDEX,100,100,100, 0   
/RGB,INDEX, 80, 80, 80,13   
/RGB,INDEX, 60, 60, 60,14   
/RGB,INDEX, 0, 0, 0,15  
!****************************************************************   
!-----------------------------编号设置---------------------------
!****************************************************************
/PNUM,KP,0  
/PNUM,LINE,0
/PNUM,AREA,0
/PNUM,VOLU,0
/PNUM,NODE,0
/PNUM,TABN,0
/PNUM,SVAL,0
/NUMBER,1   
/PNUM,SECT,1
/REPLOT
!****************************************************************
!-------------------------------参数-----------------------------  
!****************************************************************         
mesh_size_HL  = 0.5              !横梁网格划分大小
mesh_size_LZ  = 0.5              !立柱网格划分大小
mesh_size_LB  = 0.2              !楼板网格划分大小
num_mode     = 10                !振型个数,分析前10阶振型
Tg           = 0.35              !特征周期(折减系数0.6)
alpha_max    = 0.12              !地震影响系数最大值
damping_coef = 0.05              !阻尼系数
!---
L             = 5.0              !长
W             = 5.0              !宽
Height_1      = 5.0              !第1层标高
Height_2      = 10.0             !第2层标高
!****************************************************************  
!--------------------------单元类型设置--------------------------
!****************************************************************
ET,1,BEAM188                     !用于模拟框架结构的梁单元
SECTYPE,1, BEAM, RECT, , 0     
SECOFFSET, CENT
SECDATA,400e-3,400e-3,3,3        !400mmx400mm截面梁，立柱(截面号1)
SECTYPE,2, BEAM, RECT, , 0     
SECOFFSET, CENT
SECDATA,250e-3,400e-3,3,3        !250mmx400mm截面梁,横梁(截面号2)
!****************************************************************
!--------------------------材料参数------------------------------  
!****************************************************************  
!1号材料：钢筋混凝土（不区分钢筋和混凝土）  
MP,DENS,1,2600                    
MP,EX,1,30e9                     
MP,NUXY,1,0.25
!****************************************************************           
!---------------------建立框架结构几何模型-----------------------   
!****************************************************************
!顶视图
/VIEW,1,,,1
/ANG,1  
/REP,FAST
!%%%%%%%%%%%%%%%%%%%
!初步建立各层关键点
!%%%%%%%%%%%%%%%%%%%  
!建立地面关键点(关键点编号100+)
k,1,0,0,0
k,2,L,0,0
k,3,L,W,0
k,4,0,W,0
!复制生成1层关键点
kgen,2,1,4,1,,,Height_1,100,1,      
!复制生成2层关键点
kgen,2,1,4,1,,,Height_2,200,1,      

!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%&&
!生成主立柱的全部线(组集:LiZhu_Main)
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%  
allsel
NUMSTR,LINE, 1
*do,i,1,2
    *do,j,1,4
        l,(i-1)*100+j,(i-1)*100+j+100
    *enddo
*enddo
lsel,all
CM,LiZhu_Main_LINE,LINE   !建立主立柱的线集合(SET)
!给立柱划分网格
k,9999,1000,     0,         0  !远点
lesize,all,mesh_size_LZ
LATT,1,,1, ,9999 , ,1
lmesh,all
allsel

!%%%%%%%%%%%%%%%%%%%%%
!横梁建模并划分网格
!%%%%%%%%%%%%%%%%%%%%%
k,8888,-1,-1,2000   !远点
NUMSTR,LINE, 1001
l,101,102
l,102,103
l,103,104
l,104,101
l,201,202
l,202,203
l,203,204
l,204,201
lsel,s,,,1001,1008,1
LATT,1,,1, ,8888 , ,2
lesize,all,mesh_size_HL
lmesh,all


!****************************************************************      
!-----------------------  边界条件设置  -------------------------
!****************************************************************
!斜视图
/VIEW,  1,  0.317    , -0.850    ,  0.419
/ANG,   1,  -41.55
/REPLO  
allsel
NSEL,S,LOC,Z,0                              
D,all,all
allsel
   
!****************************************************************  
!                          进入求解器
!****************************************************************  
/solution
!反应谱分析需要先进行模态分析
ANTYPE,2       !分析类型为模态分析
allsel
! MODOPT,SUBSP,num_mode
MODOPT,LANB,num_mode
!expass,on
MXPAND,num_mode, , ,1   !对模态进行扩展
solve

*DIM,fre,,num_mode
*DO,i,1,num_mode
    *GET,fre(i),MODE,i,FREQ ! OBTAIN MODE FREQENCY FOR MODE I
*ENDDO

save
finish

/solution
ANTYPE,8       !分析类型为谱分析
SPOPT ,SPRS , ,!单点反应谱分析
SVTYPE ,2      !指定单点反应谱分析类型-地震加速度
SED ,1 ,0 ,0   !指定地震加速度方向为x方向


!计算反应谱
gama  = 0.9 + (0.05-damping_coef)/(0.5+5*damping_coef)
yita1 = 0.02+ (0.05-damping_coef)/8
yita2 = 1.0 + (0.05-damping_coef)/(0.06+1.7*damping_coef)
T1 = 0.00001
S1 = 0.45*alpha_max
T2 = 0.1
S2 = yita2*alpha_max
T3 = Tg
S3 = yita2*alpha_max
T4 = 2*Tg
S4 = ((Tg/T4)**gama)*yita2*alpha_max
T5 = 2.5*Tg
S5 = ((Tg/T5)**gama)*yita2*alpha_max
T6 = 3*Tg
S6 = ((Tg/T6)**gama)*yita2*alpha_max
T7 = 3.5*Tg
S7 = ((Tg/T7)**gama)*yita2*alpha_max
T8 = 4*Tg
S8 = ((Tg/T8)**gama)*yita2*alpha_max
T9 = 4.5*Tg
S9 = ((Tg/T9)**gama)*yita2*alpha_max
T10 = 5*Tg
S10 = ((Tg/T10)**gama)*yita2*alpha_max
T11 = 3.0
S11 = (yita2*0.2**gama-yita1*(T11-5*Tg))*alpha_max
T12 = 6.0
S12 = (yita2*0.2**gama-yita1*(T12-5*Tg))*alpha_max

!周期折减
S1=S1*9.8 $S2=S2*9.8 $S3=S3*9.8 $S4=S4*9.8 $S5=S5*9.8
S6=S6*9.8 $S7=S7*9.8 $S8=S8*9.8 $S9=S9*9.8 $S10=S10*9.8 $S11=S11*9.8 $S12=S12*9.8

FREQ,1/T12,1/T11,1/T10,1/T9,1/T8,1/T7,1/T6,1/T5,1/T4
FREQ,1/T3,1/T2,1/T1
SV,0.05,S12,S11,S10,S9,S8,S7,S6,S5,S4
SV,0.05,S3,S2,S1


SRSS,0,DISP   !平方根耦合
!CQC,0.001,DISP, ,STATIC

DMPRAT,damping_coef   !阻尼系数
solve
save

!****************************************************************  
!                          进入后处理器/post1
!****************************************************************  
/post1
/INPUT, ,MCOM
/VIEW,1,,-1
/ANG,1  
/AUTO,1
/REP,FAST  
allsel
SET,LIST
/INPUT,,MCOM          !计算反应谱工况
PLNSOL, U,X, 0,1.0    !x方向位移云图
!PLNSOL, U,Y, 0,1.0   !y方向位移云图

图4  反应谱分析-x方向位移云图

4 LS-DYNA时程分析
    时程分析法，也称直接动力法，它是根据动力学运动方程，将地震波时程记录（一般为地震x方向和y方向加速度数据）作为激励，直接求解结构在各个时刻的动态响应问题。时程分析法常见的有显式动态时间积分法和Newmark隐式时间积分法。其中，ANSYSLS-DYNA显式动态分析程序功能强大，能够模拟各种复杂问题。此外，LS-PrePost是一套专为LS-DYNA开发的有限元前后处理软件，可用来对ANSYSLS-DYNA计算数据进行后处理。

!****************************************************************
!----      框架结构时程分析                                  ----
!----      Units: SI(m,kg,s)                                 ----
!----      Date:  April 21, 2016                             ----
!----      作者:  师访                                       ----
!----      QQ: 1549221758                                    ----
!----      Website:  phipsi.top                              ----
!****************************************************************
!
!
!****************************************************************      
!----------------------------初始化------------------------------
!****************************************************************
finish
/clear
/FILNAME,ANSYS_Seismic_analysis_DYNA
/Titie,Seismic analysis of the frame structure         
/PREP7                           !进入前处理器
/DSCALE,ALL,10.0                 !后处理变形缩放系数10倍
/eshape,1                        !显示单元真实形状
/UIS,MSGPOP,3                    !忽略警告信息   
!****************************************************************        
!--------------------------设置白色背景--------------------------
!****************************************************************
/REPLO  
/RGB,INDEX,100,100,100, 0   
/RGB,INDEX, 80, 80, 80,13   
/RGB,INDEX, 60, 60, 60,14   
/RGB,INDEX, 0, 0, 0,15  
!****************************************************************   
!-----------------------------编号设置---------------------------
!****************************************************************
/PNUM,KP,0  
/PNUM,LINE,0
/PNUM,AREA,0
/PNUM,VOLU,0
/PNUM,NODE,0
/PNUM,TABN,0
/PNUM,SVAL,0
/NUMBER,1   
/PNUM,SECT,1
/REPLOT
!****************************************************************
!-------------------------------参数-----------------------------  
!****************************************************************         
mesh_size_HL  = 0.5              !横梁网格划分大小
mesh_size_LZ  = 0.5              !立柱网格划分大小
mesh_size_LB  = 0.2              !楼板网格划分大小
grav_accel    = 9.8              !重力加速度
damping_coef = 0.05              !阻尼系数
ShockTime    = 30                !地震持续时间(最大为40s)
TotalTime    = 30                !总的计算时间(>=ShockTime)
output1      = 200               !200
output2      = 2000              !2000
!---
L             = 5.0              !长
W             = 5.0              !宽
Height_1      = 5.0              !第1层标高
Height_2      = 10.0             !第2层标高
!****************************************************************  
!--------------------------单元类型设置--------------------------
!****************************************************************
!用于模拟框架结构的矩形截面梁单元
ET,1,BEAM161                  
KEYOPT,1,1,1
KEYOPT,1,2,2
KEYOPT,1,4,0,
KEYOPT,1,5,0
R,1,5/6,400e-3,400e-3,400e-3,400e-3,
R,2,5/6,400e-3,400e-3,250e-3,250e-3,
!****************************************************************
!--------------------------材料参数------------------------------  
!****************************************************************  
!1号材料：钢筋混凝土（不区分钢筋和混凝土）  
MP,DENS,1,2600                    
MP,EX,1,30e9                     
MP,NUXY,1,0.25
!****************************************************************           
!---------------------建立框架结构几何模型-----------------------   
!****************************************************************
!顶视图
/VIEW,1,,,1
/ANG,1  
/REP,FAST
!%%%%%%%%%%%%%%%%%%%
!初步建立各层关键点
!%%%%%%%%%%%%%%%%%%%  
!建立地面关键点(关键点编号100+)
k,1,0,0,0
k,2,L,0,0
k,3,L,W,0
k,4,0,W,0
!复制生成1层关键点
kgen,2,1,4,1,,,Height_1,100,1,      
!复制生成2层关键点
kgen,2,1,4,1,,,Height_2,200,1,      

!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%&&
!生成主立柱的全部线(组集:LiZhu_Main)
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%  
allsel
NUMSTR,LINE, 1
*do,i,1,2
    *do,j,1,4
        l,(i-1)*100+j,(i-1)*100+j+100
    *enddo
*enddo
lsel,all
CM,LiZhu_Main_LINE,LINE   !建立主立柱的线集合(SET)
!给立柱划分网格
k,9999,1000,     0,         0  !远点
lesize,all,mesh_size_LZ
LATT,1,1,1, ,9999 , ,
lmesh,all
allsel

!%%%%%%%%%%%%%%%%%%%%%
!横梁建模并划分网格
!%%%%%%%%%%%%%%%%%%%%%
k,8888,-1,-1,2000   !远点
NUMSTR,LINE, 1001
l,101,102
l,102,103
l,103,104
l,104,101
l,201,202
l,202,203
l,203,204
l,204,201
lsel,s,,,1001,1008,1
LATT,1,2,1, ,8888 , ,
lesize,all,mesh_size_HL
lmesh,all
allsel

!****************************************************************      
!-----------------------  边界条件设置  -------------------------
!****************************************************************

!斜视图
/VIEW,  1,  0.317    , -0.850    ,  0.419
/ANG,   1,  -41.55
/REPLO  
allsel
NSEL,S,LOC,Z,0   
CM,Bottom,node                               !建立底部节点的节点集
!-------------
D,all,UZ                                     !约束底面节点竖向位移
D,all,ROTX                                   !约束底面节点x轴旋转自由度
D,all,ROTY                                   !约束底面节点y轴旋转自由度
D,all,ROTZ                                   !约束底面节点z轴旋转自由度
!耦合底部x、y方向位移
cp,1,ux,all
cp,2,uy,all  
!----------------------------------------------------------------     
!                        施加重力加速度     
!----------------------------------------------------------------
allsel
cm,AllStuff,node                             !建立节点集合AllStuff
!-------------  
*DIM,timeZ,ARRAY,3,1,1, , ,  
*SET,timeZ(2,1,1) , 2.0
*SET,timeZ(3,1,1) , TotalTime
*DIM,ACCGZ,ARRAY,3,1,1, , ,  
*SET,ACCGZ(1,1,1) , 9.8  
*SET,ACCGZ(2,1,1) , 9.8  
*SET,ACCGZ(3,1,1) , 9.8  
edload,add,ACLZ,,AllStuff,timeZ,ACCGZ        !施加重力加速度
!----------------------------------------------------------------     
!                         施加地震加速度     
!----------------------------------------------------------------
tnum=TotalTime/0.02+1
dnum=ShockTime/0.02+1                        !地震波数据间隔是0.02s,总数据个数为dnum
*dim,eqw,array,tnum,1,1,,,
*VREAD,eqw,seismic-accelerations-TH2TG035-x_Gravity,dat,,,,,,0,
(e16.0)
*dim,time,array,tnum,1,1,,,
*do,i,1,tnum,1
    time(i,1,1)=(i-1)*0.02
    *if,i,le,dnum,then
        eqw(i,1,1)=0.01*eqw(i,1,1)           !加速度单位从cm/s^2转换成m/s^2，设防烈度7级，最大加速度0.15g
    *else
        eqw(i,1,1)=0
    *endif
*enddo

edload,add,ax,0,Bottom,time,eqw  !x方向地震加速度
!edload,add,ay,0,Bottom,time,eqw   !y方向地震加速度

!----------------------------------------------------------------
!                          进入求解器
!----------------------------------------------------------------
/solution
EDRUN,SMP,1,8                                !设置4个CPU满负荷运转，工作站为8
time,TotalTime
!-------------                               !求解控制
EDRST,output1,  
EDHTIME,output2,
EDDUMP,20,   
EDENERGY,1,1,1,1                             !打开所有能量控制开关
!EDCTS,-MassScale,                            !质量缩放
!---------
eddamp,all,,0.05                             !阻尼0.1
EDHGLS,0.1                                    !刚漏控制0.1
!---------
!---------
!edwrite,both
edwrite,LSDYNA
!edout,all
save
!solve              !仅仅生成关键字，不用ansys计算，后面直接用dyna计算
save
finish

simzhai

一楼沙发先抢了， 辛苦大神了！

summermorton

感谢大神

luqiang010

师博士大爱啊

shifang157300

simzhai 发表于 2016-4-24 09:54
一楼沙发先抢了， 辛苦大神了！

感谢支持

neulc

辛苦了，

espada4

辛苦大神了！

shifang157300

neulc 发表于 2016-4-28 16:08
辛苦了，

感谢支持

N次变频

非常好                  

w55858880w

大神辛苦了！很有帮助的帖子！

luqiang010

一直支持师博士！！！

shifang157300

w55858880w 发表于 2016-5-7 12:42
大神辛苦了！很有帮助的帖子！

感谢

htbbzzg

谢谢分享！

zcy_zxt

代码很能体现楼主的业务素质
赞!

shifang157300

zcy_zxt 发表于 2016-6-5 16:19
代码很能体现楼主的业务素质
赞!

可以加我qq交流
qq：1549221758

springer_

代码写的好，学习了

hello2001zzu

有实力，学习一下

TALENT

感谢，好东西，收藏了

rhww

佩服楼主的大作啊，以前也研究过谱分析，好好拜读一下。

lpg1588

感谢，正需要