ansys隧道洞室开挖塑性区分析

tjwxx

大家好！我在用ansys做一个公路隧道洞室开挖的塑性区分析。围岩参数按照公路隧道设计规范五级围岩参数取中值，一次开挖成型 ，无支护。命令流如下：/COM, Structural                             
/TITLE, Tunnel Construct Modeling Analysis      
/FILNAM,support,1                          
!（2）建立模型
！进入前处理器
/PREP7
*afun,deg
!定义单元类型         
ET,2,PLANE42                                
KEYOPT,2,3,2           
!定义材料属性
!围岩材料
MP,EX,2,1.5E9  
MP,PRXY,2,0.4   
MP,DENS,2,1800
TB,DP,2
TBDATA,1,0.125E6,23.5,0
!挖去土体材料
MP,EX,3,1.5E9  
MP,PRXY,3,0.4   
MP,DENS,3,1800
TB,DP,3
TBDATA,1,0.125E6,23.5,0                  
!建立几何模型      
k, 1  ,-5.7,0,.000,
k, 2  ,-4.0305,4.0305,0
k, 3  ,0,5.7,.000,
LARC,1  ,3 ,2
k, 4  ,4.0305,4.0305,.000,
k, 5  ,5.7,0,.000,
LARC,3 ,5  ,4
k, 6  ,5.6582,-0.8269,.000,
k, 7  ,5.5332,-1.6454,.000,
LARC,5  ,7  ,6
k, 8  ,5.3048,-2.1047,.000,
k, 9  ,4.8788,-2.3904,.000,
LARC,7 ,9  ,8
k, 10  ,2.4733,-3.0007,.000,
k, 11  ,0,-3.2060,0
LARC,9 ,11  ,10
k, 12 ,-2.4733,-3.0007,.000,
k, 13 ,-4.8788,-2.3904,.000,
LARC,11  ,13  ,12
k, 14 ,-5.3048,-2.1047,.000,
k, 15 ,-5.5332,-1.6454,.000,
LARC,13 ,15  ,14
k, 16  ,-5.6582,-0.8269,.000,
LARC,15 ,1  ,16                                         
!细分隧道分析线模型
k,60,-70,-70                                       
k,61,-12,-70
k,62,12,-70
k,63,70,-70
k,64,70,-12
k,65,12,-12
k,66,-12,-12
k,67,-70,-12
k,68,-70,12
k,69,-12,12
k,70,12,12
k,71,70,12
k,72,70,70
k,73,12,70
k,74,-12,70
k,75,-70,70
l,60,61                                          
l,61,62
l,62,63
l,63,64
l,64,65
l,65,66
l,66,67
l,67,68
l,68,69
l,69,70
l,70,71
l,71,72
l,72,73
l,73,74
l,74,75
l,75,68
l,74,69
l,73,70
l,69,66
l,70,65
l,71,64
l,67,60
l,66,61
l,65,62
a,60,63,72,75                                 
asbl,all,all  
adele,1                                    
NUMCMP,AREA                                 
save,Tunel-geom.db

lsel,s,,,1,37,36
lsel,a,,,3,8,5
lsel,a,,,4,7,3
lsel,a,,,5,6,1
lesize,all,1
mat,3
type,2
mshkey,0                                       
mshape,0                                       
amesh,9   


lsel,s,,,9,32,1
lesize,all,,,8                              
mat,2
type,2
mshkey,0                                       
mshape,0
asel,s,,,1,8,1
asel,a,,,10
amesh,all
allsel
save,Tunel-grid,db

csys,0
nsel,s,loc,x,-70                                    
nsel,a,loc,x,70                                    
d,all,ux                                       
allsel
nsel,s,loc,y,-70                              
d,all,uy                                       
acel,,9.8

/solu
antype,static                                    
nsubst,100                                      
pred,on                                          
nropt,full                                       
nlgeom,on                                    
lnsrch,on                                      
outres,all,all                                                                     
!初始应力模拟
time,1                                                                                 
allsel
solve                                          
save,tunnel-step1,db                                ！把初始应力模拟求解结果保存
!隧道开挖与支护模拟
allsel
time,2                                           ！设定载荷步结束时间
esel,s,mat,,3                                       !开挖
ekill,all                                           ！杀死挖去土体单元                                    
esel,all
esel,s,live                                         ！选择活单元
nsle,s
nsel,inve
d,all,all,0                                          ！约束非活动节点
nsel,all
esel,all
solve                                              ！求解
save,tunnel-step2,db                               ！把开挖模拟求解结果保存

!（5）后处理
/post1
!初始应力模拟结果分析
Resume,'tunnel-step1','db'                           ！读入初始应力模拟数据
set,1,last                                         ！读入本荷载步最后一个子步
esel,s,live                                        ！选择活单元
!显示位移云图
plnsol,u,sum,                                     !绘制总位移矢量云图
plnsol,u,x                                        !绘制X方向位移云图
plnsol,u,y                                        !绘制Y方向位移云图
!显示应力云图
plnsol,s,x                                        ！绘制X方向应力云图
plnsol,s,y                                        ！绘制Y方向应力云图
plnsol,s,z                                        ！绘制Z方向应力云图
plnsol,s,1                                        ！绘制第1主应力云图
plnsol,s,2                                        ！绘制第2主应力云图
plnsol,s,3                                        ！绘制第3主应力云图
plnsol,s,eqv                                      ！绘制等效应力云图
!开挖模拟结果分析
Resume,'tunnel-step2','db'                           ！读入开挖模拟数据
set,2,last                                         ！读入第二荷载步的最后一个子步
esel,s,live
!显示位移云图
plnsol,u,sum,                                     !绘制总位移矢量云图
plnsol,u,x                                        !绘制X方向位移云图
plnsol,u,y
!显示应力云图
plnsol,s,x                                        ！绘制X方向应力云图
plnsol,s,y                                       ！绘制Y方向应力云图
plnsol,s,z
plnsol,s,1
plnsol,s,2                                        ！绘制第2主应力云图
plnsol,s,3
plnsol,s,eqv                                      ！绘制等效应力云图
plnsol,eppl,eqv                              ！看等效塑性应变

我用plnsol,eppl,eqv查看等效塑性应变，
得出塑性区见附件。



发现拱顶和隧道底部没有塑性应变，塑性区主要出现边墙部位。为什么会出现这种情况，请各位高手帮忙分析一下。非常感谢！

csgw

你这个没有考考虑初始应力场，及开挖的应力释放，既然已经杀死了单元，根据定义应该杀死单元的影响很小，为什么还要约束杀死单元的节点？

zhangzhichaohhu

请教楼主，DP模型的塑性应变应该是看什么应变啊？plastic strain里的选项那么多
多谢！

c7225237

正在学  太难了

benxingji

顶一个  

lujunfem

zhangzhichaohhu 发表于 2011-11-28 15:04
请教楼主，DP模型的塑性应变应该是看什么应变啊？plastic strain里的选项那么多
多谢！ ...

看等效塑性应变就行了