以下是命令流
FINISH
/CLEAR,START
/PREP7
h=20 !桩长
d1=2.0 !桩内径
d2=2.5 !桩外径
ex=2.0e10 !桩的弹性模量
ET,1,PLANE42
ET,2,SOLID45
!桩的材料
MP,EX,1,ex
MP,PRXY,1,0.3
MP,DENS,1,2600
!土的材料
MP,EX,2,2.5E8
MP,PRXY,2,0.4
MP,DENS,2,2000
TB,DP,2
TBDATA,1,19,32,0
!************建立1/4桩土模型 **********
CYLIND,d1/2,d2/2,0,h,0,360
CYLIND,d2/2,d2/2+10,0,h,0,360
WPROTA,0,90,0
VSBW,ALL
WPROTA,0,0,90
VSBW,ALL
VSEL,S,LOC,X,-30,0
VSEL,A,LOC,Y,-30,0
VDELE,ALL,,,1
ALLSEL
WPSTYL,,,,,,,,0
!***************划分网格*************
AATT, , ,1, ,
LSEL,S,,,16,29,13
LSEL,A,,,9,36,27
LESIZE,ALL,,,10,
LSEL,A,,,48,64,16
LESIZE,ALL,,,10,0.1
LSEL,S,,,44,56,12
LESIZE,ALL,,,3,
ALLSEL
MSHAPE,0,2D
MSHKEY,1
ASEL,S,,,38,56,18
AMESH,ALL
LSEL,S,LOC,Z,1,h-1
LESIZE,ALL,,,40
ALLSEL
EXTOPT,ACLEAR,1 !生成体网格后删除面网格
VATT,1,,2,
VSWEEP,8
VATT,2,,2,
VSWEEP,12
!***********定义接触单元************
ET,3,170 !刚性目标面的单元类型
ET,4,173 !柔性接触面的单元类型
KEYOPT,4,9,0
KEYOPT,4,12,2
R,1,d2/2
MP,MU,2,0.2 !库仑摩擦系数为0.2
ASEL,S,,,36
CM,target,area
TYPE,3
REAL,1
NSLA,S,1
ESURF,ALL
ALLSEL
ASEL,S,,,55
CM,contact,area
TYPE,4
NSLA,S,1
ESURF,ALL
ALLSEL
!**********加载与求解************
/SOLU
ACEL,0,0,9.8
ASEL,S,LOC,X,0
DA,ALL,SYMM
ASEL,S,LOC,Y,0
DA,ALL,SYMM
ASEL,S,LOC,Z,0
DA,ALL,ALL
CSYS,1
ASEL,S,LOC,X,d2/2+10
DA,ALL,ALL
CSYS,0
NSEL,S,LOC,Y,0
NSEL,R,LOC,X,d2/2
NSEL,R,LOC,Z,h
F,ALL,FX,-600000
ALLSEL
ANTYPE,STATIC
NEQIT,30
NROPT,FULL,,OFF
NLGEOM,ON
AUTOTS,ON
CNVTOL,F, ,0.05,2, ,
NSUBST,200,1000,10
LNSRCH,ON
PRED,ON
OUTPR,ALL,ALL
OUTRES,ALL,ALL
ALLSEL
SOLVE
FINISH |