关于ANSYS help中P方法求静电力的问题。

ywzb

/title, Comb Drive Example
/filname,comb,1
/pmeth,on,1
/prep7
! dimensions (microns) / parameters
wf=2                   ! Fixed  finger width
wm=2                   ! Moving finger width
gg=2                   ! Gap
tt=40                  ! Moving length
t1=4                   ! Fixed finger backing
t2=tt                  ! Moving finger length
hh=10                  ! Height
dt=tt/2
V0=10
xx=(2*tt-dt)*2.75
y1=(wm/2)+gg
y2=(wm/2)+gg+wf
x1=tt+t1
! Create Model
cyl4,0,0,xx,0,,360,1
block,-tt,0,y1,y2,0,1
block,(-tt-t1),-tt,-y2,y2,0,1
block,-tt,0,-y1,-y2,0,1
block,-dt,(tt-dt),(-wm/2),(wm/2),0,1
block,(-dt-(gg/2)),(tt-dt+(gg/2)),((-wm/2)-(gg/2)),(wm/2)+(gg/2),0,1
dx=wm*1.1
dy=dx
block,-x1-dx,tt-dt+dx,-y2-dy,y2+dy,0,1
vovlap,all
/com  ---------------------------------------
/comVolumeComponent
/com  ---------------------------------------
/com  2,8,9   Fixed Finger
/com   5      Moving Finger
/com   11     Air Layer around Moving Finger
/com   12     Air Layer around the Comb Drive
/com   10     Boundary
/com  ---------------------------------------
! 2D mesh
et,11,200,7              ! Use high order tri mesh element
esize,gg/2
mshape,1                  ! Force a traingle mesh
amesh,52                 ! Mesh air layer around moving finger
esize,gg
amesh,54                 ! Mesh air layer around comb drive
esize,(y2+dy)*5
amesh,50                 ! Mesh boundary
! 3D mesh
et,1,128
emunit,epzro,8.854e-6    ! Free space permittivity (uMKSV units)
mp,perx,1,1              ! Set relative permittivity to 1
mat,1                    ! 指定单元的材料属性
lsel,s,loc,z,0.5
lesize,all,,,1           ! Set element size in z-direction to 1
lsel,all
type,1
vsel,s,volu,,10,12,1
vsweep,all               ! Create wedge volume elements from tri mesh
vsel,all
vsel,s,volu,,10          ! Plot model
eslv,s                   ! 选择与所选体相关的单元 Selects elements associated with the selected volumes
eplot                    ! 查看所有单元
allsel
asel,s,loc,z,1           ! Select original areas
aclear,all               ! 删除所选面的节点和面单元
etdele,11                ! Remove meshing elements
asel,all
csys,1
nsel,s,loc,x,xx
d,all,VOLT,0             ! Apply volt=0 at outer boundary
nsel,all
csys,0
vsel,s,volu,,5
cm,MFINGER,volu          ! 定义组元，将几何元素分组形成组元
asel,s,ext
nsla,s,1                 ! Selects those nodes associated with the selected areas
d,all,VOLT,0             ! Apply a zero potential on the moving finger
sf,all,mxwf              ! Specifies surface loads on nodes.节点上施加表面载荷
vsel,s,volu,,2
vsel,a,volu,,8,9,1
cm,FFINGER,volu
asel,s,ext
nsla,s,1
d,all,VOLT,V0            ! Apply 10 Volts on the fixed finger
allsel
! p-convergence control
pemopts,5.0,dual          ! Select Dual Method with tolerance of 5%
pconv,2,efor,x           ! Base convergence on Maxwell forces with tolerance of 2%
/gst,on
save                     
finish
/solu
eqslv,iccg               ! Set ICCG solver
solve                 
finish
/post1
set,last                 ! Set the last data step
vsel,s,volu,,11,12
eslv,s
pplot                    ! Plot the p-levels around the fingers
esel,all
plconv,all               ! Plot the convergence curve
etable,fx,fmag,x
etable,fy,fmag,y
etable,fz,fmag,z
ssum
*get,fx,ssum,,item,fx    ! Get summed forces
*get,fy,ssum,,item,fy
*get,fz,ssum,,item,fz
/com,Comb Drive Force
*stat,fx
finish

这个是ANSYS help中的关于P方法求梳齿之间的静电力的例子。
我的问题是：（红色标注）
1.为什么要进行2维的网格划分，建模的时候建的空气域也是3D，这里划分的目的是什么....
2.3D划分网络时，为什么删除一些面的节点和面单元。

刚学ANSYS，实在很菜，望高人指点一下，十分感激啊！！！

perch88

大概看了一下，像是用来辅助建模的，做完了不需要就删除了

ywzb

十分感谢回答我的问题，那留在那对计算结果有影响吗？

perch88

当然没有影响，只要材料一样，分成几块都没关系