几个电磁场的例子有循环，界面设计，优化我的毕业设计

lijiliang

简单的界面设计
可以进行结果的处理
*create,shezhi,mac
/PREP7
N=50
multipro,'start',6
*cset,1,3,Iinit,inital of I,0
*cset,4,6,Ifin,final of I,4
*cset,7,9,Iinc,inc of I,0.5
*cset,10,12,Xinit,inital of X,0
*cset,13,15,Xfin,final of X,0.00015
*cset,16,18,Xinc,inc of X,0.00005
*cset,61,62,'chu shi hua ','dian liu bian hua fan wei'
*cset,63,64,'wei yi bian hua fan wei'
multipro,'end'
*DIM,F,ARRAY,(Xfin-Xinit)/Xinc+1,(Ifin-Iinit)/Iinc+1
C=1
D=1
finish
*end

*create,huanjing,mac,
!/BACH,LIST
/TITLE,2DLJL
/FILNAME,2DLJL,1
KEYW,MAGNON,1
/prep7
ET,1,PLANE13
EMUNIT,MKS
KEYOPT,1,3,1
MP,MURX,1,1
MP,MURX,2,1
MP,MURX,3,1.0997785406
MP,MGYY,3,8.9e+5
TB,BH,4,,40
TBPT,,159.2,0.2402
,,318.3,0.8654
,,477.5,1.1106
,,636.6,1.2458
,,795.8,1.331
,,1591.5,1.5
,,3183.1,1.6
,,4774.6,1.683
,,6366.2,1.741
,,7957.7,1.78
,,15915.5,1.905
,,31831,2.025
,,47746.5,2.085
,,63662,2.13
,,79577.5,2.165
,,159155,2.28
,,318310,2.485
,,397887,2.585
FINISH
*end

*creat,qiujie,mac
*DO,X,Xinit,Xfin,Xinc
/PREP7

/PNUM,AREA,1
RECTNG,0,0.0019,0.0153,0.0243
RECTNG,0.002,0.003,0.0153,0.0243
RECTNG,0.003,0.0038,0.0153,0.0193
RECTNG,0.003,0.0038,0.0193,0.0243
RECTNG,0.0038,0.00525,0.0153,0.0163
RECTNG,0.0038,0.00525,0.0163,0.0233
RECTNG,0.0038,0.005,0.0233,0.0243
RECTNG,0.00525,0.006,0.0223,0.0233
ASEL,S,AREA,,ALL
ARSYM,Y,ALL

RECTNG,0,0.0019,-0.015-X,0.015-X
RECTNG,0.002,0.003,-0.015-X,0.015-X
RECTNG,0.003,0.00525,-0.014-X,0.014-X
RECTNG,0.0038,0.00525,0.0141-X,0.015-X
RECTNG,0.0038,0.00525,-0.015-X,-0.0141-X

RECTNG,0,0.01,-0.05,0.05
AOVLAP,ALL
AGLUE,ALL
AADD,19,35
AADD,24,29,31
AADD,25,36
AADD,27,32,34
AADD,28,37
/REPLOT

ASEL,S,AREA,,30
ASEL,A,AREA,,33
AATT,2,1,1,0
ASEL,S,AREA,,20,21
ASEL,A,AREA,,23
ASEL,A,AREA,,26
AATT,3,1,1,0
ASEL,S,AREA,,1,6
ASEL,A,AREA,,9
ASEL,A,AREA,,17
AATT,4,1,1,0
/PNUM,MAT,1
ALLSEL,ALL
SMRTSIZE,2  
MSHAPE,0,2D
MSHKEY,0
AMESH,ALL
ASEL,S,AREA,,2
ESLA,S
CM,ARM,ELEM
FMAGBC,'ARM'
FINISH

/SOLU
ALLSEL,ALL
NSEL,EXT
D,ALL,AZ,0
FINISH

*DO,I,Iinit,Ifin,Iinc

/SOLU
ASEL,S,AREA,,30
ESLA,S
BFE,ALL,JS,,,,-N*I/(0.004*0.0008)
ASEL,S,AREA,,33
ESLA,S
BFE,ALL,JS,,,,N*I/(0.004*0.0008)
ALLSEL,ALL
SOLVE   
FINISH  
/POST1  
ETABLE,FMAGY,FMAG,Y
SSUM
*GET,FXL,SSUM,,ITEM,FMAGY
F(C,D)=FXL
D=D+1
FINISH
*ENDDO

D=1
I=0
/PREP7
CMDELE,ARM
ASEL,ALL
APLOT
ESLV
ACLEAR,ALL
ASEL,ALL
ADELE,ALL
LSEL,ALL
LDELE,ALL
KSEL,ALL
KDELE,ALL
C=C+1
FINISH
*ENDDO
*end

*creat,plotif,mac
*ask,xweiyi,x fang xiang pian yi,0
xx=(xweiyi-Xinit)/Xinc+1
*dim,fi,array,(Ifin-Iinit)/Iinc+1,(Xfin-Xinit)/Xinc+1
n=1
m=1
*DO,X,Xinit,Xfin,Xinc
*DO,I,Iinit,Ifin,Iinc
fi(n,m)=F(m,n)
n=n+1
*ENDDO
n=1
m=m+1
*enddo
*dim,ii,array,(Ifin-Iinit)/Iinc+1,1
a=1
*DO,I,Iinit,Ifin,Iinc
ii(a,1)=I
a=a+1
*ENDDO
*vplot,ii(1,1),fi(1,xx)
fifin=fi((Ifin-Iinit)/Iinc+1,xx)
fiinit=fi(1,xx)
kii=(fifin-fiinit)/(ii((Ifin-Iinit)/Iinc+1,1)-ii(1,1))
*msg,ui,xweiyi,kii
wei yi wei %g shi dian liu gang du wei %g
*end

*creat,plotxf,mac
*ask,ikongzhi,i kong zhi dian liu,0
i1=(ikongzhi-Iinit)/Iinc+1
*dim,xx,array,(Xfin-Xinit)/Xinc+1,1
a=1
*DO,X,Xinit,Xfin,Xinc
xx(a,1)=X
a=a+1
*enddo
*vplot,xx(1,1),F(1,i1)
kxx=(F((Xfin-Xinit)/Xinc+1,i1)-F(1,i1))/(xx((Xfin-Xinit)/Xinc+1,1)-xx(1,1))
*msg,ui,ikongzhi,kxx
kong zhi dian liu wei %g shi wei yi gang du wei %g
*END

*creat,baocun,mac
*cfopen,2dshuju,txt
*do,k,1,(Ifin-Iinit)/Iinc+1,1
*vwrite,SEQU,F(1,K)
(F3.0,'  ',F8.4)
*enddo
*cfclos
*end

*abbr,YHSZ,shezhi
*abbr,CJHJ,huanjing
*abbr,SOLV,qiujie
*abbr,plotki,plotif
*abbr,plotkx,plotxf
*abbr,SAVE,baocun

2维的一个优化设计
比较简单，没啥实际意义
我用来连手的
/TITLE,2DLJL
/FILNAME,2DLJL,1
KEYW,MAGNON

e=0.8e-3
/PREP7
a=0.004
N=50
I=2
f=2.176e-8/a/e
c=(f+e)/2
b=(f-e)/2

ET,1,PLANE13
EMUNIT,MKS
KEYOPT,1,3,1
MP,MURX,1,1
MP,MURX,2,1
MP,MURX,3,1.0997785406
MP,MGYY,3,8.9e+5
TB,BH,4,,40
TBPT,,159.2,0.2402
,,318.3,0.8654
,,477.5,1.1106
,,636.6,1.2458
,,795.8,1.331
,,1591.5,1.5
,,3183.1,1.6
,,4774.6,1.683
,,6366.2,1.741
,,7957.7,1.78
,,15915.5,1.905
,,31831,2.025
,,47746.5,2.085
,,63662,2.13
,,79577.5,2.165
,,159155,2.28
,,318310,2.485
,,397887,2.585
FINISH


/PREP7

/PNUM,AREA,1
RECTNG,0,0.0019,0.0153,0.0243
RECTNG,0.002,b,0.0153,0.0243
RECTNG,b,c,0.0153,0.0153+a
RECTNG,b,c,0.0153+a,0.0243
RECTNG,c,0.00525,0.0153,0.0163
RECTNG,c,0.00525,0.0163,0.0233
RECTNG,c,0.005,0.0233,0.0243
RECTNG,0.00525,0.006,0.0223,0.0233
ASEL,S,AREA,,ALL
ARSYM,Y,ALL

RECTNG,0,0.0019,-0.015,0.015
RECTNG,0.002,b,-0.015,0.015
RECTNG,b,0.00525,-0.014,0.014
RECTNG,c,0.00525,0.0141,0.015
RECTNG,c,0.00525,-0.015,-0.0141

RECTNG,0,0.01,-0.05,0.05
AOVLAP,ALL
AGLUE,ALL
/REPLOT

asel,all
ASEL,S,AREA,,30
ASEL,A,AREA,,33
AATT,2,1,1,0
asel,all
ASEL,S,AREA,,20,21
ASEL,A,AREA,,23
ASEL,A,AREA,,26
AATT,3,1,1,0
asel,all
asel,u,,,30,33,3
asel,u,,,20,21
asel,u,,,23,26,3
asel,u,,,38
AATT,4,1,1,0
/PNUM,MAT,1
ALLSEL,ALL
SMRTSIZE,2
MSHAPE,0,2D
MSHKEY,0
AMESH,ALL
ASEL,S,AREA,,19,35,16
ESLA,S
CM,ARM,ELEM
FMAGBC,'ARM'
FINISH

/SOLU
ALLSEL,ALL
NSEL,EXT
D,ALL,AZ,0
FINISH

/SOLU
ASEL,S,AREA,,30
ESLA,S
BFE,ALL,JS,,,,-N*I/(a*e)
ASEL,S,AREA,,33
ESLA,S
BFE,ALL,JS,,,,N*I/(a*e)
ALLSEL,ALL
SOLVE   
FINISH  

/POST1  
ETABLE,FMAGY,FMAG,Y
SSUM
*GET,FXL,SSUM,,ITEM,FMAGY
FXLA=10-FXL
FINISH
以上保存为。mac

优化文件
finish
/filname,yhopt
/input,'youhua','mac',,,0
/opt
opclr
opanl,'youhua','mac'
opvar,e,dv,0.0006,0.001
opvar,FXLA,obj
opdata,,,
oploop,prep,proc,all
opkeep,on
optype,rand
oprand,30,5
opexe
optype,sweep
opsweep,best,10
opexe

/filname,yhopt
/input,'youhua','mac',,,0
/opt
opclr
opanl,'youhua','mac'
opvar,e,dv,0.00075,0.00085
opvar,FXLA,obj
opdata,,,
oploop,prep,proc,all
opkeep,on
optype,rand
oprand,30,5
opexe
optype,sweep
opsweep,best,10
opexe
optype,sweep
opsweep,best,10
opexe
opvar,e,dv,0.0008,0.00085
optype,sweep
opsweep,best,10
opexe
opvar,e,dv,0.0008,0.00082
optype,sweep
opsweep,best,10
opexe
optype,first
opfrst,10,100,0.2
opexe

/filname,yhopt
/input,'youhua','mac',,,0
/opt
opclr
opanl,'youhua','mac'
opvar,e,dv,0.0008,0.00082
opvar,FXLA,obj
opdata,,,
oploop,prep,proc,all
opkeep,on
optype,rand
oprand,30,5
opexe
optype,first
opfrst,10,100,0.2
opexe
opvar,e,dv,0.0008,0.00081
optype,sweep
opsweep,best,10
opexe
opvar,e,dv,0.00081,0.00082
optype,sweep
opsweep,best,10
opexe

gqjneu

干嘛用的？

moon_night

把程序读一遍就大概知道了
计算电磁轴承电流刚度位移刚度

JCHLI2000

楼主真是高手呀，佩服！

lb6384

寻求高手帮作电磁场分析。
联系：qq305480462
liubeny@tom.com