请问螺旋在ansys里怎么画？

lsf262

如图，请问这种螺旋轴上的螺旋在ansys里怎么画？谢谢！！！用catia等软件导不进去


[ 本帖最后由 lsf262 于 2007-4-2 17:13 编辑 ]

lmxtom

用Apdl语言绘制

东北人在西南

原帖由 lmxtom 于 2007-3-29 21:07 发表
用Apdl语言绘制

具体些啊
菜鸟路过

whatinrain

You can try import Catia file directly into Ansys Workbench( v10 or v11), which supports the interface of CATPart, CATProduct.

lsf262

原帖由 lmxtom 于 2007-3-29 21:07 发表
用Apdl语言绘制

怎么操作呀？请指点！！！

lmxtom

首先产生扫描中心螺线，注意变换坐标，然后产生断面矩型，沿螺线扫描即可！

lsf262

我是个新手，请帮个忙，如1楼图所示，轴直径50mm，螺距118mm，叶片厚2mm，共5圈，螺旋外径118mm，能把命令贴出来吗？或把做好的ANSYS文件发一下，拜托了，我的e-mail：lsf262@163.com

lmxtom

以前做的题目，将建模部分给你作个思路。由于以前全部采用参数化建模，因此里边有许多不必要的参数和部分操作（对你的模型而言），慢慢看！若向看参数含义，请自行调整.其实catia proe、ug等模型完全可以导入ansys，只是可能会有局部的小问题，需要修正而已，多研究一下，问题不大！

!*************************************************
!****        环境  Ansys 8.1                 *****
!****        Copy Right(2004.6) by Li        *****
!*************************************************

/prep7                   !开启前处理模块
!/units,user               !单位制设定(m, Kg, s, °C).
*AFUN,DEG                !转换角度单位为度

!*************************************************
!************基本参数定义             ************
!*************************************************

Pi=3.1415926             !圆周率

radius=62.5                !半径2
WireDia=11.5               !线径
TotalCoil=5.5            !总圈数
n=3.9                    !有效圈数
height=354               !中心线高度

CenterDotNum=200         !中心线关键点数
StartAngle=270           !起始角
DotDensity=0.05          !关键点密度

SpringType=3             !弹簧类型 0-"C"型 1-"S"型 2-"sin"型 3-Cylinder型 4-"L"型

CenterCur=0.001          !中心线曲率   **注:小于0.005,否则单元变形过大,不能自动划分网格
Amplitude=10             !中心线振幅

SD=0.5                   !下段所占比率0.2~0.7
TOPCenterCur=0.001       !上段中心线曲率
DownCenterCur=0.001      !下段中心线曲率
PAOa=0.0008


  
EndCloseFlag=1           !上端部闭合否 0-否 1-是
EndCloseSmallFlag=1      !上端部缩小否 0-否 1-是

EndCloseRadius=45        !上端部闭合圈半径
EndCloseSpace=10         !上端部闭合间隙

StartCloseFlag=1         !下端部闭合否 0-否 1-是
StartCloseSmallFlag=1    !下端部缩小否 0-否 1-是

StartCloseRadius=49      !下端部闭合圈半径
StartCloseSpace=10       !下端部闭合间隙

StartDotNum=500000       !中心线关键点起始编号

IntAngle=0               !倾斜角度  

BottomAreaElementSize=1!下端面单元尺寸
WireElementSize=10      !簧丝单元尺寸

DBaseRI=30               !下底座中心圆柱半径
DBaseHeight=20           !下底座中心圆柱高度
DBaseOffset =-15         !下底座偏移位置
DBaseRO=80               !下底座半径
DBaseElementSize=8       !下底座单元尺寸


UBaseRI=24               !上底座中心圆柱半径
UBaseHeight=20           !上底座中心圆柱高度
UBaseOffset =-15         !上底座偏移位置
UBaseRO=80               !上底座半径
UBaseElementSize=8       !上底座单元尺寸



PistonRodLength=190      !减震器活塞杆长度
PistonRodDia=20          !减震器活塞杆直径
PistonCyLength=250       !减震器筒长度
PistonCyDia=40           !减震器筒直径


!*************************************************
!************材料及基本参数定义       ************
!*************************************************



!*************************************************
!****        初始计算关键点各段分布          *****
!*************************************************

EndBetweenAngle=(TotalCoil-n)/2*360      !上端部无效圈角度
StartBetweenAngle=(TotalCoil-n)/2*360    !下端部无效圈角度                        

StartBetweeNum=NINT(StartBetweenAngle*DotDensity)  !下端部过渡部分关键点数
KPNum=NINT(n*360*DotDensity)                       !螺旋线关键点数
EndBetweeNum=NINT(EndBetweenAngle*DotDensity)      !上端部过渡部分关键点数

!*************************************************
!****        旋转并激活工作坐标系            *****
!*************************************************

EndY=((4*Paoa*Paoa*height*height+1)**0.5-1)/2/Paoa
EndX=(EndY/Paoa)**0.5
Enda=atan(Endy/Endx)

csys,4

*IF,SpringType,EQ,4,THEN
   wpro,,,90-Enda+IntAngle
   k,StartDotNum-1,(EndY/tan(Enda-IntAngle))-EndX,0,0
*ElseIF,SpringType,NE,4
   wpro,,,IntAngle
   k,StartDotNum-1,Height*tan(IntAngle),0,0
*ENDIF
!*************************************************
!****        生成中心线关键点                *****
!*************************************************

*IF,SpringType,EQ,3,THEN                        !圆柱螺旋
   *DO,i,StartDotNum,StartDotNum+CenterDotNum-1
      k,i,0,0,(i-StartDotNum)*Height/(CenterDotNum-1)           
   *ENDDO
*ENDIF

!*************************************************
!****        生成中心线,X向正弦规律         ******
!*************************************************

FLST,3,CenterDotNum,3  
*DO,i,StartDotNum,StartDotNum+CenterDotNum-1
   FITEM,3,i  
*ENDDO
BSPLIN, ,P51X

!*************************************************
!****        移动工作坐标系到中心线起始点    *****
!****        垂直于中心线                    *****
!*************************************************

LWPL,-1,1,0  

!*************************************************
!****        闭合下端部                       ******
!*************************************************

*if,StartCloseFlag,NE,0,then

  *if,StartCloseSmallFlag,EQ,0,then
    StartCloseRadius=Radius
  *endif
  
  closedHeight=WireDia+StartCloseSpace
  pPitch=(Height-closedHeight*2)/n
  PEXP=(pPitch/closedHeight*(totalCoil-n)/2)

  *do,i,1,StartBetweeNum
    LWPL,-1,1,(i/StartBetweeNum)**(PEXP)*closedHeight/height
    k,i,(StartCloseRadius+(i/StartBetweeNum)*(Radius-StartCloseRadius))*cos(StartAngle+StartBetweenAngle*i/StartBetweeNum),(StartCloseRadius+(i/StartBetweeNum)*(Radius-StartCloseRadius))*sin(StartAngle+StartBetweenAngle*i/StartBetweeNum),0
  *enddo

*ELSEIF,StartCloseFlag,EQ,0
  StartBetweeNum=0
*endif

!*************************************************
!****        生成螺旋线关键点               ******
!*************************************************

*DO,i,1,KPNum
  LWPL,-1,1,closedHeight/height+i*((Height-closedHeight*2)/KPNum)/Height
  k,StartBetweeNum+i,radius*cos((n*360)*i/KPNum+StartAngle+StartBetweenAngle),radius*sin((n*360)*i/KPNum+StartAngle+StartBetweenAngle)
*ENDDO

!*************************************************
!****        闭合上端部                     ******
!*************************************************

*if,EndCloseFlag,NE,0,then

   *if,EndCloseSmallFlag,EQ,0,then
      EndCloseRadius=Radius
   *endif  

   PEXP=(pPitch/closedHeight*(totalCoil-n)/2)

   *do,i,1,EndBetweeNum
       LWPL,-1,1,((Height-ClosedHeight)+((i-EndBetweeNum)/(EndBetweeNum))**(PEXP)*closedHeight+closedHeight)/Height
       k,StartBetweeNum+KPNum+i,(Radius-i/EndBetweeNum*(Radius-EndCloseRadius))*cos(n*360+StartAngle+StartBetweenAngle+EndBetweenAngle*i/EndBetweeNum),(Radius-i/EndBetweeNum*(Radius-EndCloseRadius))*sin(n*360+StartAngle+StartBetweenAngle+EndBetweenAngle*i/EndBetweeNum)
   *enddo

*ELSEIF,EndCloseFlag,EQ,0
   EndBetweeNum=0
*endif


!*************************************************
!****        生成螺旋线                     ******
!*************************************************

FLST,3,StartCloseNum+StartBetweeNum+KPNum+EndBetweeNum+EndCloseNum,3
*do,i,1,StartBetweeNum+KPNum+EndBetweeNum  
   FITEM,3,i   
*enddo
BSPLIN, ,P51X

!*************************************************
!****        移动工作平面到螺旋线起始点     ******
!****        并垂直于螺旋线                 ******
!*************************************************

LWPL,-1,2,0

!*************************************************
!****        生成簧丝端面       ******
!*************************************************

rectng,-15,15,-5,5


!*************************************************
!****        扫描生成簧丝实体模型           ******
!*************************************************

VDRAG,       1, , , , , ,2  

WPCSYS,-1,0
CYL4,0,0,radius, , , ,height  

/VIEW,1,,-1

[ 本帖最后由 lmxtom 于 2007-4-2 12:37 编辑 ]

lsf262

谢谢，但我是个新手，看不懂，能帮我改一下吗？轴的参数见CAD图，螺旋从图中虚线位置开始，向箭头方向延伸5个螺距（5圈）

yangjungang2004

我随便写了一段
/prep7
R=25
N=5
h0=118
H=N*h0
*DO,i,0,100,1
t=0+i/100
xx=R*cos(t*N*360)
yy=R*sin(t*N*360)
zz=H*t
K,i+1,xx,yy,zz
*ENDDO

*DO,i,1,94,5
BSPLIN,i,i+1,i+2,i+3,i+4,i+5
*ENDDO
BSPLIN,96,97,98,99,100,101

R1=54
*DO,i,0,100,1
t=0+i/100
xx=R1*cos(t*N*360)
yy=R1*sin(t*N*360)
zz=H*t
K,102+i,xx,yy,zz
*ENDDO

*DO,i,102,196,5
BSPLIN,i,i+1,i+2,i+3,i+4,i+5
*ENDDO
BSPLIN,197,198,199,200,201,202

*DO,i,1,20,1
ASKIN,i,i+20
*ENDDO

CYL4,0,0,r, , , ,h

lsf262

不好用呀，请指点！

lubin

谢谢了
是好东西

sy_kbice

请问lmxtom一个问题，你那个螺旋体是用矩形截面沿螺旋线扫描得到的吧？看你的命令流里有个vdrag命令。有一点不清楚能给解释一下吗？就是你是怎么得到一整条螺旋线的？为什么螺旋拉伸体能是一个整体？我也做过螺旋体的设计，可拉伸出来的螺旋体是一段一段的，不便于网格划分。能介绍一下你的设计方法吗？

sy_kbice

请问lmxtom一个问题，你那个螺旋体是用矩形截面沿螺旋线扫描得到的吧？看你的命令流里有个vdrag命令。有一点不清楚能给解释一下吗？就是你是怎么得到一整条螺旋线的？为什么螺旋拉伸体能是一个整体？我也做过螺旋体的设计，可拉伸出来的螺旋体是一段一段的，不便于网格划分。能介绍一下你的设计方法吗？

yangjungang2004

原帖由 lsf262 于 2007-4-14 09:30 发表
不好用呀，请指点！

上次写的太匆忙  这次改了一下 完全照你的要求：轴直径50mm，螺距118mm，叶片厚2mm，共5圈，螺旋外径118mm
命令流：
/prep7
R=25          !轴半径
N=5           !螺旋圈数
h0=118        !螺距
H=N*h0        !螺旋总高度
R1=54         !螺旋外径(半径)

PI=ACOS(-1)
num=2*PI*N/100
zz=0
t=0
*DO,i,0,100,1
t=t+num
xx=R*cos(t)
yy=R*sin(t)
zz=i*H/100
K,i+1,xx,yy,zz
*ENDDO

*DO,i,1,94,5
BSPLIN,i,i+1,i+2,i+3,i+4,i+5
*ENDDO
BSPLIN,96,97,98,99,100,101

zz=0
t=0
*DO,i,0,100,1
t=t+num
xx=R1*cos(t)
yy=R1*sin(t)
zz=i*H/100
K,102+i,xx,yy,zz
*ENDDO

*DO,i,102,196,5
BSPLIN,i,i+1,i+2,i+3,i+4,i+5
*ENDDO
BSPLIN,197,198,199,200,201,202

*DO,i,1,20,1
ASKIN,i,i+20
*ENDDO

CYL4,0,0,r, , , ,h

peirenfeng

用CATIA转化为V4版本格式也就是model格式应该可以顺利导入，前提当然要求你用的CATIA是V4以上的版本。

prolee

我随便画了一段
单元已经分好

[ 本帖最后由 prolee 于 2007-4-19 21:57 编辑 ]

jsp613

请问只能用命令流的方式画螺旋吗？可以直接建模吗？初次使用，请多指教，能否在命令流后面注释阿

jsp613

你怎么画出来的啊

yangjungang2004

原帖由 jsp613 于 2007-5-10 21:33 发表
请问只能用命令流的方式画螺旋吗？可以直接建模吗？初次使用，请多指教，能否在命令流后面注释阿

ansys没有现成的螺旋可用阿 只能先建点 再建螺旋线