- 积分
- 1
- 注册时间
- 2008-5-9
- 仿真币
-
- 最后登录
- 1970-1-1
|
1.设计参数
封头内径2000mm
封头壁厚35mm
接管外径550mm
接管壁厚15mm
接管与封头焊接内侧圆角6~10,这里取8mm
接管与封头焊接外侧圆角10~30,这里取20mm
设计内压1.5Mpa
材料特性:弹性模量E=2e11 Mpa,泊松比μ=0.3
2.几何建模
为了便于计算,取实体作为分析对象并进行适当简化,由于封头是关于中心平面对称的,为减小计算规模,取带有接管的四分之一封头进行建模。
椭圆封头及接管处的内外侧倒圆角(实际是焊角)的建立均采取自底向上的建模方式,即由关键点—>线—>面—>体;接管的建立采用自顶向下的建模方式,即体—>面—>线—>关键点。
建好的几何模型如图1所示:
3.网格划分
利用ANSYS 结构分析模块中的三维实体单元Solid45单元将实体离散。为了提高分析精度,网格划分时采用映射网格。计算模型如图2所示:
4.载荷及边界条件
位移边界条件:封头底面约束Y方向自由度;在1/4封头的对称面及1/2接管的对称面上,施加对称约束;接管顶端限制Y方向自由度。
力边界条件:封头内部表面及接管与封头内部连通处均施加面载荷。
加载后的模型如图3所示:
5 计算结果及分析
5.1 最大变形区域
由合成位移云图可以看出最大位移呈现在垂直接管剖面的封头中心线上且靠近接管与封头相贯的部分。
5.2 高应力区
计算结果显示,在接管与封头相贯区域出现两个高应力区
内侧高应力区:在相贯区内侧与封头结构对称面的交点附近呈现最大应力,从最大应力点起,沿结点周向相贯线方向应力逐渐减小;在相贯区内侧经向方向应力呈迅速衰减态势。说明接管内侧最大应力点是最高应力集中所在,可作为设计的主要控制参数。
外侧高应力区:与相贯区内侧相对应,在接管与封头相贯线外侧也存在着一个高应力区,且该区域整体应力水平低于内侧高应力区,外侧最大应力点是内侧最大应力点沿接管壁厚的对应点,沿相贯线周向应力衰减很快。
6.以上前处理及加载求解操作的APDL如下:
!***********************环境设置************************
FINISH
/ CLEAR
/ FILNAME,Oval_head
/ TITLE,FEM of connecting zone of nozzle to Oval_head
!***********************参数设定************************
!此处参数设定但没有采用,而是直接以数值的的形式写入命令流代码中,原因是采用变量
!参数后,在蒙皮操作时发生错误,而数值却不会。
Di=2000 !封头内径
tc=35 !封头壁厚
dn=550 !接管外径
t=15 !接管壁厚
r1=8 !接管与封头焊接内侧圆角
r2=20 !接管与封头焊接外侧圆角
pi=1.5e6 !内压
!***********************前处理*************************
/ PREP7
ET,1,SOLID45
MP,EX,1,2e11
MP,NUXY,1,0.3
!***********************建立模型************************
CSWPLA,11,1,0.5,1
K,1,-1000,,
K,2,1000,,
K,3,-1000-35,,
K,4,1000+35,,
L,1,2
L,3,4
LDIV,1,0.5,,2,,
LDIV,2,0.5,,2,,
L,1,3
L,5,6
LDELE,3,4,1
AL,ALL
VROTAT,1,,,,,,5,6,-90,
WPOFFS,-350,0,0
WPROTA,0,-90,0
CYLIND,225,210,300,600,0,180
VOVLAP,ALL
VDELE,3,,,1
CSYS,0
APLOT
/ PNUM,AREA,ON
AFILLT,21,32,20
AL,2,35,52
AL,1,36,53
VA,2,11,12,8,9
AFILLT,31,19,8
AL,19,49,63
AL,18,58,64
VA,13,19,21,33,36
ALLSEL
ASKIN,54,59
VSBA,7,31
!***********************划分网格*************************
LESIZE,14,,,40,,1
LESIZE,16,,,40,,1
LESIZE,27,,,5,,1
LESIZE,29,,,20,,1
ALLSEL
VSWEEP,ALL
ALLSEL
NUMMRG,ALL
NUMCMP,ALL
FINISH
!***********************加载求解*************************
/ SOLU
CSYS,0
DA,4,UY,0
ASEL,S,LOC,Z,0
ASEL,A,LOC,X,0
DA,ALL,SYMM
ASEL,S,LOC,Y,600
DA,ALL,UY
ASEL,S,,,6
ASEL,A,,,10
ASEL,A,,,13
ASEL,A,,,14
ASEL,A,,,15
ASEL,A,,,17
ASEL,A,,,23
SFA,ALL,1,PRES,1.5e6
ALLSEL
SOLVE
FINISH
!*************************结束*********************
[ 本帖最后由 tongying 于 2008-12-7 00:30 编辑 ] |
本帖子中包含更多资源
您需要 登录 才可以下载或查看,没有账号?注册
×
|