帮忙看一下，温度场分析

jiahong76

已知资料：12个月均气温
不考虑自生热，只考虑空气、水对流作用(假定水温=气温)
考察年内温度变化（以天为单位）

疑问：为什么整个结构的温度在某一特定时刻为常数？

fini
/cle
*set,day,360

!单位统一用KJ/m2.h.deg
Hair=1440                                !空气的对流系数取60kJ/m2.h.deg
Hwater=288000                !水的对流系数取12000KJ/m2.h.deg

/PREP7
!定义单元类型
et,1,solid70
!et,2,solid45
mp,kxx,1,254.4                   !混凝土导热系数10.6kJ/m.h.deg
mp,dens,1,2400

!输入气温表
*dim,qiwen,table,12,1,1,time,,,
qiwen(1,0,1)=0
qiwen(1,1,1)=22.3
qiwen(2,0,1)=30
qiwen(2,1,1)=22.2
qiwen(3,0,1)=60
qiwen(3,1,1)=15.9
qiwen(4,0,1)=90
qiwen(4,1,1)=8.7
qiwen(5,0,1)=120
qiwen(5,1,1)=0
qiwen(6,0,1)=150
qiwen(6,1,1)=-8.8
qiwen(7,0,1)=180
qiwen(7,1,1)=-12.8
qiwen(8,0,1)=210
qiwen(8,1,1)=-8.6
qiwen(9,0,1)=240
qiwen(9,1,1)=-0.6
qiwen(10,0,1)=270
qiwen(10,1,1)=7.8
qiwen(11,0,1)=300
qiwen(11,1,1)=14.6
qiwen(12,0,1)=360
qiwen(12,1,1)=19


BLOCK,0,50,0,10,0,40
BLOCK,0,50,0,-10,0,40
allsel
vglue,all
numcmp,all
lesize,7,,,20,,,,,,
lesize,11,,,16,,,,,,
VMESH,all

/SOLU
antype,4
trnopt,full   !瞬态分析选项
nropt,full
!对基础节点设置初始温度——地温(摄氏度)
vsel,s,,,2,,,1
nslv,s,1
ic,all,temp,8

asel,s,,,1,2,1
asel,a,,,4,6,1
sfa,all,,conv,hair,%qiwen%        !施加空气对流边界
allsel
sfa,10,,conv,hwater,%qiwen%        !施加水对流边界

allsel

*do,i,1,day,1
time,i
timint,on
autots,0

kbc,0
trnopt,full
outres,all,all
SOLVE
*enddo

jiahong76

/cle
*set,day,5
*set,hour,day*24
*set,beg_temp,24
*set,air_max,28
*set,air_min,22
*set,l,15
*set,h,3.8
*set,t,0.5
*set,plank,0.8
*set,board,2

/PREP7
et,1,solid70
mp,dens,1,2400
mp,kxx,1,8.595
mp,c,1,0.948

block,,1,0.4,h,,-t
block,,1,0.4,0,,-t
block,,1,-plank,0,0,-t
block,,1,-plank,0,-t,-board

vglue,1,2
vglue,3,5
vglue,3,4
block,,1,0.4,h,,0.02
vglue,1,4
block,,1,0.4,h,-t,-t-0.02
vglue,1,4
block,1,1+0.02,0.4,h,0,-t
vglue,1,4

lsel,s,length,,t,t
lesize,all,,,5
lsel,s,length,,l,l
lesize,all,,,35*3/2
lsel,s,length,,h-0.4,h-0.4
lesize,all,,,16
lsel,s,length,,0.4,0.4
lesize,all,,,2
lsel,s,length,,plank,plank
lesize,all,,,2
lsel,s,length,,board-t,board-t
lesize,all,,,5
vmesh,1
vmesh,2
vmesh,3
vmesh,5

mp,dens,2,250
mp,kxx,2,0.837
mp,c,2,1.8
mat,2
type,1

lsel,s,length,,l,l
lesize,all,,,35*3/2
lsel,s,length,,0.02,0.02
lesize,all,,,1
lsel,s,length,,h-0.4,h-0.4
lesize,all,,,16
vmesh,8
vmesh,6
vmesh,7

asel,s,,,20,21
asel,a,,,37
cm,wood,area

allsel
asel,s,,,4
asel,a,,,8
asel,a,,,14
asel,a,,,11
asel,a,,,18
asel,a,,,25
asel,a,,,7
asel,a,,,9
asel,a,,,12
cm,conc1,area
allsel
asel,s,,,1,2
asel,a,,,6
cm,conc2,area

allsel
vsel,s,,,1,2
nslv,s,1
*get,n_num,node,,count

allsel
asel,s,loc,x,0
da,all,symm        !建立对称面
dtran

!生热
*dim,he,array,1
*cfopen,gen_hot,txt
he00=330*536*(1-exp(-0.69/24))
*vwrite,he00
(f15.5)
*do,i,1,hour
he00=330*536*(1-exp(-0.69*(i/24)**0.56))
he01=330*536*(1-exp(-0.69*((i+1)/24)**0.56))
*vwrite,he01-he00
(f15.5)
*enddo
*cfclos

!求解
/solu
antype,4,new
nropt,full
allsel
nsel,s,,,all
ic,all,temp,25   !初始温度25度
*do,i,1,hour
time,i
timint,on
*vread,he(1),gen_hot,txt,,,,,,i-1
(f25.15)
vsel,s,,,1
eslv,s
bfe,all,hgen,,he(1)


!超过48小时，要拆模
*if,i,ge,48,then
vsel,s,,,6,8
eslv,s
ekill,all
cmsel,s,conc1
cmsel,a,conc2
sfa,all,,conv,53,air_max/2+air_min/2+(air_max/2-air_min/2)*cos(15*(i-7))
*else
cmsel,s,wood
sfa,all,,conv,49.40,air_max/2+air_min/2+(air_max/2-air_min/2)*cos(15*(i-7))
cmsel,s,conc1
sfa,all,,conv,53,air_max/2+air_min/2+(air_max/2-air_min/2)*cos(15*(i-7))
*endif
allsel
trnopt,full
deltim,0.5,0.1,1
autots,on
kbc,0
outres,all,1
solve
*enddo
save
allsel


/post1
allsel
vsel,s,,,1,2
nslv,s,1
*get,n_num,node,,count   !节点数
*cfopen,temp,txt,,append !创建temp.txt文件
*do,i,1,hour             !对载荷步循环
set,i                    !调用i步
*do,ii,1,n_num           !对节点循环
*get,te,node,ii,temp     !得到节点温度
*vwrite,te
(f15.10)
*enddo
*enddo
*cfclos

*dim,tt1,array,n_num
*cfopen,t-temp,txt,,append  !创建t-temp.txt文件
*vread,tt1(1),temp,txt
(f15.10)
*do,i,1,n_num
*set,s,tt1(i)
s=s-beg_temp              !得到温差
*vwrite,s
(f15.10)
*enddo
*cfclos


*dim,tt2,array,n_num
*dim,tt3,array,n_num
*dim,tt4,array,n_num
*dim,tt5,array,n_num
*cfopen,t-temp,txt,,append
*do,i,1,hour-1
  *vread,tt2(1),temp,txt,,,,,,n_num*(i-1)
   (f15.10)
    *vread,tt3(1),temp,txt,,,,,,n_num*i
     (f15.10)
    *voper,tt4(1),tt3(1),sub,tt2(1)
   *vwrite,tt4(1)
    (f15.10)
*enddo
*cfclos
save
/post26
nsol,2,2286,temp,,nodetemp  !变量2286处温度放入变量2中
plvar,2                     !变量图
/color,pbak,off             !底色为白色
/replot
/ui,copy,save
fini

jiahong76

为什么仅仅考虑空气对流的时候
结构的温度场是均匀的，并且与大气温度场一样？

高手指点！

tonnyw

为什么不用一个小问题试一试？这么长的程序，看了就头晕。

jiahong76

不好意思，没说清楚。
第一个命令流是我的小算例；
第二个是偶整理的算例，调通的，供大家学习的。

iomega

(1) Please use correct unit first:
if you use: KJ/m2.h.deg, then the 360 day is 360*24.

(2) The standard unit :  for convective heat transfer coefficent:  W/m^2-K =  J/s.m^2.deg; thermal conductivity :W/m-K  = J/s.m.deg

(3) the key reason why you have uniform constant temperature is because you don't have heat capacity input for transient analysis in case (1).  What's your unit in case (2)?

jiahong76

斑竹的回答：
1、单位输入错误，我是以dat为单位，kxx以小时为单位，转换时应该*24对吧。
2、热传导系数与对流系数统一起来，都以KJ、m、d、deg为单位的话，计算结果应该是摄氏度，对不？是不是没有必要换算成瓦。
3、heat capacity 我不明白，（还是热焓？比热？）请教。
4、至于第二个实例，我是把资料中的内容粘贴到论坛，与大家共享的。
他的导热系数单位好像是KJ/m.h.deg

iomega

Heat capacity is 比热,it is very similar to the electrical capacity in electrical circuit.
If you apply a AC Voltage across a pure electrical resistance, there is no phase delay betwen voltage and current flow through the resistance. If the resistance has also capacity, then there will be a phase delay between voltage and current, right? Same thing for heat tranfer, voltage = temperature, current = heat flow.
So if you want to do transient analysis, heat capacity is required, while steady state analysis only thermal conductivity is required.
The unit of the here heat capacity i mean here is J/m^3-K.

You have to make all the units consistent in simulation.

jiahong76

我在明令中加入比热mp,c,1,0.96
结果似乎就比较合理了，多谢指点。


热-结构分析，偶是新手，希望和大家多交流
入门的朋友参考我的算例也可以。