结构地震反应谱分析实例

kxgglm

在多位朋友的大力帮助下，经过半个多月的努力，鄙人终于对结构地震反应谱分析有了一定的了解，现将其求解步骤整理出来，以便各位参阅，同时，尚有一些问题，欢迎各位讨论！
      为叙述方便，举一简单实例：
      在侧水压与顶部集中力作用下的柱子的地震反应谱分析，谱值为加速度反应谱，考虑X与Y向地震效应作用。已知地震影响系数a与周期T的关系：
a(T)= 0.4853*(0.4444+2.2222*T) 0<T<=0.04 秒
          0.4853*(0.10/T)^(-0.686) 0.04<T<=0.1 秒
          0.4853 0.1<T<=1.2 秒
          0.4853*(1.2/T)^1.5 1.2<T<=4 秒

以下是命令流程序
----------------------------------------------------------------------------------------------------

/filname,SPEC,1
/PREP7
!定义单元类型及材料特性
ET,1,45
MP,EX,1,2.8E10
MP,DENS,1,2.4E3
MP,NUXY,1,0.18

!建立模型
BLOCK,0,1,0,1,0,5

!网格剖分
ESIZE,0.5
VMESH,all

/VIEW,,-0.3,-1,1
EPLOT

FINISH

/SOLU

!施加底部约束
ASEL,,LOC,Z,0
DA,ALL,ALL
ALLSEL

!施加自重荷载
ACEL,0,0,10

!进行模态求解
ANTYPE,MODAL
MODOPT,LANB,30

SOLVE
FINISH

!进行谱分析
/SOLU
ANTYPE,SPECTR
SPOPT,SPRS,30,YES
SVTYP,2 !加速度反应谱
SED,1,1 !X与Y向

FREQ,0.2500,0.2632,0.2778,0.2941,0.3125,0.3333,0.3571,0.3846,0.4167
FREQ,0.4545,0.5000,0.5556,0.6250,0.7143,0.8333,1.1111,2.0000,10.0000
FREQ,25.0000,1000.0000

SV,0.05,0.0797,0.0861,0.0934,0.1018,0.1114,0.1228,0.1362,0.1522,0.1716
SV,0.05,0.1955,0.2255,0.2642,0.3152,0.3851,0.4853,0.4853,0.4853,0.4853
SV,0.05,0.2588,0.2167

SOLVE

FINISH

!进行模态求解(模态扩展)
/SOLU
ANTYPE,MODAL
EXPASS,ON
MXPAND,30,,,YES,0.005
SOLVE
FINISH

!进行谱分析(合并模态)
/SOLU
ANTYPE,SPECTR
SRSS,0.15,disp
SOLVE
FINISH

/POST1
SET,LIST  !结果1
/INP,,mcom
lcwrite,11

LCASE,11
PRRSOL,    !结果2
SET,FIRST
PRRSOL,    !结果3
SET,NEXT
PRRSOL,    !结果4
SET,NEXT
PRRSOL,    !结果5
SET,NEXT
PRRSOL,    !结果6
FINISH

!静力分析

/SOLU
ANTYPE,STATIC

!施加水压荷载
NSEL,,LOC,Y,0
NSEL,R,LOC,Z,0,5
SFGRAD,PRES,0,Z,0,-10000
SF,ALL,PRES,50000

!施加集中荷载
NSEL,,LOC,Y,0
NSEL,R,LOC,z,5
F,ALL,FY,10000

ALLSEL
EPLOT
SOLVE
FINISH

/POST1
set,last
lcwrite,12
Lcase,11
Lcoper,add,12
Lcwrite,13

LCASE,12
PRRSOL,    !结果7
LCASE,13
PRRSOL,    !结果8

FINISH

---------------------------------------------------------------------------------------------------

以下是计算的结果
---------------------------------------------------------------------------------------------------
结果1：（Results Summary）
1  21.647
2  21.647
3  121.51
4  121.51

结果2：（单独谱分析反力LCASE,11）
VALUE 2467.9 2290.1 18384.

结果3：（单独谱分析反力SET,FIRST）
VALUE 0.13334E+06-0.15785E+07-0.18819E-06

结果4：（单独谱分析反力SET,NEXT）
VALUE -0.15785E+07-0.13334E+06-0.48918E-06

结果5：（单独谱分析反力SET,NEXT）
VALUE -0.87805E+07 0.27008E+08 0.86846E-07

结果6：（单独谱分析反力SET,NEXT）
VALUE 0.27008E+08 0.87805E+07 0.79325E-06

结果7：（单独静力分析反力LCASE,12）
VALUE 0.22901E-08-0.15500E+06 0.12000E+06

结果8：（谱分析与静力分析叠加反力LCASE,13）
VALUE 2467.9 -0.15271E+06 0.13838E+06

---------------------------------------------------------------------------------------------------

以下是问题的讨论
---------------------------------------------------------------------------------------------------
1、模态提取数为30，即取前30阶振型数，但在谱分析时得到的是4阶，这4阶是什么意思？
2、在单独谱分析时，为何结果2、3、4、5、6会相差如此之大？（其应力和位移也是如此。）
3、在进行谱分析的合并模态步骤中，模态合并方法应该选用SRSS,0.15,DISP还是SRSS,0.15,ACEL（其对结果影响很大）？
4、在谱分析中，似乎应该将水压力折算成各节点处的附加质量MASS21，但对于非竖值方向（如本例为Y方向），MASS21单元如何加上去？
5、在选取（离散）频率和谱值时，似乎没有一定的标准，而其基本原则是须选取具有代表性的点。
6、模态分析中采用Subspace法与Block Lanczos法所得结果相差2%~4%左右，用后一种方法计算更快，但占用内存大50%左右。
7、在网格剖分时采用VMESH和VSWEEP两种方法，对静力分析结果没有影响，但对谱分析结果却有一定影响，何也？
8、有朋友说可以“做模态分析之前先做打开预应力的静力分析，然后再做打开预应力的模态分析，接着和以前一样”，但我试了试，得到的结果相差很大，不知何故，如果哪位朋友曾经作过这方面的例子，能否再试一下本例，以便进行比较！

laogu

最近我也在计算地震方面，有几点看法，和各位共同切磋：

1、模态提取数为30，........
  与 MXPAND,30,,,YES,0.005
  SRSS,0.15,DISP  中的0.005和0.15有关。
3、模态合并方法计算应力位移应该选用SRSS,0.15,DISP，计算加速度分布用SRSS,0.15,ACEL。
4、水压力折算成各节点处的附加质量MASS21，可以通过设置 MASS21单元属性。
5、在选取（离散）频率和谱值时，.......
最好是根据你模态分析得出来的频率，进行选取点，而且你的SV值需乘以9.81。
另外你的  SED,1,1 是不行的它表示与x、y 45度夹角，需两种工况（SED,1,0和SED,0,1）进行组合。

laogu

不好意思，SV值不是乘以9.81。而是乘以地震动最大峰值加速度，比如重力坝规范中：
7级0.1g；
8级0.2g；
9级0.4g。

gxx917

施加了加速度谱以后，得到的结果中，载荷步3表示1sigma应力，位移；载荷步4表示1sigma速度解；载荷步5表示1sigma加速度解。而三种解中都可以得到对应的应力，位移！那这三种位移和应力有何不同呢？

zengzhan

结果2，3里面的值分别代表什么啊？请楼主告诉我，我是新手，楼主有联系方式吗

zengzhan

有人回答我吗？
我还有一个不明白，inp是什么命令

Analyst

大哥，得知你在地震反应谱方面有专攻，小弟正在做一个关于地震反应谱的项目，有很多问题请教，不知道如何联系？

小弟的QQ：114713307

Analyst

咨询： 我现在有一个高耸结构，只要为一个直径为12米的圆通。如图一所示。

载荷有如下几种
1.重力载荷
2.风载
3.动载荷（折算成等效力分布在一定的区域）
4.静力载荷
5.地震载荷

对于地震载荷我们准备采用反应谱的形式进行加载
想咨询的是，我们是应该先进性谱分析呢 还是先做静力分析。

请老师指导！万分感激！

daihaifeng

谢谢楼主！！！

ap1le

好好学习，学习

maybey

要求不高，看你算多大的东西了

809386521

楼主，你好，请问你这个计算时静力分析和谱分析时在同一个模型里计算的吗？还是在两个模型里算的？如果是前者，那么算完谱分析后还能再算静力分析吗？