[共建]＜ANSYS命令流实例库＞敬请您的加盟

changzl

炉胆屈曲分析命令流：
/filname,fire_tube,1
/title,fire tube of boiler
/com,structural
*set,mat_nonlinear,0     !=0,不包括材料非线性
*set,max_defect,0.001    !最大缺陷施加为0.001m
/prep7
et,1,solid95
mptemp,1,0
mpdata,ex,1,,2e11
mpdata,prxy,1,,0.3
cylind,0.4,0.416,0,2,0,360
/view,1,1,1,1
esize,0.06,0
vsweep,1,,,
da,1,ux
da,1,uy
da,2,ux
da,2,uy
dk,12,uz     !关键点12约束Z位移（虚拟约束）
sfa,3,1,pres,1
sfa,4,1,pres,1
save
finish
/solu
antype,0       !设定分析类型为静力分析
pstres,on
solve
save
finish
/solu
antype,1                      !设定分析类型为特征值屈曲分析
bucopt,subsp,5,0,0            !特征值屈曲分析方法为子空间迭代
subopt,0,0,0,0,0,all          !子空间迭代参数设定
mxpand,5,0,0,0,0,0.001        !扩展求解选项设定
solve
finish
save
/post1
set,list
set,first
pldisp,o

*get,pressure1,mode,1,freq      !将第一阶临界压力赋值给变量pressure1
nsort,u,sum                     !对节点位移（矢量和）排序
*get,max_disp_sum,sort,,max     !将最大变形量赋值给max_disp_sum
*set,scale_factor,max_defect/max_disp_sum    !设定更新形状的比例系数
finish
/prep7
upgeom,scale_factor,last,last,'fire_tube','rst'    !更新结构形状
*if,mat_nonlinear,eq,1,then
  tb,miso,1,1,3
  tbtemp,0
  tbpt,,0,0
  tbpt,,0.00125,250e6
  tbpt,,0.5,250e6
*endif
finish
/solu
antype,0
sfa,3,1,pres,pressure1          !面3施加面载荷（特征值结果）
sfa,4,1,pres,pressure1          !面4施加面载荷（特征值结果）
nlgeom,1                        !考虑几何大变性
nsubst,10,0,0
arclen,1,4,0.001                !选定弧长法
outres,all,all
arctrm,l                        !载荷达到第一个峰值停止运行
solve
finish
/post26
nsol,2,9207,u,x,ux_2
xvar,1
plvar,2
finish

倚天剑

/prep7
!定义单元特性
rd1=8.0/1000
rd2=22.0/1000
et,1,solid65
et,2,link8
et,3,solid45
!定义混凝土材料特性
r,1
mp,ex,1,2.4e10
mp,prxy,1,0.1667
mp,dens,1,2500
fc=25.0e6 !混凝土抗压强度25.0MPa
fr=3.1125e6 !混凝土抗拉强度3.1125MPa
hntra=fc
op=0.35 !裂缝张开剪力传递系数 op=0.7
cl=0.75 !裂缝闭合剪力传递系数 cl=1

tb,concr,1
!tbdata,,op,cl,fr,fc !考虑压碎
tbdata,,op,cl,fr,-1 !不考虑压碎
kn=14 !应力应变关系描述点数
tb,miso,1,,kn
tbpt,,0.0002,hntra*0.192
tbpt,,0.0004,hntra*0.36
tbpt,,0.0006,hntra*0.51
tbpt,,0.0008,hntra*0.64
tbpt,,0.0010,hntra*0.75
tbpt,,0.0012,hntra*0.84
tbpt,,0.0014,hntra*0.91
tbpt,,0.0016,hntra*0.96
tbpt,,0.0018,hntra*0.99
tbpt,,0.0020,hntra*1.00
tbpt,,0.0025,hntra*0.95
tbpt,,0.0030,hntra*0.90
tbpt,,0.0035,hntra*0.85
tbpt,,0.0040,hntra*0.80

!定义钢筋材料特性
mp,ex,2,200e9 !纵向钢筋
mp,dens,2,7850
r,2,acos(-1)*0.25*rd2*rd2
mp,prxy,2,0.3
!受拉受压如何表示
tb,bkin,2 !双线性随动强化
tbtemp,0
tbdata,,360e6,0

!横向箍筋!(包括上排纵向钢筋)
mp,ex,3,200e9
mp,dens,3,7850
r,3,acos(-1)*0.25*rd1*rd1
mp,nuxy,3,0.25
tb,bkin,3 !双线性随动强化
tbtemp,0
tbdata,,210e6,0

blc4,,,0.150,0.300,1.325
/view,1,1,1,1
/ang,1
kwpave,6
wpoffs,,,-75/1000
vsbw,all
wpoff,,,-50/1000
vsbw,all
wpoffs,,,-75/1000
vsbw,all
*do,i,1,14,1
wpoffs,,,-75/1000
vsbw,all
*enddo
kwpave,6
wpoff,,30/1000,
wprot,,90,
vsbw,all
wpoff,,,-240/1000
vsbw,all
wprot,,,90
wpoff,,,-18.75/1000
vsbw,all
wpoff,,,-112.5/1000
vsbw,all
nummrg,all,,,,low
numcmp,all
wpsty !关闭工作平面显示

DESIZE,1,2,15,15,28, , ,1,4, !单元尺寸控制
lsel,s,loc,x,18.75/1000
lsel,a,loc,x,131.25/1000
lsel,r,loc,y,30/1000
latt,2,2,2 !下排纵向钢筋

FLST,5,8,4,ORDE,8
FITEM,5,423
FITEM,5,428
FITEM,5,463
FITEM,5,468
FITEM,5,558
FITEM,5,567
FITEM,5,606
FITEM,5,613
CM,_Y,LINE
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y
LESIZE,_Y1,25/1000, , , , , , ,1
   

FLST,5,28,4,ORDE,28
FITEM,5,407
FITEM,5,417
FITEM,5,433
FITEM,5,438
FITEM,5,443
FITEM,5,448
FITEM,5,453
FITEM,5,458
FITEM,5,493
FITEM,5,498
FITEM,5,473
FITEM,5,478
FITEM,5,483
FITEM,5,488
FITEM,5,540
FITEM,5,550
FITEM,5,572
FITEM,5,577
FITEM,5,584
FITEM,5,589
FITEM,5,596
FITEM,5,601
FITEM,5,642
FITEM,5,645
FITEM,5,618
FITEM,5,625
FITEM,5,630
FITEM,5,637
CM,_Y,LINE
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y
LESIZE,_Y1, , ,1, , , , ,1

ALLSEL,ALL
lsel,s,loc,x,18.75/1000
lsel,a,loc,x,131.25/1000
lsel,r,loc,y,270/1000
latt,2,3,2 !上排纵向钢筋

FLST,5,8,4,ORDE,8
FITEM,5,56
FITEM,5,73
FITEM,5,233
FITEM,5,253
FITEM,5,393
FITEM,5,398
FITEM,5,228
FITEM,5,261
CM,_Y,LINE
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y
LESIZE,_Y1,25/1000, , , , , , ,1
FLST,5,28,4,ORDE,28
FITEM,5,15
FITEM,5,42
FITEM,5,90
FITEM,5,106
FITEM,5,120
FITEM,5,138
FITEM,5,163
FITEM,5,167
FITEM,5,199
FITEM,5,205
FITEM,5,665
FITEM,5,667
FITEM,5,288
FITEM,5,363
FITEM,5,368
FITEM,5,373
FITEM,5,378
FITEM,5,383
FITEM,5,388
FITEM,5,516
FITEM,5,520
FITEM,5,403
FITEM,5,501
FITEM,5,506
FITEM,5,511
FITEM,5,649
FITEM,5,655
FITEM,5,660
CM,_Y,LINE
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y
LESIZE,_Y1, , ,1, , , , ,1

ALLSEL,ALL
lsel,s,loc,y,30/1000,270/1000,240/1000
lsel,r,loc,x,19/1000,131/1000
latt,2,3,2

FLST,5,38,4,ORDE,38
FITEM,5,552
FITEM,5,554
FITEM,5,561
FITEM,5,563
FITEM,5,580
FITEM,5,592
FITEM,5,609
FITEM,5,621
FITEM,5,633
FITEM,5,688
FITEM,5,690
FITEM,5,692
FITEM,5,694
FITEM,5,696
FITEM,5,698
FITEM,5,701
FITEM,5,-702
FITEM,5,705
FITEM,5,-706
FITEM,5,708
FITEM,5,710
FITEM,5,712
FITEM,5,714
FITEM,5,716
FITEM,5,718
FITEM,5,720
FITEM,5,722
FITEM,5,724
FITEM,5,726
FITEM,5,728
FITEM,5,730
FITEM,5,732
FITEM,5,734
FITEM,5,736
FITEM,5,738
FITEM,5,740
FITEM,5,742
FITEM,5,744
CM,_Y,LINE
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y
LESIZE,_Y1,18.75/1000, , , , , , ,1

ALLSEL,ALL
lsel,s,loc,x,18.75/1000,131.25/1000,112.5/1000
lsel,r,loc,y,31/1000,269/1000
latt,2,3,2

FLST,5,38,4,ORDE,4
FITEM,5,521
FITEM,5,-539
FITEM,5,668
FITEM,5,-686
CM,_Y,LINE
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y
LESIZE,_Y1,30/1000, , , , , , ,1

ALLSEL,ALL
LSEL,r,TYPE,,2
lmesh,all
ALLSEL,ALL

FLST,5,2,4,ORDE,2
FITEM,5,154
FITEM,5,298
CM,_Y,LINE
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y
LESIZE,_Y1, , ,1, , , , ,1
FLST,5,4,4,ORDE,4
FITEM,5,1
FITEM,5,154
FITEM,5,298
FITEM,5,410
CM,_Y,LINE
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y
LESIZE,_Y1, , ,1, , , , ,1
FLST,5,1,4,ORDE,1
FITEM,5,323
CM,_Y,LINE
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y
LESIZE,_Y1,30/1000, , , , , , ,1
FLST,5,1,4,ORDE,1
FITEM,5,699
CM,_Y,LINE
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y
LESIZE,_Y1,18.75/1000, , , , , , ,1

ALLSEL,ALL
vsel,all
vatt,1,1,1
mshape,0,3d
mshkey,1
vmesh,all
allsel,all
NUMMRG,ALL, , , ,LOW
NUMCMP,ALL

!定义钢板
r,1
mp,ex,4,2e11
mp,prxy,4,0.25
mp,dens,4, 7.85e3
tb,bkin,4 !双线性随动强化
tbtemp,0
tbdata,,360e6,0

ALLSEL,ALL
ESEL,S,TYPE,,1
FLST,5,40,2,ORDE,8
FITEM,5,661
FITEM,5,-662
FITEM,5,669
FITEM,5,-671
FITEM,5,893
FITEM,5,-897
FITEM,5,1265
FITEM,5,-1294
ESEL,R, , ,P51X

EGEN,2,3000,all, , , , , , , , ,-30/1000, ,

ALLSEL,ALL
ESEL,S,TYPE,,1
FLST,5,48,2,ORDE,6
FITEM,5,646
FITEM,5,-651
FITEM,5,884
FITEM,5,-889
FITEM,5,1211
FITEM,5,-1246
ESEL,R, , ,P51X
EGEN,2,6000,all, , , , , , , , ,30/1000, ,

ALLSEL,ALL
ESEL,S,TYPE,,1
FLST,5,88,2,ORDE,2
FITEM,5,2633
FITEM,5,-2720
ESEL,R, , ,P51X

EMODIF,all,type,3,
EMODIF,all,MAT,4,
EMODIF,all,real,1,

ALLSEL,ALL
NUMMRG,NODE, , , ,LOW
NUMCMP,NODE

!中间截面约束
FLST,2,99,1,ORDE,32
FITEM,2,1
FITEM,2,15
FITEM,2,45
FITEM,2,75
FITEM,2,-81
FITEM,2,208
FITEM,2,212
FITEM,2,-216
FITEM,2,283
FITEM,2,-289
FITEM,2,446
FITEM,2,-450
FITEM,2,561
FITEM,2,-563
FITEM,2,628
FITEM,2,630
FITEM,2,632
FITEM,2,639
FITEM,2,646
FITEM,2,-650
FITEM,2,682
FITEM,2,-683
FITEM,2,834
FITEM,2,-840
FITEM,2,1020
FITEM,2,-1022
FITEM,2,1116
FITEM,2,-1122
FITEM,2,1480
FITEM,2,-1484
FITEM,2,1700
FITEM,2,-1734
/GO
D,P51X, , , , , ,UX,UZ, , , ,

!边支座约束
FLST,2,9,1,ORDE,6
FITEM,2,2577
FITEM,2,2579
FITEM,2,2589
FITEM,2,2591
FITEM,2,2604
FITEM,2,-2608
/GO
D,P51X, , , , , ,UX,UY,, , ,

allsel,all
NUMMRG,NODE, , , ,LOW !压缩合并节点
NUMCMP,NODE
NUMMRG,ELEM, , , ,LOW !压缩合并单元
NUMCMP,ELEM
allsel,all
finish

/solu
!ACEL,0,9.8,0 ! 重力加速度
antype,0
cnvtol,f,,0.10,2,0.05 !定义力收敛条件10%，使用不缺省的value:5%
                         !0.05 The minimum value allowed for the program calculated reference value.
nsubst,15 !定义子步数15
outres,all,LAST !输出每一子步结果
                    !由于结果文件最大4G，本程序已经超出，故要求控制
autots,1 !打开自动时间步控制
lnsrch,1 !线性搜索
ncnv,2 !如果不收敛时结束不退出
neqit,10 !每一子步中方程的迭代次数控制10
pred,on !打开预测器
kbc,0
NROPT,FULL, ,ON !全牛顿拉谱森法
LUMPM,0
EQSLV,SPAR, ,0,
PRECISION,0
MSAVE,0
PIVCHECK,1
SSTIF
PSTRES

FCUM,ADD,1, !将载荷设为后续加载在同一位置时为加载增量值

!加载
*do,n,1,15
time,n
!加载荷载值20000/(9*10)N
!time=1自重不加载
*if,n,eq,1,then
F,2631,FY,0
F,2634,FY,0
F,2645,FY,0
F,2648,FY,0
F,2662,FY,0
F,2663,FY,0
F,2664,FY,0
F,2665,FY,0
F,2666,FY,0
*elseif,n,gt,1 !n>=2,加载2000N
F,2631,FY,-2000/9
F,2634,FY,-2000/9
F,2645,FY,-2000/9
F,2648,FY,-2000/9
F,2662,FY,-2000/9
F,2663,FY,-2000/9
F,2664,FY,-2000/9
F,2665,FY,-2000/9
F,2666,FY,-2000/9
*endif
lswrite
*enddo

lssolve,1,15 !求解
finish

/post26
numvar,10
finish
save

倚天剑

/PREP7
SMRT,OFF

ANTYPE,STATIC   
ET,1,PLANE42,,,3            ! 定义平面应力单元有单元厚度
                           
MP,EX,1,210E9               ! 定义材料属性
MP,NUXY,1,.3
R,1,0.1                     ! 给定厚度
LOCAL,11,1,,,,,,,0.5        ! 定义区域坐标系统为圆柱坐标系，Y轴是X的0.5倍。
K,1,2,90                     
K,2,2,0                     
L,1,2                        
LOCAL,12,1,,,,,,,0.8461585  ! 定义区域坐标系统为圆柱坐标系，Y轴是X的0.846倍。
K,3,3.25,90
K,4,3.25,0.0
L,3,4
CSYS,0                      !回到卡式坐标系下。
L,2,4
L,1,3
AL,2,4,1,3                  ! 创建面积
DL,4,1,SYMM                 ! 创建对称面约束
DL,3,1,SYMM
SFL,2,PRES,-10E6            ! 定义线上的分布载荷
MSHK,2                      ! 混合网格划分
MSHA,0,2D                   ! 四边形网格
SAVE                        ! 备份数据库
FINISH
ADAPT,7,7,,,1               ! 求解次数为nsoln=4次，能量误差百分比stargt=7,单元尺寸改变最大比例因子facmx=1
                           
/POST1
EPLOT                       ! 绘制单元
PRERR                       ! 打印能量误差百分比
NSEL,S,LOC,Y,0.0
NSEL,R,LOC,X,2.0
*GET,MNODE,NODE,,NUM,MAX
*GET,SY_D,NODE,MNODE,S,Y    ! GET DESIRED STRESS SY VALUE
NSEL,ALL
ESEL,ALL
FINISH

besttop001

呕心沥血之作，请求斑竹加分！



/prep7
csys,0
NUMCMP,ALL
allsel,all
*get,t,elem,,num,max
*dim,vv,array,t,1
*dim,ecx,array,t,1
*dim,ecy,array,t,1
*dim,ecz,array,t,1
sv=0
scvx=0
scvy=0
scvz=0
*do,i,1,t
*get,vv(i),elem,i,volu
*if,vv(i),ne,0,then
*get,ecx(i),elem,i,cent,x
*get,ecy(i),elem,i,cent,y
*get,ecz(i),elem,i,cent,z
scvx=scvx+ecx(i)*vv(i)
scvy=scvy+ecy(i)*vv(i)
scvz=scvz+ecz(i)*vv(i)
sv=sv+vv(i)

*endif
*enddo
c1x=scvx/sv
c1y=scvy/sv
c1z=scvz/sv
k,10000000,c1x,c1y,c1z

shupeng2hao

求变截面梁的最大挠度,用beam189单元计算准确吗,有没有需要注意的地方?

命令流:

/prep7
b=0.1
t=0.008
d=0.006
h1=0.3
h2=0.1
l=4
p1=100000
p2=10000
et,1,beam189
keyopt,1,2,1
keyopt,1,12,0
nlgeom,off
mp,ex,1,2.1e11
mp,prxy,1,1/3
k,1
k,2,l
k,4,2,2
l,1,2
sectype,1,beam,i
secdata,b,b,h1,t,t,d
sectype,2,beam,i
secdata,b,b,h2,t,t,d
sectype,3,taper,i
SECDATA,   1,kx(1),ky(1),kz(1),
SECDATA,   2,kx(2),ky(2),kz(2),
lesize,all,,,50
latt,1,,1,,4,,3
lmesh,all
/eshape,1
eplot
nsel,all
d,all,uz,,,,,rotx,roty
d,1,ux,,,,,uy
d,2,uy
nsel,s,loc,x,l/2
f,all,fy,-p1
allsel,all
f,2,fx,-p2
finish
/solu
solve
finish
/post1
pldisp,1

sh_lin30

原帖由 fpemail 于 2004-11-30 23:45 发表
RAD=0.8  !底面半径
H=1
G=9.8
OMEGAR=2
ROU=1000　　　!定义参数变量
/PREP7　　　　!进入前处理器
ET,1,FLUID79    !选择单元类型
KEYOPT,1,3,1　　!设置单元关键字
MP,EX,1,2E9　　　　!设置杨氏模量
MP,DENS, ...

这个不应该算作流固耦合吧？！

流体特性和流固耦合标识都没有定义！

qiangyue

/clear,start
/FILNAME,Gravity Dam
/CWD,'F:\'  
/TITLE,an example of 3D Gravity Dam   
!*  set cons value
*SET,h,180  
*SET,h1,100
*SET,h2,80  
*SET,h3,100
*SET,gm,1000
*SET,fia1,90-atan(0.75)*180/3.1415926   
*SET,fia2,90-fia1   
!*  enter preprocessor
/prep7  
et,1,plane42
et,2,solid65
et,3,solid45
mp,ex,1,2.85e10
mp,prxy,1,0.167
tb,conc,1,1,9,  
tbdata,,0.3,1,1.96e6,22e6   
mp,dens,1,2400  
mp,ex,2,2.6e10  
mp,prxy,2,0.167
tb,conc,2,1,9   
tbdata,,0.3,1,1.2e6,17.5e6  
mp,dens,2,2400  
mp,ex,3,2.9e10  
mp,prxy,3,0.3   
mp,dens,3,2600  
k,1
k,2,0.9*0.75*h+0.1*h
k,3,0.1*h,0.9*h
k,4,0,0.9*h
l,1,2   
l,2,3   
l,3,4   
l,4,1   
al,1,2,3,4  
rectng,0,0.1*h,0.9*h,h  
rectng,-1.5*h,0,-2*h,0  
rectng,0,0.9*0.75*h+0.1*h,-2*h,0
rectng,0.9*0.75*h+0.1*h,(2+0.75*0.9)*h,-2*h,0   
rectng,-1.5*h,(2+0.9*0.75)*h,-2*h,h
aplot   
aovlap,all  
/pnum,line,1
/pnum,area,1
nummrg,all  
numcmp,all  
aplot     
lsel,s,,,3,5,2  
lesize,all,,,5  
lsel,s,,,12,13,1
lesize,all,,,2  
amesh ,3
lsel,s,,,2,4,2
lesize,all,,,18
lsel,s,,,1
lesize,all,,,5
amesh,1
eplot
lsel,s,,,11
lesize,all,,,5  
lsel,s,,,9,10,1
lesize,all,,,8,4
amesh,2
lsel,s,,,14
lesize,all,,,5,4
lsel,s,,,7  
lesize,all,,,8,4
lsel,s,,,6  
lesize,all,,,5,0.25
amesh,4   
lsel,s,,,15,16,1
lesize,all,,,8,4
lsel,s,,,8  
lesize,all,,,8,0.25
amesh,5
eplot   
lsel,s,,,4,13,9
lccat,all   
lsel,s,,,19
lesize,all,,,5,4
lsel,s,,,20,21,1
lesize,all,,,20
amesh,7
lsel,s,,,2,12,10
lccalc,all  
lsel,s,,,17
lesize,all,,,8,4
lsel,s,,,18,22,4
lesize,all,,,20
amesh,6
eplot   
allsel  
lsel,r,lcca
ldele,all,1
extopt,esize,8,0
type,2  
mat,1   
vext,1,3,2,,,-0.75*h
/view,1,1,1,1   
vplot   
eplot   
extopt,esize,8,0
type,3  
mat,3   
vext,2,,,,,-0.75*h  
vext,4,5,1,,,-0.75*h
eplot   
有问题请联系,qiangyue-320@163.com

jz200428

我觉得要作成专门的工程实例命令流贴，需要有人整理才行！因为大家看时，当时未必有例子，但是觉得不错是要顶下的，对吧！但是不建议把经常见到的贴出来，或者没运行正确的都最好不要帖，如果要贴要注明。
这确实是个不错的注意，应该感谢楼主！我在做毕业设计，结构分析方面的！目前遇到问题，没有分析出正确的结果。不知道怎么处理两个零件之间的螺钉连接，所以需要这方面的例子，螺栓的也可以，这方面在装配分析中应该比较常用。有人说用设置刚性区域或耦合，顺便说下，我考虑螺栓的影响。恳请做过这样项目的人发个例子上来。我做完之后定把命令流传上来！

icst_li

瞬态热力学分析实例：

/Title, Casting Solidification

!进入前处理
/prep7
et,1,plane55                           !定义单元类型
mp,dens,1,0.054                       !定义砂模热性能
mp,kxx,1,0.025
mp,c,1,0.28
mptemp,1,0,2643,2750,2875           !定义铸钢的热性能
mpdata,kxx,2,1.44,1.54,1.22,1.22
mpdata,enth,2,0,128.1,163.8,174.2
mpplot,kxx,2
mpplot,enth,2
save
!创建几何模型
k,1,0,0,0
k,2,22,0,0
k,3,10,12,0
k,4,0,12,0
/pnum,kp,1
/pnum,line,1
/pnum,area,1
/Triad,ltop
kplot
a,1,2,3,4
save
rectng,4,22,4,8
aplot
aovlap,all
adele,3
aplot
save
!划分网格
esize,1
amesh,5
mat,2
aplot
amesh,4
eplot
/pnum,elem
/number,1
save

!进入加载求解
/SOLU
antype,trans                       !设定为瞬态分析
esel,s,mat,,2                      !设定铸钢的初始温度
nsle,s
/replot
ic,all,temp,2875
esel,inve                           !设定砂模的初始温度
nsle,s
/replot
ic,all,temp,80
allsel
save
lplot
sfl,1,CONV,0.014,,80              !设定砂模外边界对流
sfl,3,CONV,0.014,,80
sfl,4,CONV,0.014,,80
/psf,conv,2
time,3                               !设定瞬态分析时间
kbc,1                                !设定为阶越的载荷
autots,on                           !打开自动时间步长
deltim,0.01,0.001,0.25            !设定时间步长
timint,on                            !打开时间积分
tintp,,,,1                           !将THETA设定为1
outres,all,all                      !输出每个子步的结果
solve

!进入后处理
/post26
/pnum,node,1
/number,0
eplot
nsol,2,204,temp,center            !设定铸钢中心点温度随时间的变量
plvar,2                              !绘制温度～时间曲线
save
finish

djgdjgdjg

三跨连续梁桥的分析
fini
/clear
/title,three span continous bridge
/prep7
!上顶板的关键点位置
k,1,0,0
k,2,-2.1
k,3,-2.6,-0.125
k,4,-2.8,-0.125
k,5,-3.0,-0.125
k,6,-3.4857,-0.1036
k,7,-3.9714,-0.0821
k,8,-4.4571,-0.0607
k,9,-4.9429,-0.0393
k,10,-5.4286,-0.0179
k,11,-5.9143,0.0036
k,12,-6.4,0.025

!下底板的关键点位置
k,13,-2.8,-1.85
k,14,,-1.85

!上顶板关键点49m位置
kgen,9,1,12,1,0,0,49/8,100

!上顶板关键点50m位置
kgen,2,1,12,1,0,0,50,900

!上顶板关键点50+34.5m位置
kgen,9,901,912,1,0,0,34.5/8,100

!上顶板关键点50+35m位置
kgen,2,901,912,1,0,0,35,900
!板的高度由1.85m变至3.875m
c1=0.000843399               !49m边跨的二次抛物线系数
c2=0.001701323               !34.5m边跨的二次抛物线系数

*dim,x1,array,8              !定义边跨的八分点位置
*do,i,1,8,1
  x1(i)=i*49/8
*enddo

*dim,x2,array,8              !定义中跨的八分点位置
*do,i,1,8,1
  x2(i)=i*34.5/8
*enddo

!下底板边跨（49m）八分点关键点的y坐标位置
*dim,yb,array,8              
*do,i,1,8,1
  yb(i)=c1*x1(i)**2
*enddo

!下底板中跨（34.5m）八分点关键点的y坐标位置
*dim,ym,array,8              
*do,i,1,8,1
  ym(i)=-c2*(x2(i)-34.5)**2+2.025
*enddo

!生成下底边跨（49m）八分点的关键点
*do,i,1,8,1
  kgen,2,13,14,1,0,-yb(i),x1(i),i*100
*enddo
!下底板50m处关键点
kgen,2,813,814,1,0,0,1,100

!生成下底中跨（50＋34.5m）八分点的关键点
*do,i,1,8,1
  kgen,2,913,914,1,0,ym(i),x2(i),i*100
*enddo

!边墩处的横隔板位置
!1，2，3，4～14为0m处横隔板位置的所有关键点
!51，52，53～54为-0.5m处横隔板位置的所有关键点
kgen,2,1,14,1,0,,-0.5,50

!中墩处的横隔板位置
!801，802，803，804～814为49m处横隔板位置的所有关键点
!901，902，903～904为50m处横隔板位置的所有关键点

!连成板面
!上顶板，板厚0.25m
et,1,shell63
mp,dens,1,2500
mp,ex,1,3.5e10
mp,prxy,1,0.1667
r,1,0.25

*do,i,0,16,1
a,1+i*100,1+(i+1)*100,2+(i+1)*100,2+i*100
*enddo
a,1,51,52,2
aatt,1,1,1
asel,none

!上顶板的加腋，板厚0.375m
r,2,0.375
*do,i,0,16,1
a,2+i*100,2+(i+1)*100,3+(i+1)*100,3+i*100
*enddo
a,2,52,53,3
aatt,1,2,1
asel,none

!肋板与翼缘交接处，板厚0.5m
r,3,0.5
*do,i,0,16,1
a,3+i*100,3+(i+1)*100,4+(i+1)*100,4+i*100
a,4+i*100,4+(i+1)*100,5+(i+1)*100,5+i*100
*enddo
a,3,53,54,4
a,4,54,55,5
aatt,1,3,1
asel,none

!翼缘厚度渐变，下面定义翼缘板的渐变厚度
*dim,hd,array,9
hd(9)=0.2
hd(8)=1*(3.4/7)*0.3/3.4+0.2
hd(7)=2*(3.4/7)*0.3/3.4+0.2
hd(6)=3*(3.4/7)*0.3/3.4+0.2
hd(5)=4*(3.4/7)*0.3/3.4+0.2
hd(4)=5*(3.4/7)*0.3/3.4+0.2
hd(3)=6*(3.4/7)*0.3/3.4+0.2
hd(2)=7*(3.4/7)*0.3/3.4+0.2
hd(1)=0.5

*do,i,1,8,1
r,30+i,hd(i),hd(i),hd(i+1),hd(i+1)   !定义渐变的翼缘厚度
*enddo

*do,i,0,16,1
*do,k,5,11,1
  a,k+i*100,k+(i+1)*100,k+1+(i+1)*100,k+1+i*100
  a,k,k+50,k+1+50,k+1
  aatt,1,k+26,1
  asel,none   
*enddo
*enddo
asel,none

!肋板厚度0.5m
r,4,0.5
*do,i,0,16,1
  a,4+i*100,4+(i+1)*100,13+(i+1)*100,13+i*100
*enddo
a,4,54,63,13
aatt,1,4,1
asel,none

!下底板厚度0.25m～0.4m按2次抛物线过度
c3=6.2474e-05   !边跨底板厚度变化的二次抛物线系数
c4=0.000126024  !中跨底板厚度变化的二次抛物线系数
*dim,h1,array,8  !边跨底板厚度
*do,i,1,8,1
  h1(i)=0.25+c3*x1(i)**2
*enddo

*dim,h2,array,9  !中跨底板厚度
*do,i,1,8,1
  h2(i)=0.25+c4*x2(i)**2
*enddo
h2(9)=0.4

!生成边跨的底板单元
*do,i,1,8,1
  r,10+i,h1(i)
  a,13+(i-1)*100,13+i*100,14+i*100,14+(i-1)*100
  aatt,1,10+i,1
  asel,none
*enddo

!生成中跨的底板单元
*do,i,1,9,1
  r,20+i,h2(i)
  a,13+(i+7)*100,13+(i+8)*100,14+(i+8)*100,14+(i+7)*100
  aatt,1,20+i,1
  asel,none
*enddo
a,13,63,64,14
aatt,1,20+i,1
asel,none

r,50,0.5   !横隔板厚度2m
a,1,2,13,14   !端横隔板
a,51,52,63,64
a,801,802,813,814   
a,901,902,913,914
aatt,1,50,1

allsel
esize,0.4
mshape,0
mshkey,1
amesh,all
nsel,all

nsym,x,10000,all
esym,x,10000,all

local,11,0,,,84.5
csys,11
allsel
nsym,z,100000,all
esym,z,100000,all

allsel
nummrg,all
numcmp,all
csys,0

!施加支座约束
!支座位置选择在肋板处（端部支座）
nsel,s,loc,y,-1.85
nsel,r,loc,x,-3,-2.6
nsel,r,loc,z,-0.5,0
d,all,ux,,,,,uy,roty,rotz

allsel
nsel,s,loc,y,-1.85
nsel,r,loc,x,3,2.6
nsel,r,loc,z,-0.5,0
d,all,ux,,,,,uy,roty,rotz

allsel
nsel,s,loc,y,-1.85
nsel,r,loc,x,-3,-2.6
nsel,r,loc,z,169,169.5
d,all,ux,,,,,uy,roty,rotz

allsel
nsel,s,loc,y,-1.85
nsel,r,loc,x,3,2.6
nsel,r,loc,z,169,169.5
d,all,ux,,,,,uy,roty,rotz

!中部支座
allsel
nsel,s,loc,y,-3.875
nsel,r,loc,x,3,2.6
nsel,r,loc,z,49,50
d,all,ux,,,,,uy,roty,rotz

allsel
nsel,s,loc,y,-3.875
nsel,r,loc,x,-3,-2.6
nsel,r,loc,z,49,50
d,all,ux,,,,,uy,roty,rotz

allsel
nsel,s,loc,y,-3.875
nsel,r,loc,x,-3,-2.6
nsel,r,loc,z,119,120
d,all,ux,,,,,uy,uz,roty,rotz

allsel
nsel,s,loc,y,-3.875
nsel,r,loc,x,3,2.6
nsel,r,loc,z,119,120
d,all,ux,,,,,uy,uz,roty,rotz

!工况1  一期恒载
allsel
/solu
acel,,9.8
solve
fini

chjq1121

csys,1
k,1,20,0,0                    !定义关键点1
k,110,16,40                   !定义关键点110
KWPAVE,110                    !偏移工作平面到节点110处
wprota,-50,0,0                !旋转工作平面
csys,4                        !降激活的坐标系设置为工作平面坐标系
k,2,12.838,0,0

csys,1
k,120,16,43                   !定义关键点120
k,130,16,46
k,140,16,49
k,150,16,52
k,160,16,55

KWPAVE,120
wprota,3,0,0
csys,4
k,3,13.676,0,0
KWPAVE,130
wprota,3,0,0
csys,4
k,4,14.513,0,0
KWPAVE,140
wprota,3,0,0
csys,4
k,5,15.351,0,0
KWPAVE,150
wprota,3,0,0
csys,4
k,6,16.189,0,0
KWPAVE,160
wprota,3,0,0
csys,4
k,7,17.027,0,0

csys,1                           !降工作平面坐标系设置为柱面坐标系
k,8,24,9.857
k,9,24,13
k,10,20,-5

lstr,1,2                             !通过节点创建直线
lstr,2,3
lstr,3,4
lstr,4,5
lstr,5,6
lstr,6,7
lstr,7,8
lstr,8,9
lstr,1,10


lcomb,all,,0                        !把所有险段add成一条线


！！！！偏移工作平面到总体坐标系的原点
！！！！将工作平面与总体坐标系对齐

wprota,13,0,0                !旋转工作平面
csys,4                       !降激活的坐标系设置为工作平面坐标系
LSYMM,y,1,,,1000,0,0         !将所有线沿X-Z面进行镜像
lglue,1,2,,,,,,,                    !把齿顶上的两条线粘结起来
lcomb,3,4,0
csys,1
LGEN, 10, all, , , , 36, , , , 0    ! 在柱面坐标系下复制所有线

lglue,2,6
lglue,4,12
lglue,13,17
lglue,18,22
lglue,23,27
lglue,28,32
lglue,33,37
lglue,38,42
lglue,43,47
lglue,48,5
lcomb,2,51,0
lcomb,4,6,0
lcomb,12,13,0
lcomb,17,18,0
lcomb,22,23,0
lcomb,27,28,0
lcomb,32,33,0
lcomb,37,38,0
lcomb,42,43,0
lcomb,5,47,0
LGLUE, all, , , , , , , ,
AL, all, , , , , , , , ,
cyl4,0,0,8,,,,                  !创建圆面
ASBA,1,2,,,  ！从齿轮面中减去圆面


建立齿轮的三维实体模型
VOFFST,3,8,           ！把圆面拉什成体
CYL4,0,0,16,,,,-2.5
workplane>offset wp to>xyz locations  0,0,-8
CYL4,0,0,16,,,,2.5
csys,1
k,10000,12,-5,

CYL4,0,0,2.5,,,,-8

VSBV,1,2,,,DELETE
VSBV,5,3,,,DELETE
VSBV,1,4,,,keep
csys,1
VGEN, 10, 1, , , , 36, , , 0,0
VSBV,2,3,,,DELETE
VSBV,12,4,,,DELETE
VSBV,2,5,,,DELETE
VSBV,3,6,,,DELETE
VSBV,2,7,,,DELETE
VSBV,3,8,,,DELETE
VSBV,2,9,,,DELETE
VSBV,3,10,,,DELETE
VSBV,2,11,,,DELETE
VDELE,1,,,1

huajian5410

Finish
/clear
/title,the analysis of linking rod
wpstyle,,,,,,,,1  !显示工作平面
/triad,off
keyw,pr_struc,1  !设置结构分析类型
/prep7
ET,1,SOLID92
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,2.06e5
MPDATA,PRXY,1,,0.3
!**********left and rignt column**********
!左筒
k,1,-137/2,101.6/2
k,2,-103.12/2,ky(1)
k,3,kx(1),-ky(1)
k,4,kx(2),-ky(2)
k,5,kx(1)-5
l,1,2
l,2,4
l,3,4
BSPLIN,1,5,3
al,1,2,3,4
!左筒旋转轴
k,6,0,0
k,7,0,ky(1)
!右筒
k,8,330.2+142.11/2,101.6/2
k,9,kx(8),10.41/2
k,10,kx(9)+2.985,ky(9)
k,11,kx(8),-ky(9)
k,12,kx(10),-ky(10)
k,13,kx(8),-ky(8)
k,14,kx(13)+0.5*(180-142.11),-ky(8)
k,15,kx(14)+5,0
k,16,kx(14),ky(8)
k,17,330.2,ky(8)
k,18,330.2,0
l,8,9
l,9,10
l,10,12
l,11,12
l,11,13
l,13,14
l,8,16
BSPLIN,14,15,16
al,5,6,7,8,9,10,11,12
!旋转生成两圆柱
vrotat,1,,,,,,6,7,,2
vrotat,2,,,,,,17,18,,2
!上下板
wpoff,52,0,0
wprot,,,-90
CSYS,4  
FLST,2,2,8  
FITEM,2,52,-40.95,34.625
FITEM,2,52,-37.45,34.625
CIRCLE,P51X, , , ,360, ,
k,,87.65/2
l,35,34
ldele,49,,,1
ldele,52,,,1
FLST,2,2,8  
FITEM,2,52,40.95,34.625
FITEM,2,52,37.45,34.625
CIRCLE,P51X, , , ,360, ,
l,35,36
ldele,49,,,1
ldele,55,,,1
k,,25.425
l,32,31
l,31,38

k,,35,-11.11/2
k,,0,-11.11/2
k,,35,11.11/2
k,,0,11.11/2
l,39,40
l,41,42

lsbl,49,57,,,keep
ldel,59,,,1
ldel,57
kdele,39
l,40,43
lsbl,55,58,,,keep
ldel,57,,,1
ldel,58
kdele,41
l,39,42

LFILLT,60,49,6.35, ,
LFILLT,59,55,6.35, ,
LFILLT,53,56,50.8, ,
kdele,35
kdele,39
kdele,43
l,40,42
!*********combine lines**********
FLST,2,13,4,ORDE,2  
FITEM,2,49  
FITEM,2,-61
LCOMB,P51X, ,0  
al,49,62
! then generated the area 29
kdele,6,7
kdele,17,18
!generate the offseting line
WPCSYS,-1,0
k,,52,0,87.65/2
k,,279.2,0,114.56/2
l,6,7
! generate the line 50
!*****generate the column******
VDRAG,29,,,,,,50

!*********the middle colume*******
wprot,,,-90
CYL4,0,0,31.75/2
VOFFST,33,-330, ,
!***********devide the colume**********
FLST,3,4,5,ORDE,4   
FITEM,3,6   
FITEM,3,11  
FITEM,3,18  
FITEM,3,27  
VSBA,       6,P51X  
FLST,3,4,5,ORDE,4   
FITEM,3,6   
FITEM,3,11  
FITEM,3,18  
FITEM,3,27  
VSBA,       5,P51X
FLST,2,4,6,ORDE,3   
FITEM,2,6   
FITEM,2,-8  
FITEM,2,10  
VDELE,P51X, , ,1
FLST,3,1,6,ORDE,1   
FITEM,3,11  
VSYMM,X,P51X, , , ,0,0  
FLST,2,7,6,ORDE,4   
FITEM,2,1   
FITEM,2,-5  
FITEM,2,9   
FITEM,2,11  
VADD,P51X  
!***** oil hole*****
CYL4,0,0,10.41/2
VOFFST,1,-330, ,
VSBV,       6,       1  

!*****方形******
wpoff,,,-330.2
k,,103.505,-50.8,101.6/2
k,,148.08/2,-50.8,101.6/2
k,,148.08/2,-50.8,-101.6/2
k,,103.505,-50.8,-101.6/2
a,17,34,35,36
LFILLT,31,14,17.78, ,   
LFILLT,31,27,17.78, ,


AL,55,49,54
AL,56,58,57
FLST,3,2,5,ORDE,2   
FITEM,3,2   
FITEM,3,4   
ASBA,       1,P51X

VOFFST,6,-101.6, ,  
FLST,3,1,6,ORDE,1   
FITEM,3,1   
VSYMM,X,P51X, , , ,0,0  


wpoff,,,50.8   
CYL4,171.45/2,-63.96/2,15.88/2  
CYL4,171.45/2,63.96/2,15.88/2   
CYL4,171.45/2,-6.3,9.52/2   
FLST,3,2,5,ORDE,2   
FITEM,3,54  
FITEM,3,57  
ARSYM,X,P51X, , , ,0,0   
CYL4,-171.45/2,0,9.52/2
VOFFST,54,-101.6, ,
VOFFST,57,-101.6, ,   
VOFFST,58,-101.6, ,  
VOFFST,59,-101.6, ,   
VOFFST,60,-101.6, ,   
VOFFST,61,-101.6, ,  
!*****combine volumes******
FLST,2,3,6,ORDE,2   
FITEM,2,1   
FITEM,2,-3  
VADD,P51X
!*****subtract volumes******
FLST,3,6,6,ORDE,2   
FITEM,3,4   
FITEM,3,-9  
VSBV,      10,P51X
!*****devide the areas to load*******
wpoff,,,-50.8
wprot,,,-30
FLST,2,2,5,ORDE,2   
FITEM,2,12  
FITEM,2,16  
ASBW,P51X
!****then generate the useful areas 51,53
wprot,,,-120
FLST,2,2,5,ORDE,2   
FITEM,2,21  
FITEM,2,25  
ASBW,P51X
!****then generate the useful areas 54,57
WPCSYS,-1,0
wprot,,,-60
FLST,2,2,5,ORDE,2   
FITEM,2,36  
FITEM,2,39  
ASBW,P51X
!****then generate the useful areas 58
wprot,,,120
ASBW,59
!****then generate the useful areas 39

!*******mesh*******
SMRT,6  
MSHAPE,1,3D
MSHKEY,0
!*  
CM,_Y,VOLU  
VSEL, , , ,       1
CM,_Y1,VOLU
CHKMSH,'VOLU'   
CMSEL,S,_Y  
!*  
VMESH,_Y1   
!*  
CMDELE,_Y   
CMDELE,_Y1  
CMDELE,_Y2  
!**********boundary conditions and load************
WPCSYS,-1,0
CSYS,1  
!******boundary conditions******
FLST,2,4,5,ORDE,4   
FITEM,2,51  
FITEM,2,53  
FITEM,2,-54
FITEM,2,57  
DA,P51X,ALL,
!******load******
*DEL,_FNCNAME   
*DEL,_FNCMTID   
*SET,_FNCNAME,'second'  
! /INPUT,second.func
*DIM,%_FNCNAME%,TABLE,6,13,1
!   
! Begin of equation: 99.696*(1-0.0003875*{Y}^2)*cos(1.5*{Z})
*SET,%_FNCNAME%(0,0,1), 0.0, -999   
*SET,%_FNCNAME%(2,0,1), 0.0
*SET,%_FNCNAME%(3,0,1), 0.0
*SET,%_FNCNAME%(4,0,1), 0.0
*SET,%_FNCNAME%(5,0,1), 0.0
*SET,%_FNCNAME%(6,0,1), 0.0
*SET,%_FNCNAME%(0,1,1), 1.0, -1, 0, 2, 0, 0, 3  
*SET,%_FNCNAME%(0,2,1), 0.0, -2, 0, 1, 3, 17, -1
*SET,%_FNCNAME%(0,3,1),   1, -1, 0, 0.0003875, 0, 0, -2
*SET,%_FNCNAME%(0,4,1), 0.0, -3, 0, 1, -1, 3, -2
*SET,%_FNCNAME%(0,5,1), 0.0, -1, 0, 1, 0, 0, -3
*SET,%_FNCNAME%(0,6,1), 0.0, -2, 0, 1, -1, 2, -3
*SET,%_FNCNAME%(0,7,1), 0.0, -1, 0, 99.696, 0, 0, -2
*SET,%_FNCNAME%(0,8,1), 0.0, -3, 0, 1, -1, 3, -2
*SET,%_FNCNAME%(0,9,1), 0.0, -1, 0, 1.5, 0, 0, 4
*SET,%_FNCNAME%(0,10,1), 0.0, -2, 0, 1, -1, 3, 4
*SET,%_FNCNAME%(0,11,1), 0.0, -1, 10, 1, -2, 0, 0   
*SET,%_FNCNAME%(0,12,1), 0.0, -2, 0, 1, -3, 3, -1   
*SET,%_FNCNAME%(0,13,1), 0.0, 99, 0, 1, -2, 0, 0
! End of equation: 99.696*(1-0.0003875*{Y}^2)*cos(1.5*{Z})  
!-->
FLST,2,2,5,ORDE,2   
FITEM,2,39  
FITEM,2,58  
/GO
!*  
!*  
SFA,P51X,1,PRES, %SECOND%
solve

hongfx1003

这是我做的钢筋混凝土框架例子，绝对原创，前天在okok上发过，但还没有最后彻底完善。三层框架模型是根据实验室试验资料和郝文化《ANSYS土木工程应用实例》中钢筋混凝土梁的例子花了几天做成的，由于本问题属于土木重要问题，希望斑竹不吝加分鼓励，单向加载相当于sap2000里的推覆（pushover分析）问题，循环加载就是拟静力问题，可以得到指挥曲线，评估结构的耗能能力。


     本命令流只是是单向位移荷载，虽能运行但参数设置不是很完善，期待高手们加以援手，解决这一难题。更为重要的是期待高手们另外完善命令流，让循环加载也可以实现拟静力问题（关键是难以收敛）。
试验资料及命令流祥见：
http://simwe.com/forum/thread-772657-1-1.html


由于还不完善，别人也帮看了，还达不到试验效果，不好意思贴在这里，等高手改好后再整理一下贴在这里。
贴在这里也希望引起高手们的注意！

cowry

计算水中梁的模态命令流
/PREP7
!梁横截面4个关键点
K,1,-25.5e-3,1.69e-3,,   
K,2,-2.55e-2,0,,  
K,3,2.55e-2,0,,   
K,4,2.55e-2,1.69e-3,,

!复制关键点
KGEN,2,4, , ,100e-3, , , ,0
KGEN,2,5, , , ,20e-3, , ,0
KGEN,2,6, , ,-100e-3, , , ,0
KGEN,2,7, , ,-51e-3, , , ,0
KGEN,2,8, , ,-100e-3, , , ,0
KGEN,2,9, , , ,-20e-3, , ,0
KGEN,2,10, , , ,-1.69e-3, , ,0
KGEN,2,11, , , ,-20e-3, , ,0
KGEN,2,12, , ,100e-3, , , ,0
KGEN,2,13, , ,51e-3, , , ,0
KGEN,2,14, , ,100e-3, , , ,0
KGEN,2,15, , , ,20e-3, , ,0

!创建面
A,1,2,3,4
A,3,4,5,16
A,4,5,6,7
A,1,4,7,8
A,1,8,9,10
A,1,10,11,2
A,2,11,12,13
A,2,13,14,3
A,3,14,15,16

!创建拉伸的线
KGEN,2,1, , , , ,5e-3, ,0
KGEN,2,17, , , , ,260e-3, ,0
KGEN,2,18, , , , ,150e-3, ,0
LSTR,      1,      17
LSTR,      17,      18
LSTR,      18,      19

!拉伸成体
ASEL,S,LOC,Z,0
VDRAG,ALL, , , , , ,      25

ASEL,S,LOC,Z,5e-3
VDRAG,ALL, , , , , ,      26

ASEL,S,LOC,Z,265e-3
VDRAG,ALL, , , , , ,      27

!merge
ALLSEL,ALL
NUMMRG,KP, , , ,LOW

!定义材料
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,1.69e5
MPDATA,PRXY,1,,0.3  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,DENS,1,,2.33e-9  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,DENS,2,,1e-9
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,SONC,2,,1.5e6

!定义单元类型
ET,1,SOLID45
ET,2,FLUID30
KEYOPT,2,2,1
ET,3,FLUID30

!赋材料和单元属性
VATT,       2, ,   2,       0
  
VSEL,S, , ,       1
VSEL,A, , ,       2
VSEL,A, , ,       3
VSEL,A, , ,       4
VSEL,A, , ,       5
VSEL,A, , ,       6
VSEL,A, , ,       7
VSEL,A, , ,       8
VSEL,A, , ,       9
VSEL,A, , ,       10
VATT,       1, ,   1,       0  

ALLSEL,ALL
!划分网格
LESIZE,13, , ,8,2, , , ,1
LESIZE,15, , ,8,0.5, , , ,1
LESIZE,17, , ,8,0.5, , , ,1
LESIZE,19, , ,8,0.5, , , ,1

LESIZE,2, , ,5, , , , ,1
LESIZE,4, , ,5, , , , ,1
LESIZE,11, , ,5, , , , ,1
LESIZE,21, , ,5, , , , ,1

LESIZE,5, , ,8,2, , , ,1
LESIZE,7, , ,8,0.5, , , ,1
LESIZE,9, , ,8,0.5, , , ,1
LESIZE,23, , ,8,2, , , ,1

LESIZE,1, , ,1, , , , ,1
LESIZE,3, , ,1, , , , ,1
LESIZE,6, , ,1, , , , ,1
LESIZE,16, , ,1, , , , ,1

LESIZE,8, , ,10,2.5, , , ,1
LESIZE,10, , ,10,0.4, , , ,1
LESIZE,12, , ,10,0.4, , , ,1
LESIZE,14, , ,10,0.4, , , ,1

LESIZE,18, , ,10,2.5, , , ,1
LESIZE,20, , ,10,0.4, , , ,1
LESIZE,22, , ,10,0.4, , , ,1
LESIZE,24, , ,10,0.4, , , ,1

LESIZE,42, , ,1, , , , ,1  
LESIZE,82, , ,25, , , , ,1

LESIZE,130, , ,8, 3, , , ,1
LESIZE,132, , ,8, 3, , , ,1
LESIZE,135, , ,8, 3, , , ,1
LESIZE,138, , ,8, 3, , , ,1
LESIZE,127, , ,8, 3, , , ,1
LESIZE,27, , ,8, 3, , , ,1
LESIZE,110, , ,8, 3, , , ,1
LESIZE,124, , ,8, 3, , , ,1
LESIZE,140, , ,8, 3, , , ,1
LESIZE,114, , ,8, 3, , , ,1
LESIZE,112, , ,8, 3, , , ,1
LESIZE,143, , ,8, 3, , , ,1
LESIZE,122, , ,8, 3, , , ,1
LESIZE,117, , ,8, 3, , , ,1
LESIZE,119, , ,8, 3, , , ,1
LESIZE,146, , ,8, 3, , , ,1
  

VSWEEP,3,3,22
VSWEEP,2,2,18
VSWEEP,4,4,25
VSWEEP,9,9,42
VSWEEP,1,1,14
VSWEEP,5,5,29
VSWEEP,8,8,39
VSWEEP,6,6,32
VSWEEP,7,7,36

VSWEEP,12,22,55
VSWEEP,11,18,51
VSWEEP,13,25,58
VSWEEP,18,42,75
VSWEEP,10,14,47
VSWEEP,14,29,62
VSWEEP,17,39,72
VSWEEP,15,32,65
VSWEEP,16,36,69

VSWEEP,21,55,88
VSWEEP,20,51,84
VSWEEP,22,58,91
VSWEEP,27,75,108
VSWEEP,19,47,80
VSWEEP,23,62,95
VSWEEP,26,72,105
VSWEEP,24,65,98
VSWEEP,25,69,102

!更改与梁接触水的单元属性
ESEL,S,MAT,,1
ALLSEL,BELOW,ELEM
ESLN,S
ESEL,R,MAT,,2
EMODIF,ALL,TYPE,3,

ALLSEL,ALL

!选择固体外表面施加位移约束
ASEL,S,LOC,Z,0
NSLA,S,1
D,ALL, , , , , ,ALL, , , , ,

ALLSEL,ALL
!选择流体外表面

ASEL,S,LOC,X,-125.1e-3
ASEL,A,LOC,X,125.1e-3
ASEL,A,LOC,Y,-20e-3
ASEL,A,LOC,Y,21.69e-3
ASEL,A,LOC,Z,415e-3
ASEL,U,LOC,Z,0,5e-3
NSLA,S,1
D,ALL,PRES,0

ALLSEL,ALL
!选择流固耦合面
VSEL,S, , ,      10
ALLSEL,BELOW,VOLU
ASEL,A,LOC,Z,5e-3
ASEL,U, , ,      14
ALLSEL,BELOW,AREA
NSEL,ALL, , ,
NSLA,S,1

ESLN,S  
ESEL,R,MAT,,2
SF,ALL,FSI

ALLSEL,ALL
FINISH  

!进入求解器
/SOL
ANTYPE,2
MODOPT,DAMP,20  
EQSLV,FRONT
MXPAND,20, , ,0
LUMPM,0
PSTRES,0
MODOPT,DAMP,20,0,0, ,OFF

solve
save

zhangbit

/prep7
!*
et,1,solid65
!*
r,1,3,,,,3,,
rmore,,,3,,,,
!*
uimp,1,ex,,,30e3,
uimp,1,nuxy,,,.2,
uimp,1,alpx,,,,
uimp,1,reft,,,,
uimp,1,mu,,,,
uimp,1,damp,,,,
uimp,1,dens,,,,
!*
uimp,3,ex,,,200e3,
uimp,3,nuxy,,,.27,
uimp,3,alpx,,,,
uimp,3,reft,,,,
uimp,3,mu,,,,
uimp,3,damp,,,,
uimp,3,dens,,,,
!*
tb,mkin,1,,,,
!*
tbmodif,1,2,0.0005
tbmodif,1,3,0.001
tbmodif,1,4,0.002
tbmodif,1,5,0.0025
tbmodif,1,6,0.0038
tbmodif,2,2,15
tbmodif,2,3,24
tbmodif,2,4,30
tbmodif,2,5,29
tbmodif,2,6,22
!*
tb,concr,1,,,,
!*
tbmodif,2,1,0.6
tbmodif,3,1,0.95
tbmodif,4,1,3
tbmodif,5,1,28
!*
tb,bkin,3,,,,
!*
tbmodif,2,1,210
tbmodif,3,1,2e3

zhangbit

finish
/clear
/title, fixed - fixed concrete beam example
/prep7
et,1,65
mp,ex,1,3e7       ! steel rebar (units are pounds, inches)
mp,ex,2,1e6,      ! concrete
mp,dens,2,.00025
tb,concr,2
tbdata,1,.3,.5,200,4000        ! shear coeffs, tensile and compress strength

r,1,1,.03,0,0     ! mat 1 (steel), 3 percent reinforcement in x dir
r,2,1,.01,0,0     ! mat 1 (steel), 1 percent
r,3,1,.04,0,0     ! mat 1 (steel), 4 percent

block,,100,,5,,5
block,,100,5,10,,5
block,,100,10,15,,5
!vovlap,all
NUMMRG,KP, , , ,LOW
numcmp,volu
esize,5
mat,2        ! concrete material
real,1       ! rebar
vmesh,1
real,2
vmesh,2
real,3
vmesh,3

nsel,s,loc,x
d,all,all
nsel,s,loc,x,100
d,all,all
nsel,all
fini

/solu
nsel,s,loc,y,15
sf,all,pres,100
nsel,all
OUTRES,ALL,ALL,
nsub,10
solve
fini

/post1
/DEVICE,VECTOR,1
set,last
plcrack
fini

zhafeiyang

我也来一个，球壳函数施加风荷载

finish
/clear,all
/filname,founction
/PREP7   
ET,1,SHELL93
R,1,44, , , , , ,   
MP,EX,1,2.094e5
MP,PRXY,1,0.262
MP,DENS,1,7.83e-6  

CSYS,1                         !激活柱坐标
k,,7850,90  
k,,7850,
k,,7850,-30
k,100,  
l,1,2   
l,2,3  

FLST,2,2,4,ORDE,2   
FITEM,2,1   
FITEM,2,-2  
FLST,8,2,3  
FITEM,8,1   
FITEM,8,100
AROTAT,P51X, , , , , ,P51X, ,360, ,   !线绕轴旋转成面

CSYS,0                            !激活直角坐标

AESIZE,ALL,1000,
AMESH,all

AREVERSE,all,0                     !翻转面和单元
     
*SET,OMEGA,2                       !设置参数omega＝2

!设置加载函数wind，并导入
*DEL,_FNCNAME   
*DEL,_FNCMTID   
*DEL,_FNC_C1
*DEL,_FNCCSYS   
*SET,_FNCNAME,'wind'
*DIM,_FNC_C1,,1
*SET,_FNC_C1(1),omega   
*SET,_FNCCSYS,2
! /INPUT,wind.func,,,1  
*DIM,%_FNCNAME%,TABLE,6,18,1,,,,%_FNCCSYS%  
!   
! Begin of equation: 0.441*abs(sin(w*{time}))*(0.5*(cos({z}))^2*cos({y})-(sin   
! ({z}))^2)
*SET,%_FNCNAME%(0,0,1), 0.0, -999   
*SET,%_FNCNAME%(2,0,1), 0.0
*SET,%_FNCNAME%(3,0,1), %_FNC_C1(1)%
*SET,%_FNCNAME%(4,0,1), 0.0
*SET,%_FNCNAME%(5,0,1), 0.0
*SET,%_FNCNAME%(6,0,1), 0.0
*SET,%_FNCNAME%(0,1,1), 1.0, -1, 0, 1, 17, 3, 1
*SET,%_FNCNAME%(0,2,1), 0.0, -1, 9, 1, -1, 0, 0
*SET,%_FNCNAME%(0,3,1),   0, -1, 15, 1, -1, 0, 0
*SET,%_FNCNAME%(0,4,1), 0.0, -2, 0, 0.441, 0, 0, -1
*SET,%_FNCNAME%(0,5,1), 0.0, -3, 0, 1, -2, 3, -1
*SET,%_FNCNAME%(0,6,1), 0.0, -1, 10, 1, 4, 0, 0
*SET,%_FNCNAME%(0,7,1), 0.0, -2, 0, 2, 0, 0, -1
*SET,%_FNCNAME%(0,8,1), 0.0, -4, 0, 1, -1, 17, -2   
*SET,%_FNCNAME%(0,9,1), 0.0, -1, 0, 0.5, 0, 0, -4   
*SET,%_FNCNAME%(0,10,1), 0.0, -2, 0, 1, -1, 3, -4   
*SET,%_FNCNAME%(0,11,1), 0.0, -1, 10, 1, 3, 0, 0
*SET,%_FNCNAME%(0,12,1), 0.0, -4, 0, 1, -2, 3, -1   
*SET,%_FNCNAME%(0,13,1), 0.0, -1, 9, 1, 4, 0, 0
*SET,%_FNCNAME%(0,14,1), 0.0, -2, 0, 2, 0, 0, -1
*SET,%_FNCNAME%(0,15,1), 0.0, -5, 0, 1, -1, 17, -2  
*SET,%_FNCNAME%(0,16,1), 0.0, -1, 0, 1, -4, 2, -5   
*SET,%_FNCNAME%(0,17,1), 0.0, -2, 0, 1, -3, 3, -1   
*SET,%_FNCNAME%(0,18,1), 0.0, 99, 0, 1, -2, 0, 0
! End of equation: 0.441*abs(sin(w*{time}))*(0.5*(cos({z}))^2*cos({y})-(sin
! ({z}))^2)
!-->
FINISH

/SOL
FLST,2,8,5,ORDE,2   
FITEM,2,1   
FITEM,2,-8   
SFA,P51X,1,PRES, %WIND%     !在面上施加函数载荷
  
/PSF,PRES,NORM,3,0,1

FLST,5,4,4,ORDE,4   
FITEM,5,10  
FITEM,5,12  
FITEM,5,14  
FITEM,5,16  
LSEL,S, , ,P51X
NSLL,S,1
D,all, , , , , ,UX,UY,UZ, , ,    !约束半球下边缘所有节点的x,y,z方向的位移

alls

ANTYPE,4                          !设置分析类型为瞬态分析
TRNOPT,FULL                       !采用full法求解
LUMPM,0   
kbc,0   
NSUBST,3*12,0,0                   !子步数为3×12   
OUTRES,ERASE
OUTRES,BASI,ALL                  
TIME,3*2*3.14/omega               !总加载时间9.42秒

solve
FINISH     

/POST26
FILE,'founction','rst','.'
csys  
NSEL,S,LOC,X,0  
NSEL,R,LOC,Z,0   
*GET,top_n,NODE,,NUM,MAX, , , ,

NSOL,2,1,U,X,ux_up               !定义变量2为1节点的x方向的位移，标签为ux_up
NSOL,3,1,U,Y,uy_up               !定义变量2为1节点的y方向的位移，标签为uy_up
PLVAR,2,3, , , , , , , , ,      

DERIV,5,2,1, ,vx_up, , ,1,       !定义变量5为变量2关于变量1 time 的微分，标签为vx_up  x方向速度
DERIV,6,3,1, ,vy_up, , ,1,       !定义变量6为变量3关于变量1 time 的微分，标签为vy_up  y方向速度
PLVAR,5,6, , , , , , , , ,

zhafeiyang

真是个好帖子，再来一个，

复合材料梁受弯分析

FINISH   
/CLEAR,all
  
/PREP7  
ET,1,SHELL99
KEYOPT,1,8,1    !选择K8关键选项为记录所有层的数据

*SET,_RC_SET,1,
R,1                               !创建实常数1
RMODIF,1,1,3,0,0,0,0,0            !设置层数为3

!RMODIF-实常数修改，1－实常数序号，1－所修改的数据在列表中的起始位置，3－层数

RMODIF,1,13,1,0,4,2,0,3.5,   
!13－修改数据的起始位置，1－第一层的材料标号，0－第一层的铺设角度，4－第一层的厚度
!2,第二层的材料编号，0－第二层的铺设角度，3.5－第二层的厚度

RMODIF,1,19,3,0,2,  

!材料1的属性
MP,EX,1,120e3  
MP,PRXY,1,0.32
UIMP,1,REFT,,,  
MP,ALPX,1,1.8e-6
MP,ALPY,1,,.2e-6

!材料2的属性
MP,EX,2,40e3   
MP,PRXY,2,0.26
UIMP,2,REFT,,,  
MP,ALPX,2,.6e-6
MP,ALPY,2,.1e-6

!材料3的属性
MP,EX,3,80e3   
MP,PRXY,3,0.28
UIMP,3,REFT,,,  
MP,ALPX,3,0.6e-6   
MP,ALPY,3,0.1e-6   

!建模
RECTNG,,200,,10,

!划分单元20×2  
FLST,5,2,4,ORDE,2   
FITEM,5,1   
FITEM,5,3   
CM,_Y,LINE  
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y   
LESIZE,_Y1, , ,20, , , , ,1

FLST,5,2,4,ORDE,2   
FITEM,5,2   
FITEM,5,4   
CM,_Y,LINE  
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y   
LESIZE,_Y1, , ,2, , , , ,1  

MSHAPE,0,2D
MSHKEY,1
CM,_Y,AREA  
ASEL, , , ,       1
CM,_Y1,AREA
CHKMSH,'AREA'   
CMSEL,S,_Y  
AMESH,_Y1   

CMDELE,_Y   
CMDELE,_Y1  
CMDELE,_Y2  

!对左端施加全约束
FLST,2,1,4,ORDE,1   
FITEM,2,4   
DL,P51X, ,ALL,

!对右端中点施加y方向的力矩
FLST,2,1,1,ORDE,1   
FITEM,2,44  
F,P51X,MY,10e3  

TUNIF,100,  !对所有节点施加均布温度100
FINISH

/SOL
SOLVE   
FINISH