让link和solid共用节点,可以看看下面的例子
FINISH
/CLEAR,START
/FILENAME,CRBEAM
/PREP7
ET,1,LINK8
ET,2,SOLID65
R,1,28.3E-6 !箍筋截面积
R,2,113.1E-6 !架立钢筋截面积
R,3,314.1E-6 !纵筋截面积
R,4,
MP,EX,1,2.1E11 !线弹性参数
MP,PRXY,1,0.3
TB,BKIN,1,1,2,1 !钢筋塑性参数
TBDATA,,2.1E8,0.0
!定义混凝土材料
MP,EX,2,2.55E10
MP,PRXY,2,0.3
TB,KINH,2,1,8
TBTEMP,0
TBPT,,0.0001,0.936E6
TBPT,,0.0003,2.664E6
TBPT,,0.0006,4.896E6
TBPT,,0.0009,6.696E6
TBPT,,0.0012,8.064E6
TBPT,,0.0016,9.216E6
TBPT,,0.002,9.6E6
TBPT,,0.0033,9.6E10
TB,CONC,2,1,9, !定义砼的破坏参数
TBDATA,,0.3,0.55,1.5E6,-1
!简历几何模型
BLOCK,0,3,0,0.4,0,-0.2 !建立梁的几何模型
/VIEW,1,1,2,3
/REP,FAST
LPLOT
!划分混凝土网格
VATT,2,4,2 !设置单元属性
LSEL,S,LINE,,4,5,1
LSEL,A,LINE,,2,7,5
LESIZE,ALL,0.05
LSEL,INVE
LESIZE,ALL,0.025
LSEL,ALL
VMESH,ALL
! 建立钢筋单元
NSEL,S,LOC,X,0.125,0.175
NPLOT
/VIEW,1,1
/REPLOT
TYPE,1
MAT,1
REAL,1
!通过循环建立第一圈箍筋
*DO,I,3349,3354,1
E,I,I+1
*ENDDO
*DO,I,3355,3446,7
E,I,I+7
*ENDDO
*DO,I,3452,3447,-1
E,I+1,I
*ENDDO
*DO,I,3447,3356,-7
E,I,I-7
*ENDDO
!复制第一圈箍筋,每隔0.15m布置一圈箍筋
ESEL,S,TYPE,,1
EGEN,19,315,ALL,,,,,,,,0.15,0,0
ALLSEL,ALL
!建立纵筋单元
TYPE,1
MAT,1
REAL,3
*DO,I,3145,9130,105
E,I,I+105
*ENDDO
ESEL,S,REAL,,3
EGEN,3,-3,ALL,,,,,,,,0,0,-0.075
ALLSEL,ALL
!建立架立单元
TYPE,1
MAT,1
REAL,2
*DO,I,3237,9222,105
E,I,I+105
* ENDDO
ESEL,S,REAL,,2
EGEN,2,6,ALL,,,,,,,,0,0,0.15
ALLSEL,ALL
ESEL,S,TYPE,,1
EPLOT
/VIEW,1,1,2,3 |