共享：包含接触的热－力直接耦合例子！

nwpuyl

搞到这个例子，感觉还不错！如果重复了，请斑竹删除哦！题目如下：
两个同心圆管之间有一个小间隙，内管中突然流入一种热流体，求经过3分钟后外表面的温度分布和应力分布，已知条件：
管材弹性模量：2E11N/(m*m)
热膨胀系数：5E-5 /F
泊松比：0.3
导热系数：10W/mC
密度：7880Kg/(m*m)
比热：500 J/Kg*C
外管外半径：0.131m
外管内半径：0.121m
内管外半径：0.12m
内管内半径：0.11m
流体温度：300 C
流体与内管内壁对流系数：300W/m*m*C
内、外管接触导热：0.1W/C  （其中C表示摄氏度）
命令流如下：
/prep7
et,1,13,4,,1    !直接选用耦合单元plane13，自由度为ux、uy、temp，轴对称
et,2,48         !定义结构接触单元
keyopt,2,1,1    !设定接触的相应选项
keyopt,2,2,1
keyopt,2,7,1
r,2,2e11,0,0.0001,,,0.1 !定义接触单元的实常数
mp,ex,1,2e11        !定义管材的属性
mp,alpx,1,5e-5
mp,prxy,1,0.3
mp,kxx,1,10
mp,dens,1,7880
mp,c,1,500
rect,0.11,0.12,0,0.02   !建模
rect,0.121,0.131,0,0.02
amesh,all
nsel,s,loc,x,0.11
cp,1,ux,all
cp,2,temp,all         !耦合内管内壁的X位移和温度自由度
nsel,s,loc,x,0.12
cp,3,ux,all
cp,4,temp,all         !耦合内管外壁的X位移和温度自由度
nsel,s,loc,x,0.121
cp,5,ux,all
cp,6,temp,all         !耦合外管内壁的X位移和温度自由度
nsel,s,loc,x,0.131
cp,7,ux,all
cp,8,temp,all         !耦合外管外壁的X位移和温度自由度
nsel,s,loc,y,0.02
nsel,r,loc,x,0,0.12
cp,9,uy,all           !耦合内管顶部的Y位移
nsel,s,loc,y,0.02
nsel,r,loc,x,0.121,0.131
cp,10,uy,all          !耦合外管顶部的Y位移
nsel,s,loc,x,0.12
cm,cont,node
nsel,s,loc,x,0.121
cm,targ,node
type,2
real,2
gcgen,cont,targ,3     !创建接触单元
/solu
antype,trans           !进行瞬态分析
tunif,20               !定义初始平均温度
tref,20                !定义参考温度
sfl,4,conv,300,,300    !内管内壁对流边界条件
sfl,6,conv,10,,20      !外管外壁对流边界条件
nsel,s,loc,y,0         !约束底边的Y向位移
d,all,uy,0
time,180               !定义分析时间3分钟
deltime,10,5,15        !时间步长
outres,all,all
kbc,1
autots,on              !打开自动时间步长
allsel
solve
/post1
plnsol,temp            !查看温度分布
plnsol,s,eqv           !查看等效应力分布

learnerzhang

请问用 cont48 创建接触单元 和 用 cont171 - target169创建接触对有什么不同？

nwpuyl

48用于点面接触，无需预先知道确切的接触位置，接触面之间也不需保持一致的网格。
171和169用于面面接触，与点－面接触单元比，具有很多优点，例如：需要较少的接触单元，因而只需较少的磁盘空间和CPU时间，有利于可视化...
但是如果通过一组节点来定义接触面，生成多个单元，那么就可以通过点－面接触单元来模拟面－面的接触问题

learnerzhang

请教nwpuyl和斑竹，我用cont48单元建立了接触单元，模拟热液面对壁面的加热过程。其中液面采用了生死单元。但在计算中出现了问题，如图所示：在液面上升的第一步 接触单元就获得了与液面同样的温度，并且保持这一温度，这与实际完全违背。请问怎么解决呢？

learnerzhang

我的命令流如下：
  
/clear,start
/filname,Rjiao,1           ! my own file name.  
/config,noeldb,1          ! no results written into database.
  
resume,'coucontact','db','.'
  
fini
/solu  
antype,trans
timint,on
!tunif,20
!tref,20
!toffst,273
esel,s,mat,,7  
nropt,full,,on  
ekill,all                 !杀死所有焦体单元
allsel
  
ldread,temp,,,5,2,simplewhole,rst   
cmsel,s,outline
sf,all,conv,4.5,20        !空气温度20
allsel
  
*SET,dtop,0  
*SET,tim,0.01             !
*SET,delt,0.1             !
   
*do,i,1,17                !17 steps
esel,s,mat,,7
esel,a,type,,2            !
nsle,s  
ddele,all,temp
allsel
tim=tim+delt
time,tim
deltim,delt,delt,delt,1
KBC,1  
!AUTOTS,-1   
tintp,,,,1
timint,1,therm       !!!
timint,1,struct   
!outres,all,all
esel,s,mat,,7
nsle,s  
dtop=dtop+.38236
nsel,r,loc,y,0,dtop  
esln,s,1
ealive,all  
!esel,a,type,,2             !
nsel,r,loc,y,dtop-0.15,dtop
esln,s
nsle,s,1
d,all,temp,498
allsel                !
esel,s,live
nall
eall
solve
*enddo
fini

jnjl

谢谢nwpuyl 发的好例子！
你出差回来了？有什么收获啊？
明天我也要出差了，帮我照看一下论坛啊。
先帮楼上的兄弟把这个问题解决了吧。

nwpuyl

我把比较好的发出来了，这个例子就是之一。
斑竹不会出去很久吧？！
呵呵呵呵！放心去吧，大家会相互帮助着的，等你给大家带好东东回来哦！
learnerzhang这个问题我力不从心呀！
仅从这段命令流我实在看不出问题所在！
我有个建议，learnerzhang兄把所有的命令流发全吧！这样大伙儿一起来帮忙运行成功的几率也大一些呀！只看这个计算过程的命令流，感觉有点无从下手哦！

learnerzhang

nwpuyl，我前面的部分都是用gui命令做的。log文件很乱，我看了一下很难整理成命令流。
其实我这里没有什么新东西，接触单元是按你上面的例子里用 cont48，分别选择中间流体面右边界线上的节点作为contactnode，壁面左边界线上的节点作为targetnode，建立的。
上面加载程序也类似于以前的浇铸程序。
现在真是不知道问题出在那里，为什么接触单元从一开始就获得了温度，是实常数还是什么问题？
麻烦你了，再帮我看看。谢谢！

nwpuyl

learnerzhang wrote:
现在真是不知道问题出在那里，为什么接触单元从一开始就获得了温度，是实常数还是什么问题？

  
接触单元为什么不能“从一开始就获得温度”？它获得的温度是多少呢？和其它单元的开始温度一样吗？
我感觉：它一定会获得初始温度，这也复合实际情况。即使我们不定义初始温度，系统默认参考温度为其初始温度；如果连参考温度也不定义，两者都默认为0。
继续谈论哦！问题解决了共享一下，我也很想知道！

learnerzhang

参考温度和初始温度都设为20，只有液面用生死单元逐步加温度载荷480。但壁面的所有接触单元在一开始就都得到480了。
帮忙一起考虑一下吧。

nwpuyl

learnerzhang wrote:
参考温度和初始温度都设为20，只有液面用生死单元逐步加温度载荷480。但壁面的所有接触单元在一开始就都得到480了。
帮忙一起考虑一下吧。

我感觉你的这个问题有点怪，不过请问你怎么知道“壁面的所有接触单元在一开始就都得到480了”？CONTAC48单元三个节点，设定为具有热传导能力时，每个节点有三个自由度UX, UY, TEMP，因为它是二维的，所以我想：最多只能分别知道各个节点的温度，它应该和所属的体节点温度一致，也就是说，一般情况下，一个48单元有三个节点温度。那么你说的480指的是什么呢？
等你继续讨论！

djwndxzn

nwpuyl ，你好请问一下在直接耦合里的耦合载荷矢量和矩正是什么意思，我现在用PlANE13做感应加热分析我该怎么耦合？谢谢

haiyo

nwpuyl搞热力耦合的，你的热磁耦合他不会的，流体的他也从不做答。

djwndxzn

哦，我以为他用过PLANE13，可能对它比较熟悉那请问haiyo或者其余高手谁知道啊，请你们告诉我，谢谢！！！

huntfora

好帖，学习了

huntfora

nwpuyl大侠，一楼的例子怎么一运行，ANSYS就会自动关掉。
不知怎么回事

baifan132

11# nwpuyl \

我这运行也是出现关闭的现象，是怎么回事啊