[共建]＜ANSYS命令流实例库＞敬请您的加盟

wuneng

我自己作了一个二层框架静力分析，自己觉得比较好的是可以显示四个窗口希望高手多多指点

FINI
/cle
/PREP7
ET,1,188
ET,2,63
sectype,1,beam,rect   
secdata,0.3,0.3
sectype,2,beam,rect   
SECOFFSET, USER,0, -0.2
secdata,0.3,0.5
mp,ex,1,3e10
mp,prxy,1,0.2
mp,dens,1,2500  
r,2,0.1  
K,1,0,0,0
K,2,6,0,0
K,3,6,6,0
K,4,0,6,0
KGEN,3,1,4,,,,3
*do,i,1,4
l,i,i+4 $l,i+4,i+8
*enddo
*do,j,5,7
l,j,j+1 $l,j+4,j+5
*enddo
l,5,8 $l,12,9
lsel,s,,,9,10
latt,1,,1,,1,,2
lsel,s,,,15,16,
latt,1,,1,,1,,2
lsel,s,,,3,4
latt,1,,1,,1,,1
lsel,s,,,7,8
latt,1,,1,,1,,1
lsel,s,,,11,12
latt,1,,1,,3,,2
lsel,s,,,13,14,
latt,1,,1,,3,,2
lsel,s,,,1,2
latt,1,,1,,2,,1
lsel,s,,,5,6
latt,1,,1,,4,,1
lsel,all
esize,0.5
lmesh,all
type,2
real,2
A,5,6,7,8
A,9,10,11,12
esize,0.5
Amesh,all
nummrg,all
numcmp,all
finish
/solu
DK,1,all
DK,2,all
DK,3,all
DK,4,all
ACEL,0,0,9.8
F,345,fz,-100000
F,466,fz,-100000
allsel
solve
fini
/POST1
/WIND,ALL,OFF   
/WIND,1,LTOP
/WIND,2,RTOP
/WIND,3,LBOT
/WIND,4,RBOT
GPLOT
/GTYPE,ALL,KEYP,0
/GTYPE,ALL,LINE,0
/GTYPE,ALL,AREA,0
/GTYPE,ALL,VOLU,0
/GTYPE,ALL,NODE,0
/GCMD,1,ELEM
/GCMD,2,PLDI,0  
/GCMD,3,PLNS,U,Y,0,1
/GCMD,4,PLES,S,Y,0,1

FINI
/cle
/PREP7
ET,1,188
ET,2,63
sectype,1,beam,rect   
secdata,0.3,0.3
sectype,2,beam,rect   
SECOFFSET, USER,0, -0.2
secdata,0.3,0.5
mp,ex,1,3e10
mp,prxy,1,0.2
mp,dens,1,2500  
r,2,0.1  
K,1,0,0,0
K,2,6,0,0
K,3,6,6,0
K,4,0,6,0
KGEN,3,1,4,,,,3
*do,i,1,4
l,i,i+4 $l,i+4,i+8
*enddo
*do,j,5,7
l,j,j+1 $l,j+4,j+5
*enddo
l,5,8 $l,12,9
lsel,s,,,9,10
latt,1,,1,,1,,2
lsel,s,,,15,16,
latt,1,,1,,1,,2
lsel,s,,,3,4
latt,1,,1,,1,,1
lsel,s,,,7,8
latt,1,,1,,1,,1
lsel,s,,,11,12
latt,1,,1,,3,,2
lsel,s,,,13,14,
latt,1,,1,,3,,2
lsel,s,,,1,2
latt,1,,1,,2,,1
lsel,s,,,5,6
latt,1,,1,,4,,1
lsel,all
esize,0.5
lmesh,all
type,2
real,2
A,5,6,7,8
A,9,10,11,12
esize,0.5
Amesh,all
nummrg,all
numcmp,all
finish
/solu
DK,1,all
DK,2,all
DK,3,all
DK,4,all
ACEL,0,0,9.8
F,345,fz,-100000
F,466,fz,-100000
allsel
solve
fini
/POST1
/WIND,ALL,OFF   
/WIND,1,LTOP
/WIND,2,RTOP
/WIND,3,LBOT
/WIND,4,RBOT
GPLOT
/GTYPE,ALL,KEYP,0
/GTYPE,ALL,LINE,0
/GTYPE,ALL,AREA,0
/GTYPE,ALL,VOLU,0
/GTYPE,ALL,NODE,0
/GCMD,1,ELEM
/GCMD,2,PLDI,0  
/GCMD,3,PLNS,U,Y,0,1
/GCMD,4,PLES,S,Y,0,1

图片我不会插入，大家自己运行看一下吧！

水幽寒

有关于ansys模拟徐变方面的么？各位大侠

enigma

一个接触分析的APDL命令流
给出了接触定义的一般方法

/TITLE,Analysis of a Axis Contacting a hole in a Disc   ！定义标题
/PREP7  
!*  
ET,1,SOLID185                    ！定义单元类型
!*  
MP,EX,1,2.1E5                     ！定义材料属性
MP,PRXY,1,0.3  
!*
CYL4,0,0,34,0,100,90,25             ！创建四分之一圆环
CYL4,0,0,25,0,35,90,150
VGEN, ,2, , , , ,-10, , ,1               ！移动轴
!*
LESIZE,17, , ,15, , , , ,1                ！定义线的分网尺寸
LESIZE,19, , ,15, , , , ,1  
!*
LESIZE,18, , ,2, , , , ,1  
LESIZE,20, , ,2, , , , ,1
!*  
LESIZE,22, , ,20, , , , ,1
!*   
LESIZE,5, , ,10, , , , ,1
LESIZE,7, , ,10, , , , ,1
!*  
LESIZE,6, , ,8, , , , ,1  
LESIZE,8, , ,8, , , , ,1
!*  
LESIZE,10, , ,3, , , , ,1  
!*  
VSWEEP,ALL                   ！用扫掠方式对创建的体进行网格划分
!*  
/COM, CONTACT PAIR CREATION - START
MP,MU,1,0.2                    ！定义接触摩擦系数
MAT,1   
R,3                            ！定义接触实常数
REAL,3  
ET,2,170                        ！定义接触单元类型
ET,3,174
R,3,,,0.1,0.1,,
NROPT,UNSYM
!* Generate the target surface       下面创建目标面
ASEL,S,,,4  
CM,_TARGET,AREA
TYPE,2  
NSLA,S,1
ESLN,S,0
ESURF,ALL   
!* Generate the contact surface    下面创建接触面
ASEL,S,,,9  
CM,_CONTACT,AREA         
TYPE,3  
NSLA,S,1
ESLN,S,0
ESURF,ALL  
CMDEL,_TARGET
CMDEL,_CONTACT
ALLSEL,ALL
EPLOT
FINISH  
!*
/SOLU                      进入求解器
DA,5,SYMM                 ！定义面的对称位移边条
DA,6,SYMM
DA,11,SYMM
DA,12,SYMM
DA,3,ALL,                   ！定义面的位移约束条件
!*
ANTYPE,0                    ！指定分析类型为静力分析
NLGEOM,1                    ！考虑大变形影响
AUTOTS,0
TIME,100
SOLVE                        ！求解第一载荷步
!*  
NSUBST,150,10000,10
OUTRES,ALL,ALL  
AUTOTS,1
TIME,250
NSEL,S,LOC,Z,140               ！选定轴向坐标为140的所有节点
D,ALL,UZ,40
ALLSEL,ALL  
SOLVE                         ！求解第二载荷步
!*  
/EXPAND,4,POLAR,HALF,,90       ！进行模型扩展
/REPLOT
!*  
/POST1                         ！进入同样后处理器
SET,1,LAST,1,                   ！指定查看的载荷步
PLNSOL,S,EQV,0,1               ！查看等效应力的云图
!*
SET, , ,1, ,120, ,  
ESEL,S,ENAME,,174   
EPLOT
PLNSOL,CONT,PRES,0,1         
!*
PLNS,S,EQV  
ANDATA,0.5, ,1,0,0,1,1,1              ！查看动画显示
!*
/POST26
!*  
RFORCE,2,925,F,Z, FZ_2              ！定义约束反力变量
PLVAR,2,                           ！绘制变量－时间曲线
FINISH

wangblue

我做的是个格栅夹层板的非线性分析，下面是命令流
/clear,all
/config,nres,50000
/prep7
mp,ex,1,206000
mp,prxy,1,0.3
!mp,dens,1,7.850e-9
tb,bkin,1   
tbdata,1,235,0
h=11.5
s=16.3

et,1,beam189,rect
sectype,1,beam,rect
secdata,1.22,1.22

k,1
k,2,s
k,3,s,s
k,4,0,s
k,5,s/2,s/2,h

l,1,5
l,2,5
l,3,5
l,4,5
latt,1,0,1,,,,1
lesize,all,,,5
lmesh,all
lsel,all
lgen,9,all,,,s
lgen,6,all,,,,s

et,2,shell143
r,2,0.55
sect,2,shell
secdata,0.55,1
rectng,0,s,0,s
wpoffs,,,h
rectng,0,s/2,0,s/2
rectng,0,s/2,s/2,s
rectng,s/2,s,0,s/2
rectng,s/2,s,s/2,s
asel,all
aatt,1,2,2,,2
aesize,all,s/10
amesh,all

agen,9,all,,,s
agen,6,all,,,,s
allsel,all

nummrg,all
numcmp,all

lsel,s,loc,z,0
lsel,r,loc,x,0
dl,all,,all,0

lsel,s,loc,z,0
lsel,r,loc,x,9*s
dl,all,,all,0

lsel,s,loc,z,0
lsel,r,loc,y,0
dl,all,,all,0

lsel,s,loc,z,0
lsel,r,loc,y,6*s
dl,all,,all,0

allsel,all

asel,s,loc,z,h  
sfa,all,1,pres,-1.0
/replot

/solu
antype,0
pstres,on
solve
save
finish

/solu
antype,1
bucopt,lanb,5,0
mxpand,5
/solu
solve
save
finish

/prep7
upgeom,0.01,1,1,'file','rst'
/solu
antype,0
asel,s,loc,z,h  
sfa,all,1,pres,-0.70
NLGEOM,1
stiff,on
OUTPR,BASI,ALL,
OUTRES,BASI,ALL,
solcontrol,on,,incp
RESCONTROL,DEFINE,ALL,1,1
CNVTOL,F,1000 ,0.01,2, ,
CNVTOL,M, 1000,0.01,2, ,
time,1
NSUBST,100
lswrite,1

antype,0
asel,s,loc,z,h  
sfa,all,1,pres,-1.0
NLGEOM,1
stiff,on
OUTPR,BASI,ALL,
OUTRES,BASI,ALL,
solcontrol,on,,incp
RESCONTROL,DEFINE,ALL,1,1
CNVTOL,F,1000 ,0.01,2, ,
CNVTOL,M,1000 ,0.01,2, ,
NSUBST,300
arclen,on
ARCLEN,1,12,0.0001
lswrite,2
LSSOLVE,1,2,1,

save

dengtengshu

由于水平所限,请多指教
/BATCH  
/FILNAME,lianxi2                  !定义文件名
/UNITS,SI                         !定义国际单位制
KEYW,PR_STRUC,1                   !设置计算类型
/PREP7   
ET,1,BEAM189                      !选择单元类型
MPTEMP,,,,,,,,                    !定义材料参数
MPTEMP,1,0  
MPDATA,EX,1,,2.1e11
MPDATA,PRXY,1,,0.3   
SECTYPE,   1, BEAM, HREC, , 0      !定义三个截面
SECOFFSET, CENT
SECDATA,0.04,0.06,0.003,0.003,0.003,0.003,0,0,0,0   
SECTYPE,   2, BEAM, HREC, , 0   
SECOFFSET, CENT
SECDATA,0.04,0.05,0.003,0.003,0.003,0.003,0,0,0,0
SECTYPE,   3, BEAM, HREC, , 0   
SECOFFSET, CENT
SECDATA,0.05,0.05,0.002,0.002,0.002,0.002,0,0,0,0   
/REPLOT,RESIZE  
SAVE               
K,1,,-0.6,,                !生成7个关键点
K,2,0.7,-0.6,,
K,3,0.7,-0.6,0.4,
K,4,1.5,-0.6,0.4,
K,5,1.5,-0.6,,  
K,6,2.3,-0.6,,  
K,7,3,-0.6,,
/PNUM,KP,1                 !打开关键点编号
FLST,3,7,3,ORDE,2         
FITEM,3,1   
FITEM,3,-7  
KSYMM,Y,P51X, , , ,0,0     !镜面映射7个对称点
K,15,,-0.6,1,              !定义五个方向关键点
K,16,3,-0.6,1,
K,17,0.7,-0.6,1,
K,18,1.5,-0.6,1,
K,19,2.3,-0.6,1,
LSTR,       1,       2     !生成21条线
LSTR,       2,       3  
LSTR,       3,       4
LSTR,       2,       5
LSTR,       4,       5
LSTR,       5,       6
LSTR,       6,       7
LSTR,       8,       9
LSTR,       9,       10
LSTR,       10,      11
LSTR,       9,       12
LSTR,       11,      12
LSTR,      12,      13  
LSTR,      13,      14
LSTR,       1,      8  
LSTR,       2,      9  
LSTR,       3,      10  
LSTR,       4,      11  
LSTR,       5,      12
LSTR,       6,      13
LSTR,       7,      14
/PNUM,LINE,1               !打开线编号
LPLOT                      !显示线图形
FLST,5,4,4,ORDE,4          !给纵梁分配梁单元属性
FITEM,5,1
FITEM,5,4
FITEM,5,6     
FITEM,5,-7  
CM,_Y,LINE  
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,S,_Y  
!*   
CMSEL,S,_Y1
LATT,1, ,1, ,       15, ,1   
CMSEL,S,_Y  
CMDELE,_Y   
CMDELE,_Y1  
!*  
FLST,5,4,4,ORDE,4   
FITEM,5,8
FITEM,5,11
FITEM,5,13   
FITEM,5,-14  
CM,_Y,LINE  
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,S,_Y  
!*   
CMSEL,S,_Y1
LATT,1, ,1, ,      16, ,1   
CMSEL,S,_Y                  !给横梁分配梁单元属性
CMDELE,_Y   
CMDELE,_Y1  
!*  
SAVE
CM,_Y,LINE  
LSEL, , , ,       15
CM,_Y1,LINE
CMSEL,S,_Y  
!*   
CMSEL,S,_Y1
LATT,1, ,1, ,       15, ,2   
CMSEL,S,_Y  
CMDELE,_Y   
CMDELE,_Y1  
!*  
CM,_Y,LINE  
LSEL, , , ,      16
CM,_Y1,LINE
CMSEL,S,_Y  
!*   
CMSEL,S,_Y1
LATT,1, ,1, ,       17, ,2   
CMSEL,S,_Y  
CMDELE,_Y   
CMDELE,_Y1
!*  
CM,_Y,LINE  
LSEL, , , ,      19
CM,_Y1,LINE
CMSEL,S,_Y  
!*  
CMSEL,S,_Y1
LATT,1, ,1, ,       18, ,2   
CMSEL,S,_Y  
CMDELE,_Y   
CMDELE,_Y1
!*  
CM,_Y,LINE  
LSEL, , , ,      20
CM,_Y1,LINE
CMSEL,S,_Y  
!*  
CMSEL,S,_Y1
LATT,1, ,1, ,       19, ,2   
CMSEL,S,_Y  
CMDELE,_Y   
CMDELE,_Y1
!*  
CM,_Y,LINE  
LSEL, , , ,      21
CM,_Y1,LINE
CMSEL,S,_Y  
!*  
CMSEL,S,_Y1
LATT,1, ,1, ,       16, ,2   
CMSEL,S,_Y                  !给发动机架上各梁分配梁单元属性
CMDELE,_Y   
CMDELE,_Y1
!*  
CM,_Y,LINE  
LSEL, , , ,      3
CM,_Y1,LINE
CMSEL,S,_Y  
!*   
CMSEL,S,_Y1
LATT,1, ,1, ,       15, ,3   
CMSEL,S,_Y  
CMDELE,_Y   
CMDELE,_Y1  
!*  
CM,_Y,LINE  
LSEL, , , ,      10
CM,_Y1,LINE
CMSEL,S,_Y  
!*   
CMSEL,S,_Y1
LATT,1, ,1, ,       16, ,3   
CMSEL,S,_Y  
CMDELE,_Y   
CMDELE,_Y1  
!*  
CM,_Y,LINE  
LSEL, , , ,      17
CM,_Y1,LINE
CMSEL,S,_Y  
!*  
CMSEL,S,_Y1
LATT,1, ,1, ,      17, ,3   
CMSEL,S,_Y  
CMDELE,_Y   
CMDELE,_Y1
!*  
CM,_Y,LINE  
LSEL, , , ,      18
CM,_Y1,LINE
CMSEL,S,_Y  
!*  
CMSEL,S,_Y1
LATT,1, ,1, ,      18, ,3   
CMSEL,S,_Y  
CMDELE,_Y   
CMDELE,_Y1  
!*  
SAVE
FLST,5,21,4,ORDE,2  
FITEM,5,1   
FITEM,5,-21
CM,_Y,LINE  
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y   
!*  
LESIZE,_Y1,0.5, , , , , , ,1    !控制21条线的单元尺寸
!*  
FLST,2,21,4,ORDE,2  
FITEM,2,1   
FITEM,2,-21
LMESH,P51X                      !划分线单元网格
!*
/UI,MESH,OFF                    !关闭Meshtool对话框
!*   
/SHRINK,0                       !打开单元形状开关,以检验模型截面
/ESHAPE,1.0
/EFACET,1   
/RATIO,1,1,1
/CFORMAT,32,0   
/REPLOT
!*  
/SHRINK,0                       !关闭单元形状开关            
/ESHAPE,0.0
/EFACET,1   
/RATIO,1,1,1
/CFORMAT,32,0   
/REPLOT
!*  
FINISH  
/SOL                             !进入求解器加载
FLST,2,1,3,ORDE,1   
FITEM,2,8  
!*  
/GO
DK,P51X, , , ,0,UX,UY,UZ, , , ,  !加约束
FLST,2,1,3,ORDE,1   
FITEM,2,14  
!*  
/GO
DK,P51X, , , ,0,UY,UZ, , , , ,  
FLST,2,2,3,ORDE,2   
FITEM,2,1   
FITEM,2,7   
!*  
/GO
DK,P51X, , , ,0,UZ, , , , , ,   
FLST,2,6,3,ORDE,6   
FITEM,2,3   
FITEM,2,-4
FITEM,2,6
FITEM,2,10  
FITEM,2,-11
FITEM,2,13
!*  
/GO
FK,P51X,FZ,-1000                  !加集中力   
!*  
/PSF,DEFA, ,1,0,1   
/PBF,DEFA, ,1   
/PIC,DEFA, ,1   
/PSYMB,CS,0
/PSYMB,NDIR,0   
/PSYMB,ESYS,0   
/PSYMB,LDIV,0   
/PSYMB,LDIR,0   
/PSYMB,ADIR,0   
/PSYMB,ECON,0   
/PSYMB,XNODE,0  
/PSYMB,DOT,1
/PSYMB,PCONV,   
/PSYMB,LAYR,0   
/PSYMB,FBCS,0   
!*  
/PBC,ALL,,1
/PBC,NFOR,,0
/PBC,NMOM,,0
/PBC,RFOR,,0
/PBC,RMOM,,0
/PBC,PATH,,0
/REP
!*  
LPLOT   
/STATUS,SOLU
SOLVE                                   !执行求解
FINISH  
/POST1           
SET,FIRST                               !读取第一步
!*
/AUTO,1
/REP,FAST
!*  
/SHRINK,0   
/ESHAPE,1.0
/EFACET,1   
/RATIO,1,1,1
/CFORMAT,32,0   
/REPLOT
PLDISP,1                                    !变形显示
/EFACE,1
AVPRIN,0, ,
!*  
PLNSOL,U,SUM,1,1                            !应力状态
! /EXIT,ALL

dengtengshu

本文纯系个人原创,并经ansys8.0调试成功,大家一起来杜绝抄袭!

zhangjinf

chenshi2003 你帖的那个隧洞的例子算不出结果，隧洞开挖后与开挖前是结果是一样的，怎么回事？

峰上枫

如下图所示，一吊桥。采用混凝土C30，吊杆的EA等于横梁EI的1/20m-２。试求吊桥结构的内力图。

fini
/clear
/prep7
et,1,beam3
et,2,link1
keyopt,1,6,1
mp,ex,1,3.0e10
mp,dens,1,2500
mp,prxy,1,0.13
r,1,0.18,0.3*0.6*0.6*0.6/12,0.6,
r,2,2.7e-4
k,1
k,2,60
k,3,,15
k,4,20
k,5,60,15
k,6,40
l,1,2
l,3,4
l,5,6
ldiv,1,,,60,1
ldiv,2,,,25,1
ldiv,3,,,25,1
lsel,s,,,4,63,1
latt,1,1,1
lmesh,all
lsel,s,,,64,88,1
latt,1,2,2
lmesh,all
lmesh,all
lsel,s,,,89,113,1
latt,1,2,2
lmesh,all
d,1,all
d,179,all
d,182,ux
d,182,uy
d,258,ux
d,258,uy
esel,s,,,61,120,1
sfbeam,all,1,pres,10000
cp,next,uy,59,255
cp,next,ux,59,255
cp,next,uy,119,331
cp,next,ux,119,331
allsel,all
/solu
solve
fini
/post1
etable,imom,SMISC,6
etable,jmom,SMISC,12
plls,imom,jmom,-1
etable,imom,SMISC,2
etable,jmom,SMISC,8
plls,imom,jmom,-1

ganggong

算动力简单例子
/prep7
et,1,16
et,2,21
r,1,0.375,0.1875
r,2,,,,31e-3
mp,ex,1,31.2e6
mp,prxy,1,0.3
n,1
n,2,8
e,1,2
type,2
real,2
e,2
m,2,rotx
outpr,basic,1
d,all,all
ddele,2,rotx
finish
/solu
antype,2
modopt,reduc,1,,,1
solve
/post1
*get,freq,mode,1,freq

momovivi

请教，杀死单元，活单元，死单元的作用，什么意思？

swwen82

/prep7

k,1,          !!!!生成钢结构雨棚关键点
k,2,580,5.8
k,3,1880,18.8
k,4,3180,31.8
k,5,4480,44.8
k,6,5780,57.8
k,7,,2211
k,8,,2211,6900
*do,i,1,5   
l,i,i+1
*enddo
lgen,5,1,5,1,,,1725
*do,i,9,26
l,i,i+6
*enddo
*do,i,1,6
l,i,i+8
*enddo
LDIV,24, , ,2,0
!*  
LDIV,4, , ,2,0  
l,8,33
l,7,34
et,1,8   !!!!定义材料和单元类型
R,1,1134.12, ,
et,2,188
SECTYPE,   1, BEAM, CHAN, caogang, 0
SECOFFSET, CENT
SECDATA,100,100,120,8,8,8,0,0,0,0   
SECTYPE,   2, BEAM, L, jiaogang, 0  
SECOFFSET, CENT
SECDATA,100,60,8,8,0,0,0,0,0,0  
mp,ex,1,2.06e5
mp,prxy,1,0.3
kgen,2,9,,,,500
kgen,2,15,,,,500
kgen,2,21,,,,500
lsel,s,line,,1,5,1
lsel,a,line,,51
LATT,1,1,2, ,       7, ,1  
lsel,s,line,,6,10,1
LATT,1,1,2, ,       37, ,1  
lsel,s,line,,11,15,1
LATT,1,1,2, ,       36, ,1
lsel,s,line,,16,20,1
LATT,1,1,2, ,       37, ,1
lsel,s,line,,21,25,1
lsel,a,line,,50
LATT,1,1,2, ,       8, ,1  
alls
gplot
kgen,2,2,6,2,,1000
lsel,s,loc,x,580
LATT,1,1,2, ,       38, ,1
lsel,s,loc,x,3180
LATT,1,1,2, ,      39, ,1   
lsel,a,loc,x,5780
LATT,1,1,2, ,       40, ,1
lsel,s,line,,52
lsel,a,line,,53
LATT,1,1,1, , , ,2
lsel,s,loc,x,
ldel,all
alls
lesize,all,,,1
lmesh,all
alls
eplot
alls
fini

nsel,s,loc,x,
nplot
d,all,all
/ESHAPE,0.0
nplot
nsel,s,node,,16
nsel,a,node,,20
nsel,a,node,,27
nsel,a,node,,31
nsel,a,node,,38
nsel,a,node,,42
f,all,fy,-750
alls
/solu
solve
/post1
PLDISP,2

swwen82

应力集中分析,
/prep7
k,1
k,2,10
k,3,10,10
k,4,,10
k,5,1
k,6,,1
k,7,-0.5,0.5
larc,5,6,7,1
l,5,2
l,2,3
l,3,4
l,4,6
al,all
et,1,63
r,1,1
mp,ex,1,2.06e5
mp,prxy,1,0.3
aatt,1,1,1,
wprota,,,90
wprota,,45,
asbw,all
lesize,5,,,30
lesize,6,,,30
lesize,2,,,30
lesize,3,,,10
lesize,4,,,10
lesize,7,,,10
lesize,8,,,10
amesh,all
/solu          !!!!加载及求解
f,12,fz,100
lsel,s,radius,,1
NSLL,S,1
d,all,all
alls
gplot
NUMMRG,ALL, , , ,LOW
NUMCMP,ALL
solve
/post1     !!!!!后处理
pldisp,2
/eshape,1
PLNSOL, U,Z, 0,1
PLNSOL, S,1, 0,1.0  
plnso,s,eqv,0,  

拉伸板
/prep7
k,1         !!!!!!建立模型
k,2,15
k,3,35,4
k,4,135,4
k,5,155
k,6,170
k,7,,20
k,8,15,20
k,9,35,16
k,10,135,16
k,11,155,20
k,12,170,20
k,13,,,6
*do,i,1,5
l,i,i+1
*enddo
l,6,12
*do,i,7,11
l,i,i+1
*enddo
l,1,7
l,1,13
lsel,s,loc,z,
al,all
VDRAG, 1, , , , , , 13     !!!!拉伸成体
FLST,2,3,3,ORDE,3          !!!!分割体
FITEM,2,8   
FITEM,2,15  
FITEM,2,24  
KWPAVE,P51X
wprota,,,90
vsbw,1
wpoffs,,,20
vsbw,all
wpoffs,,,100
vsbw,all
wpoffs,,,20
vsbw,all
!!!!!!!!!定义单元类型及材料特性
et,1,95   !!!采用20节点2阶金字塔单元分析
mp,ex,1,2.06e5
mp,prxy,1,0.3
VATT,       1, ,   1,       0  
lsel,s,length,,15
lesize,all,,,6
lsel,s,length,,20
lesize,all,,,8
lsel,s,length,,6
lsel,u,line,,18,32,14
lsel,u,line,,20,30,10
lesize,all,,,4
vsel,s,volu,,2,6,4
vmesh,all
lsel,s,line,,18,32,14
lsel,a,line,,20,30,10
lesize,all,,,4
lsel,s,length,,12
lesize,all,,,4
lsel,s,length,,100
lesize,all,,,50
vsel,s,volu,,3
vmesh,all
vsel,s,volu,,1,4,3
SMRT,6      !!!!!!!!!自由网格划分
SMRT,3  
MSHAPE,1,2D
MSHKEY,0
!*  
MSHAPE,1,3D
!*  
CM,_Y,VOLU  
VSEL, , , ,       1
CM,_Y1,VOLU
CHKMSH,'VOLU'   
CMSEL,S,_Y  
!*  
VMESH,_Y1   
!*  
CMDELE,_Y   
CMDELE,_Y1  
CMDELE,_Y2  
!*  
CM,_Y,VOLU  
VSEL, , , ,       4
CM,_Y1,VOLU
CHKMSH,'VOLU'   
CMSEL,S,_Y  
!*  
VMESH,_Y1   
CMDELE,_Y   
CMDELE,_Y1  
CMDELE,_Y2  
save

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!11
!!!!!!!!!加载和求解
/solu

sally333

/filname,I-beam
/tiltle,buckling
/prep7
et,1,beam189
!以下三行用于定义梁的横截面及相关参数
sectype,1,beam,I,,2
secoffset,cent
secdata,0.15,0.15,0.25,0.015,0.015,0.015,0,0,0,0
!以下三行用于定义材料模型的参数
mp,dens,1,7.85e3
mp,ex,1,2.06e11
mp,nuxy,1,0.2
!以下三行用于定义三个关键点
k,1,0,0,0
k,2,2.5,0,0
k,3,1.25,1,0
lstr,1,2
latt,,1,,1,,3,,1
lesize,1,,,10
lmesh,1
/view,1,1,1,1
/ang,1
/rep,fast
/eshape,1.0                        !显示梁单元的实际截面形状
dk,1,,,,0,all,,,,,,                !定义位移约束
fk,2,fx,-1e6                       !定义自由端的载荷
finish

!以下为特征值屈曲分析与结果显示

/solu
antype,0     !指定分析类型为静力分析
eqslv,spar   !选择稀疏矩阵直接求解器
pstress,on   !打开预应力选项
solve
finish
/solu
antype,1     !特征值屈曲分析
bucopt,lanb,6,0,0   !屈曲模态提取方法及模态提取数
mxpand,6,0,0,1,0.001,   !屈曲模态扩展数及扩展算法选项及
solve
finish

/POST1  
SET,FIRST   
PLDISP,1
SET,NEXT
PLDISP,1
SET,NEXT
PLDISP,1
PLDISP,1
SET,NEXT
PLDISP,1
SET,NEXT
PLDISP,1
SET,NEXT
SET,LIST
PLDISP,1

!非线性屈曲分析与结果评估

/config,nres,100      ! 设置分析终止条件
/prep7
tb,biso,1,1,2,       !修正材料模型
tbtemp,0
tbdata,,2.0e8,0,,,,
upgeom,0.01,1,1,'I-beam','rst',''
finish

/sol
antype,0
nlgeon,1   !打开大变形选项
outres,all,all  !输入所有子步的结果
arclen,1,0,0,   !打开弧长法
arctrm,U,0.25,2,uy  !弧长法选项设置
nsubst,200,,,1
solve
finish

/post26
nsol,2,2,U,Y,deflection   !指定位移变量
rforce,3,1,f,x,reactionf

/axlab,x,deflection
/axlab,y,reactionf
xvar,2
plvar,3
finish

dove

/PREP7
ET,1,PLANE42
ET,2,SOLID45
BLOCK,,2,,1,,1
/VIEW,1,1,1,1
WPOFF,0.5,0.5
CYL4,,,0.2,,,,1
WPOFF,1.0,0.5,0.5
WPROT,0,90
CYL4,,,0.2,,,,1
VSBV,1,2
VSBV,4,3
WPROT,0,0,90
VSBW,1
WPOFF,0,0,-0.5
VSBW,3
WPOFF,0,0,-0.5
VSBW,1
WPROT,0,0,90
KWPAVE,15
VSBW,ALL
VPLOT
/PLOPTS,DATE,0
/TRIAD,LTOP
KWPAVE,19
WPROT,0,90
VSBW,ALL
ESIZE,0.1,0
MSHKEY,1
AMESH,90,102,6
AMESH,106
WPSTYLE,,,,,,,,0
VSEL,S,LOC,X,1,2
ACCAT,58,104
ACCAT,50,89
ACCAT,57,101
ACCAT,49,93
ACCAT,64,80
ACCAT,69,88
ACCAT,68,84
ACCAT,63,75

TYPE,2
VSWEEP,ALL
VSEL,S,LOC,X,0,1
AMAP,38,14,36,38,15
AMAP,10,15,38,34,16
AMAP,42,16,34,40,13
AMAP,45,13,40,36,14
VSWEEP,ALL
SAVE

beyondboy

希望版主加分（有些贴浏览不了）
其中有几个VSBW命令的警告，但不影响分析！enjoy！
/prep7
/title,bridge
et,1,solid95
et,2,link8
mp,prxy,1,0.1667
mp,dens,1,2600
mp,ex,1,3.5e10
mp,ex,2,1.95e11
mp,dens,2,7800
mp,prxy,2,0.3
areagjx=1.4e-4
*dim,gjarea,arry,4
gjarea(1)=15*areagjx
gjarea(2)=18*areagjx
gjarea(3)=20*areagjx
gjarea(4)=22*areagjx
F=195.5e3
E=1.95e11
L=1
detL=F*L/(E*areagjx)
istrn=detL/(detL+L)
r,2,gjarea(1),istrn
r,3,gjarea(2),istrn
r,4,gjarea(3),istrn
r,5,gjarea(4),istrn
acel,,9.8
k,2,-2.45,0
k,3,-3.25,0
k,4,-6,0
k,5,-6,-0.18
k,6,-3.25,-0.45
k,7,-2.45,-0.45
k,11,-3.25,-3.9
k,12,-2.45,-3.9
k,13,-2.45,-4.5
k,14,-3.25,-4.5
ksymm,x,2,14,1,100
kgen,2,9,14,1,0,-0.00125*(40-10)*(40-10)+2,10,2000
kgen,2,109,114,1,0,-0.00125*(40-10)*(40-10)+2,10,2000
kgen,2,9,14,1,0,-0.00125*(40-20)*(40-20)+2,20,3000
kgen,2,109,114,1,0,-0.00125*(40-20)*(40-20)+2,20,3000
kgen,2,9,14,1,0,-0.00125*(40-30)*(40-30)+2,30,4000
kgen,2,109,114,1,0,-0.00125*(40-30)*(40-30)+2,30,4000
kgen,2,9,14,1,0,-0.00125*(40-40)*(40-40)+2,40,5000
kgen,2,109,114,1,0,-0.00125*(40-40)*(40-40)+2,40,5000
kgen,2,2,14,1,0,0,1,1000
kgen,2,102,114,1,0,0,1,1000
kgen,2,2,7,1,0,0,10,2000
kgen,2,102,107,1,0,0,10,2000
kgen,2,2,7,1,0,0,20,3000
kgen,2,102,107,1,0,0,20,3000
kgen,2,2,7,1,0,0,30,4000
kgen,2,102,107,1,0,0,30,4000
kgen,2,2,7,1,0,0,40,5000
kgen,2,102,107,1,0,0,40,5000
k,100,0,0,0
k,200,1,0,0
k,300,0,1,0
k,400,0,-4.5,0
k,500,0,-14.5,0
l,400,500
k,21,-3.75,-0.25,-40
k,22,3.75,-0.25,-40
k,23,3.75,-0.25,40
k,24,-3.75,-0.25,40
k,25,-6,-0.1,-40
k,26,-3.75,-0.25,-40
k,27,-3.75,-0.25,40
k,28,-6,-0.1,40
k,29,6,-0.1,-40
k,30,3.75,-0.25,-40
k,31,3.75,-0.25,40
k,32,6,-0.1,40
a,21,22,23,24
a,25,26,27,28
a,29,30,31,32
*do,i,1000,5000,1000
v,2+i-1000,i-1000+7,i-1000+107,i-1000+102,2+i,7+i,107+i,102+i
v,2+i-1000,i-1000+3,i-1000+6,i-1000+7,2+i,3+i,6+i,7+i
v,3+i-1000,i-1000+4,i-1000+5,i-1000+6,3+i,4+i,5+i,6+i
v,7+i-1000,i-1000+6,i-1000+11,i-1000+12,7+i,6+i,11+i,12+i
v,11+i-1000,i-1000+14,i-1000+13,i-1000+12,11+i,14+i,13+i,12+i
v,12+i-1000,i-1000+13,i-1000+113,i-1000+112,12+i,13+i,113+i,112+i
v,100+2+i-1000,100+i-1000+3,100+i-1000+6,100+i-1000+7,100+2+i,100+3+i,100+6+i,100+7+i
v,100+3+i-1000,100+i-1000+4,100+i-1000+5,100+i-1000+6,100+3+i,100+4+i,100+5+i,100+6+i
v,100+7+i-1000,100+i-1000+6,100+i-1000+11,100+i-1000+12,100+7+i,100+6+i,100+11+i,100+12+i
v,100+11+i-1000,100+i-1000+14,100+i-1000+13,100+i-1000+12,100+11+i,100+14+i,100+13+i,100+12+i
*enddo
v,7,12,112,107,1007,1012,1112,1107
cskp,100,0,100,200,300
vsel,all
csys,100
vsymm,z,1,100,1,10000,0,0
csys,0
asel,s,loc,y,-4.5
vdrag,all,,,,,,1
allsel
vsel,all
wprota,0,0,90
wpave,2.7
vsbw,all
wpave,3
vsbw,all
wpave,-3
vsbw,all
wpave,-2.7
vsbw,all
wpave,2.45
vsbw,all
wpave,3.25
vsbw,all
wpave,-3.25
vsbw,all
wpave,-2.45
vsbw,all
wpave,2.2
vsbw,all
wpave,3.5
vsbw,all
wpave,-3.5
vsbw,all
wpave,-2.2
vsbw,all
wpave,1.95
vsbw,all
wpave,3.75
vsbw,all
wpave,-3.75
vsbw,all
wpave,-1.95
vsbw,all
vsel,s,loc,y,-0.45,0
vsba,all,1
vsba,all,2
vsba,all,3
allsel
vglue,all
vatt,1,1,1

lsel,s,loc,z,-10,10
lsel,r,loc,y,-0.25
lsel,r,loc,x,2.7
cm,gj1_1,line
latt,2,2,2
allsel
lsel,s,loc,z,-10,10
lsel,r,loc,y,-0.25
lsel,r,loc,x,3
cm,gj1_2,line
latt,2,2,2
allsel
lsel,s,loc,z,-10,10
lsel,r,loc,y,-0.25
lsel,r,loc,x,-3
cm,gj1_3,line
latt,2,2,2
allsel
lsel,s,loc,z,-10,10
lsel,r,loc,y,-0.25
lsel,r,loc,x,-2.7
cm,gj1_4,line
latt,2,2,2
allsel

lsel,s,loc,z,-20,20
lsel,r,loc,y,-0.25
lsel,r,loc,x,2.45
cm,gj2_1,line
latt,2,3,2
allsel
lsel,s,loc,z,-20,20
lsel,r,loc,y,-0.25
lsel,r,loc,x,3.25
cm,gj2_2,line
latt,2,3,2
allsel
lsel,s,loc,z,-20,20
lsel,r,loc,y,-0.25
lsel,r,loc,x,-3.25
cm,gj2_3,line
latt,2,3,2
allsel
lsel,s,loc,z,-20,20
lsel,r,loc,y,-0.25
lsel,r,loc,x,-2.45
cm,gj2_4,line
latt,2,3,2
allsel

lsel,s,loc,z,-30,30
lsel,r,loc,y,-0.25
lsel,r,loc,x,2.2
cm,gj3_1,line
latt,2,4,2
allsel
lsel,s,loc,z,-30,30
lsel,r,loc,y,-0.25
lsel,r,loc,x,3.5
cm,gj3_2,line
latt,2,4,2
allsel
lsel,s,loc,z,-30,30
lsel,r,loc,y,-0.25
lsel,r,loc,x,-3.5
cm,gj3_3,line
latt,2,4,2
allsel
lsel,s,loc,z,-30,30
lsel,r,loc,y,-0.25
lsel,r,loc,x,-2.2
cm,gj3_4,line
latt,2,4,2
allsel

lsel,s,loc,z,-40,40
lsel,r,loc,y,-0.25
lsel,r,loc,x,1.95
cm,gj4_1,line
latt,2,5,2
allsel
lsel,s,loc,z,-40,40
lsel,r,loc,y,-0.25
lsel,r,loc,x,3.75
cm,gj4_2,line
latt,2,5,2
allsel
lsel,s,loc,z,-40,40
lsel,r,loc,y,-0.25
lsel,r,loc,x,-3.75
cm,gj4_3,line
latt,2,5,2
allsel
lsel,s,loc,z,-40,40
lsel,r,loc,y,-0.25
lsel,r,loc,x,-1.95
cm,gj4_4,line
latt,2,5,2
allsel
!定义组
cmsel,s,gj1_1
cmsel,a,gj1_2
cmsel,a,gj1_3
cmsel,a,gj1_4
cm,gj1,line
allsel

cmsel,s,gj2_1
cmsel,a,gj2_2
cmsel,a,gj2_3
cmsel,a,gj2_4
cm,gj2,line
allsel

cmsel,s,gj3_1
cmsel,a,gj3_2
cmsel,a,gj3_3
cmsel,a,gj3_4
cm,gj3,line
allsel

cmsel,s,gj4_1
cmsel,a,gj4_2
cmsel,a,gj4_3
cmsel,a,gj4_4
cm,gj4,line
allsel
lesize,1
lsel,s,,,gj1
lsel,a,,,gj2
lsel,a,,,gj3
lsel,a,,,gj4
esize,1
lmesh,all
allsel
vmesh,all
nummrg,all
numcmp,all

nsel,s,loc,z,-1,1
esln,s,1,all
cm,kuai0,elem
allsel

nsel,s,loc,z,-10,-1
nsel,a,loc,z,1,10
esln,s,1,all
cm,kuai1,elem
allsel

nsel,s,loc,z,-20,-10
nsel,a,loc,z,10,20
esln,s,1,all
cm,kuai2,elem
allsel

nsel,s,loc,z,-30,-20
nsel,a,loc,z,20,30
esln,s,1,all
cm,kuai3,elem
allsel

nsel,s,loc,z,-40,-30
nsel,a,loc,z,30,40
esln,s,1,all
cm,kuai4,elem
allsel

nsel,s,loc,y,-14.5
d,all,all
allsel
/solu
eqslv,pcg

time,1
nlgeom,on
nropt,full
estif,1e-5
allsel
ekill,all
esel,s,,,kuai0
ealive,all
esel,s,live
nsle,s
nsel,inve
d,all,all,0
allsel
nsel,s,loc,y,-14.5
d,all,all
allsel
solve
save

time,2
allsel
esel,s,,,kuai1
ealive,all
allsel
ddele,all,all
esel,s,live
nsel,s
nsel,inve
d,all,all,0
allsel
nsel,s,loc,y,-14.5
d,all,all
allsel
solve
save

time,3
allsel
esel,s,,,kuai2
ealive,all
allsel
ddele,all,all
esel,s,live
nsel,s
nsel,inve
d,all,all,0
allsel
nsel,s,loc,y,-14.5
d,all,all
allsel
solve
save

time,4
allsel
esel,s,,,kuai3
ealive,all
allsel
ddele,all,all
esel,s,live
nsel,s
nsel,inve
d,all,all,0
allsel
nsel,s,loc,y,-14.5
d,all,all
allsel
solve
save

time,5
allsel
nsel,s,loc,z,-40,40
esln,s,1,all
ealive,all
allsel
ddele,all,all
nsel,s,loc,y,-14.5
d,all,all
allsel
solve
save