[共建]＜ANSYS命令流实例库＞敬请您的加盟

21770980 · 发表于 2008-4-1 15:06:19

谢谢楼主无私奉献

s20070882 · 发表于 2008-4-10 21:42:22

感动的哇哇的，版主，这个贴太好了！

s20070882 · 发表于 2008-4-11 14:00:27

版主，这个可以用1/4对称结构做吗？

wan_chn · 发表于 2008-4-17 12:50:06

/image

zengpeng908 · 发表于 2008-4-21 16:31:16

怎么没有继续了，有没有碳纤维不加固的例子。并且是模拟粘贴破坏的例子。

lfs1981 · 发表于 2008-4-28 19:13:11

请问，有没有做隧道周边围岩渗流的例子啊，要能算出渗流作用在隧道支护上的渗透力。谢谢啦！

lwd899 · 发表于 2008-5-2 09:43:56

这是我做的一个实体单元后处理求内力的实际工程，发上来共同学习，共同探讨！绝对原创啊！
!单位：kN,m
finish
/clear,start
/filname,'zhugong'
/prep7
et,1,solid45
mp,ex,1,3.20e7                      !C30
mp,prxy,1,0.2
mp,dens,1,25
/view,1,1,1,1
WPSTYLE,,,,,,,,1
wprot,0,90,0
BLC5,0,0,14,9.6,1
*get,maxkp,kp,,num,max
wpoff,0,0,1
CSYS,4
k,maxkp+1,6.8,4.6
k,maxkp+2,-6.8,4.6
k,maxkp+3,-6.8,-4.6
k,maxkp+4,6.8,-4.6
k,maxkp+5,4.35,3.10,1.50
k,maxkp+6,-4.35,3.10,1.50
k,maxkp+7,-4.35,-3.10,1.50
k,maxkp+8,4.35,-3.10,1.50
v,maxkp+1,maxkp+2,maxkp+3,maxkp+4,maxkp+5,maxkp+6,maxkp+7,maxkp+8
wpoff,0,0,1.5
*get,maxkp,kp,,num,max
k,maxkp+1,4.25,3.0
k,maxkp+2,2.25,3.0
k,maxkp+3,2.25,1.5
k,maxkp+4,4.25,1.5

k,maxkp+5,4.25,3.0,13.0
k,maxkp+6,2.25,3.0,13.0
k,maxkp+7,2.25,1.5,13.0
k,maxkp+8,4.25,1.5,13.0
v,maxkp+1,maxkp+2,maxkp+3,maxkp+4,maxkp+5,maxkp+6,maxkp+7,maxkp+8
*get,maxvolu,volu,,num,max
vgen,2,maxvolu,,,-6.5,
vsel,s,loc,z,0,20
vgen,2,all,,,,-4.5
wpoff,0,0,13.0
BLC5,0,0,10,8,2.5
allsel
vadd,all
!
vsbw,all
wpoff,0,0,-13
vsbw,all
wpoff,0,0,-1.5
vsbw,all
wpoff,0,0,17
CSYS,0
asel,s,loc,y,0
/pnum,area,1
*get,areanum,area,,num,max
hptcreate,area,areanum,,coord,-5.4,0,3.65 !HPTCREATE, TYPE, ENTITY, NHP, LABEL, VAL1, VAL2, VAL3(nhp=57)
hptcreate,area,areanum,,coord,-5.4,0,-3.65
hptcreate,area,areanum,,coord,5.4,0,3.65
hptcreate,area,areanum,,coord,5.4,0,-3.65
hptcreate,area,areanum,,coord,0,0,0

hptcreate,area,areanum,,coord,-2.25,0,1.5
hptcreate,area,areanum,,coord,-2.25,0,0
hptcreate,area,areanum,,coord,-2.25,0,-1.5

hptcreate,area,areanum,,coord,2.25,0,1.5
hptcreate,area,areanum,,coord,2.25,0,0
hptcreate,area,areanum,,coord,2.25,0,-1.5
allsel
NUMCMP,ALL
vatt,1,,1,0
MSHAPE,1,3d
MSHKEY,0
VMESH,all
nsel,s,loc,x,-5.4                         !定义组以方便后面加载
nsel,r,loc,y,0
nsel,r,loc,z,3.65
cm,cm1,node
nsel,s,loc,x,-5.4
nsel,r,loc,y,0
nsel,r,loc,z,-3.65
cm,cm2,node
nsel,s,loc,x,5.4
nsel,r,loc,y,0
nsel,r,loc,z,-3.65
cm,cm3,node
nsel,s,loc,x,5.4
nsel,r,loc,y,0
nsel,r,loc,z,3.65
cm,cm4,node
nsel,s,loc,x,0
nsel,r,loc,y,0
nsel,r,loc,z,0
cm,cm00,node
nsel,s,loc,x,-2.25
nsel,r,loc,y,0
nsel,r,loc,z,1.5
cm,cm01,node
nsel,s,loc,x,-2.25
nsel,r,loc,y,0
nsel,r,loc,z,0
cm,cm02,node
nsel,s,loc,x,-2.25
nsel,r,loc,y,0
nsel,r,loc,z,-1.5
cm,cm03,node
nsel,s,loc,x,2.25
nsel,r,loc,y,0
nsel,r,loc,z,1.5
cm,cm04,node
nsel,s,loc,x,2.25
nsel,r,loc,y,0
nsel,r,loc,z,0
cm,cm05,node
nsel,s,loc,x,2.25
nsel,r,loc,y,0
nsel,r,loc,z,-1.5
cm,cm06,node
asel,s,loc,y,-18
da,all,all                      !DA,P51X,ALL,
allsel
save
finish
/solu
antype,static
time,1                         !自重
allsel
acel,,9.8,
lswrite,01
time,2                         !双重主力
fdele,all
acel,,,
f,cm1,fy,-9430
f,cm2,fy,-9079
f,cm3,fy,-9079
f,cm4,fy,-9430
f,cm00,fx,594.0
f,cm00,fy,-3281.0
allsel
lswrite,02
time,3                            !单孔重载（主力）
fdele,all
acel,,,
f,cm1,fy,-9874
f,cm2,fy,-6560
f,cm3,fy,-6560
f,cm4,fy,-9874
f,cm00,fx,422
f,cm00,fy,-2653
allsel
lswrite,03
time,4                            !特载作用
fdele,all
acel,,,
f,cm1,fy,-6560
f,cm2,fy,-6560
f,cm3,fy,-6560
f,cm4,fy,-6560
f,cm00,fy,-5307.1
f,cm01,fy,-320
f,cm02,fy,-320
f,cm03,fy,-320
f,cm04,fy,-320
f,cm05,fy,-320
f,cm06,fy,-320
allsel
lswrite,04
lssolve,1,4
finish
/post1
lcdef,1,1                               !自重
lcdef,2,2                               !双重主力
lcdef,3,3                               !单孔重载
lcdef,4,4                               !特载
lcfact,1,1.0
lcfact,2,1.0
lcfact,3,1.0
lcfact,4,1.0
lcase,1
lcoper,add,2
lcwrite,05
lcase,1
lcoper,add,3
lcwrite,06
lcase,1
lcoper,add,4
lcwrite,07
LCASE,5,                      !读取工况5
vsel,s,,,3
eslv,s
wpoff,2.25,3.00,-2.51
!asel,s,,,16
sucr,sufy1,cplane,3
sumap,s_x,s,x
sumap,s_y,s,y
sumap,s_z,s,z
sumap,s_xy,s,xy
sumap,s_yz,s,yz
sumap,s_xz,s,xz
supl,sufy1
supl,sufy1,s_
supl,sufy1,s_y
sueval,xforce,s_xy,intg
sueval,yforce,s_y,intg
sueval,zforce,s_yz,intg
sueval,a,da,sum
sueval,az,gcz,intg                      !gcz*da
az=az/a                                  !面重心至整体坐标轴x的距离
sueval,ax,gcx,intg                      !gcx*da
ax=ax/a                                  !面重心至整体坐标轴z的距离
sucalc,sygcz,s_y,mult,gcz
sueval,mz,sygcz,intg                      !绕整体坐标x轴的弯矩
sucalc,sygcx,s_y,mult,gcx
sueval,mx,sygcx,intg                      !绕整体坐标z轴的弯矩
mz0=mz-yforce*az
mx0=mx-yforce*ax
*stat

heguojun66 · 发表于 2008-7-9 10:46:58

我是新手，对命令流不是很熟悉，不过我会通过向大家的学习，逐渐提高，希望尽快在此提供命令流库，我的小小建议是：能否想法把图片放在文首，而非文末（办法肯定是有的）。因为直到把命令流看完，才看到图片及题目要求，感觉不是很舒服！呵呵，个人拙见！

dio9527 · 发表于 2008-7-21 11:12:45

太好了!顶顶顶!!!

wzzjkf · 发表于 2008-7-21 11:38:40

一个模态分析的实例！这是自己亲自动手做的一个模态分析的例题，和理论解吻合。
附件是这个例题的一些参数，横梁是完全刚性的，只有横向运动。
理论解的圆频率是w1=14.522rad/s,w2=31.048rad/s,w3=46.100rad/s。
模态求解的频率是：f1=2.3112Hz,f2=4.9414Hz,f3=7.3370Hz。
模态分析的命令流如下:

/BATCH
KEYW,PR_STRUC,1
/PREP7
ET,1,BEAM3
ET,2,MASS21
R,1,1,1/12,1, , , ,
R,2,1, , , , , ,
R,3,1.5,0,0,0,0,0,
R,4,2.0, , , , , ,
mp,ex,1,6e5
mp,prxy,1,0
mp,ex,2,12E5
mp,prxy,2,0
mp,ex,3,18e5
mp,prxy,3,0
k,1,0,0
k,2,0,10
k,3,0,20
k,4,0,30
l,1,2
l,2,3
l,3,4
type,1
mat,3
REAL,1
lesize,1,,,10
lmesh,1
type,1
mat,2
REAL,1
lesize,2,,,10
lmesh,2
type,1
mat,1
REAL,1
lesize,3,,,10
lmesh,3
/PNUM,NODE,1
TYPE, 2
MAT,    1
REAL,    2
ESYS,    0
E,    22
TYPE, 2
MAT,    1
REAL,    3
ESYS,    0
E,    12
TYPE, 2
MAT,    1
REAL,    4
ESYS,    0
E,    2
elist
FINISH
/OUTPUT,cpb100,out,,
/SOL
ANTYPE,2
MSAVE,0
MODOPT,LANB,10
MXPAND,10, , ,0
PSTRES,0
MODOPT,LANB,10,0,1000, ,OFF
!NSEL,S,NODE,,2,22,10
!D,ALL,UY,0,,,,ROTZ
!NSEL,U,NODE,,1
!D,ALL,ALL,0
D,1,UX,0,,,,UY,ROTZ
D,2,UY,0,,22,10,ROTZ
dlist
/STATUS,SOLU
SOLVE
FINISH
/POST1
SET,LIST

gangguanfenxi · 发表于 2008-7-21 21:09:50

怎么都是ansys自己带的例子？

httcm · 发表于 2008-7-21 21:15:10

看到大家如此踊跃，我这个仿真论坛的老兵也深受感动，自己平时从论坛受益匪浅，饮水思源，也是应该为论坛作一点贡献了，刚好最近完成了一个简单的热分析工程实例，拿出来与大家分享，希望对需要的兄弟姐妹们有所帮助。
该问题可当作二维平面问题来处理，因此采用PLANE55单元。边界条件为涂层外表面施加热源温度载荷，基体背面以及涂层和基体的上下表面施加对流条件，初始温度为零度，环境温度为零度。
稳态分析：
*SET,thickness_tc,0.0006    ! 0.6mm to 1.5mm by 0.1mm
*SET,thickness,0.01
*SET,total_height,0.1
*SET,element_number,10
*SET,ratio,2

*SET,source_temp,1500
*SET,air_temp,0
*SET,air_conv,500
*SET,steel_k,70
*SET,tc_k,2

*DIM,VALUE_C1,,10,4

*DO,I,1,10,1
/PREP7
aclear,all
adele,all,,,1
NUMCMP,all

ET,1,PLANE55
MP,KXX,1,tc_k

ET,2,PLANE55
MP,KXX,2,steel_k

BLC4,0,0,thickness_tc+(i-1)*0.0001,total_height
BLC4,thickness_tc+(i-1)*0.0001,0,thickness,total_height
AGLUE,all
NUMCMP,ALL

AATT,1,,1
AESIZE,1,thickness_tc+(i-1)*0.0001,
MSHAPE,0,2D
MSHKEY,1
AMESH,1

AATT,2,,2
LESIZE,6,,,element_number,ratio,,,,0
LESIZE,7,,,element_number,ratio,,,,0
MSHAPE,0,2D
MSHKEY,1
AMESH,2
FINISH

/SOLu
ANTYPE,static
NSEL,S,LOC,X,0
D,all,TEMP,source_temp
allsel
NSEL,S,LOC,X,thickness+thickness_tc+(i-1)*0.0001
NSEL,a,LOC,y,0
NSEL,a,LOC,y,total_height
SF,ALL,CONV,air_conv,air_temp
allsel
OUTPR,ALL,ALL
OUTres,ALL,ALL
SOLVE
FINISH

/POST1
LFT_NODE = NODE (0,total_height/2,0)
mid_NODE=NODE(thickness_tc+(i-1)*0.0001,total_height/2,0)
RT_NODE=NODE(thickness+thickness_tc+(i-1)*0.0001,total_height/2,0)
*GET,LFT_TEMP,NODE,LFT_NODE,TEMP
*GET,mid_TEMP,NODE,mid_NODE,TEMP
*GET,RT_TEMP,NODE,RT_NODE,TEMP
*VFILL,VALUE_C1(i,1),DATA,thickness_tc+(i-1)*0.0001
*VFILL,VALUE_C1(i,2),DATA,LFT_TEMP
*VFILL,VALUE_C1(i,3),DATA,mid_TEMP
*VFILL,VALUE_C1(i,4),DATA,RT_TEMP
finish
*enddo

/OUT,tc_thickness_steady,vrt
/COM,node temperature vary with parameter tc_thickness
/COM,-----------------------------------------------------------
/COM, | tc_thickness | LFT_TEMP | mid_TEMP | rt_TEMP |
*VWRITE,VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3),VALUE_C1(1,4)
(F12.4,F12.2,F12.2,f12.2)
/COM,-----------------------------------------------------------
/OUT
*LIST,tc_thickness_steady,vrt

    动态分析：
*SET,thickness_tc,0.0008
*SET,thickness,0.01
*SET,total_height,0.1
*SET,element_number,10
*SET,ratio,2

*SET,source_temp,1300
*SET,initial_temp,0
*SET,air_temp,0
*SET,air_conv,500
*SET,steel_k,70
*SET,steel_c,448
*SET,steel_ro,7800
*SET,tc_k,3.0
*SET,tc_c,467
*SET,tc_ro,5730

*SET,computer_time_1,0.1
*SET,number_set_1,100
*SET,computer_time_2,300.1
*SET,number_set_2,1500

/PREP7
ET,1,PLANE55
MP,KXX,1,tc_k
MP,DENS,1,tc_ro
MP,C,1,tc_c

ET,2,PLANE55
MP,KXX,2,steel_k
MP,DENS,2,steel_ro
MP,C,2,steel_c

BLC4,0,0,thickness_tc,total_height
BLC4,thickness_tc,0,thickness,total_height
AGLUE,all
NUMCMP,ALL

AATT,1,,1
AESIZE,1,thickness_tc,
MSHAPE,0,2D
MSHKEY,1
AMESH,1

AATT,2,,2
LESIZE,6,,,element_number,ratio,,,,0
LESIZE,7,,,element_number,ratio,,,,0
MSHAPE,0,2D
MSHKEY,1
AMESH,2
FINISH

/SOLu
ANTYPE,trans
TIME,computer_time_1
NSUBST,number_set_1
AUTOTS,ON                ! USE AUTOMATIC TIME STEPPING
BFUNIF,TEMP,initial_temp
KBC,1
NSEL,S,LOC,X,0
D,all,TEMP,source_temp
allsel
NSEL,S,LOC,X,thickness+thickness_tc
NSEL,a,LOC,y,0
NSEL,a,LOC,y,total_height
SF,ALL,CONV,air_conv,air_temp
allsel
OUTPR,ALL,ALL
OUTres,ALL,ALL
SOLVE
TIME,computer_time_2
NSUBST,number_set_2
solve
FINISH

/POST26
/PLOPTS,INFO,On
/AXLAB,X,TIME,(sec)
/AXLAB,Y,TEMPERTURE
/GTHK,AXIS,3
/GTHK,CURVE,3
/REPLOT
/XRANGE,0,computer_time_2
/YRANGE,0,source_temp
LFT_NODE=NODE(0,total_height/2,0)
middle_NODE=NODE(thickness_tc,total_height/2,0)
RT_NODE=NODE(thickness+thickness_tc,total_height/2,0)
NSOL,2,lft_node,TEMP
NSOL,3,middle_node,TEMP
NSOL,4,rt_node,TEMP
PLVAR,2,3,4
LINES,2000

PrVAR,2,3,4

[ 本帖最后由 httcm 于 2008-7-21 21:28 编辑 ]

wzzjkf · 发表于 2008-7-28 09:49:40

这里面的实例不错，很有帮助

pengpigeon · 发表于 2009-4-29 18:08:23

请问谁有拱坝建模方面的例子啊？谢谢

wcm850326 · 发表于 2009-7-2 19:07:24

感觉这个帖子越来越垃圾了

gxg198009 · 发表于 2009-7-16 17:21:21

初学者，继续学习！

laiyi0921 · 发表于 2009-9-4 10:40:40

谢谢楼主！！！！！！！！！！！！！！！！

tan92 · 发表于 2009-9-7 18:22:00

!V级深埋衬砌
!隧道埋深约100m,拱顶垂直土压102.5kN/m
!拱顶水头1.5MPa
/filname,Water090601add
/units,si!申明为国际标准单位
/com,structural
/prep7
!总体参数
*AFUN,DEG  !改变角度的单位为度
!二衬承受围岩压力比例
hzbl=0.5          !二衬承受围岩压力比例按50%考虑(深埋)
Bkd=9.57       !隧道宽度(不包括初支)
Hgd=8.0          !隧道高度(不包括初支)
cqtm=33.5e9       !衬砌弹性模量C35砼
cqbsb=0.2       !衬砌泊松比
cqmd=2500    !衬砌密度(kg/m3)钢筋砼

wytxkl=150e6    !围岩弹性抗力系数MPa/m
wybsb=0.25    !围岩泊松比
!wyzd=20e3       !围岩重度N/m3
wymd=1.0    !围岩密度(kg/m3)
!szd=10e3          !地下水重度N/m3
!gdst=150          !拱顶水头3.0m
!faic=45             !Ⅴ级围岩计算摩擦角
!theta=0.5*faic !顶板土柱两侧摩擦角
!tanp=TAN(faic)+SQRT((TAN(faic)**2+1)*TAN(faic)/(TAN(faic)-TAN(theta))) !偏压隧道内侧TANβ值
!cylxs=(tanp-TAN(faic))/(tanp*(1+tanp*(TAN(faic)-TAN(theta))+TAN(faic)*TAN(theta)))!浅埋隧道侧压力系数λ
!cylxs1=0.50    !地质上给出的
!分项荷载计算
qq=108e3       !拱部隧道竖直荷载
eq=54e3       !隧道水平荷载最小值(已考虑承载比例及水压)
!单元类型,材料,实常数定义
ET,1,BEAM3 !  第1类单元为梁单元,模拟衬砌
MP,EX,1, cqtm !第1类材料弹性模量
MP,NUXY,1,cqbsb  !第1类材料泊松比
MP,DENS,1, cqmd !第1类材料密度

ET,2,LINK10 ! 第2类单元为弹簧连杆,模拟弹性抗力
KEYOPT,2,2,0 !2类单元不具有刚度的参数设定
KEYOPT,2,3,1 !2类单元为单压的参数设定
MP,EX,2,0.50*wytxkl  !第2类材料弹性模量(侧向)
MP,NUXY,2,wybsb !第2类材料泊松比
MP,DENS,2, wymd !第2类材料密度
R,200,1,0

ET,4,SURF153 !4号单元为表面荷载单元,加载用
MP,EX,4,0 !第4种材料弹性模量

!=================建模部分开始=================
*Dim,houdu,,200!定义一个10行的一维数组
!赋值给该衬砌厚度数组
Houdu(1) = 1.0
Houdu(2) = 1.0
Houdu(3) = 1.0
Houdu(4) = 1.0
Houdu(5) = 1.0
Houdu(6) = 1.0
Houdu(7) = 1.0
Houdu(8) = 1.0
Houdu(9) = 1.0
Houdu(10) = 1.0
Houdu(11) = 1.0
Houdu(12) = 1.0
Houdu(13) = 1.0
Houdu(14) = 1.0
Houdu(15) = 1.0
Houdu(16) = 1.0
Houdu(17) = 1.0
Houdu(18) = 1.0
Houdu(19) = 1.0
Houdu(20) = 1.0
Houdu(21) = 1.0
Houdu(22) = 1.0
Houdu(23) = 1.0
Houdu(24) = 1.0
Houdu(25) = 1.0
Houdu(26) = 1.0
Houdu(27) = 1.0
Houdu(28) = 1.0
Houdu(29) = 1.0
Houdu(30) = 1.0
Houdu(31) = 1.0
Houdu(32) = 1.0
Houdu(33) = 1.0
Houdu(34) = 1.0
Houdu(35) = 1.0
Houdu(36) = 1.0
Houdu(37) = 1.0
Houdu(38) = 1.0
Houdu(39) = 1.0
Houdu(40) = 1.0
Houdu(41) = 1.0
Houdu(42) = 1.0
Houdu(43) = 1.0
Houdu(44) = 1.0
Houdu(45) = 1.0
Houdu(46) = 1.0
Houdu(47) = 1.0
Houdu(48) = 1.0
Houdu(49) = 1.0
Houdu(50) = 1.0
Houdu(51) = 1.0
Houdu(52) = 1.0
Houdu(53) = 1.0
Houdu(54) = 1.0
Houdu(55) = 1.0
Houdu(56) = 1.0
Houdu(57) = 1.0
Houdu(58) = 1.0
Houdu(59) = 1.0
Houdu(60) = 1.0
Houdu(61) = 1.0
Houdu(62) = 1.0
Houdu(63) = 1.0
Houdu(64) = 1.0
Houdu(65) = 1.0
Houdu(66) = 1.0
Houdu(67) = 1.0
Houdu(68) = 1.0
Houdu(69) = 1.0
Houdu(70) = 1.0
Houdu(71) = 1.0
Houdu(72) = 1.0
Houdu(73) = 1.0
Houdu(74) = 1.0
Houdu(75) = 1.0
Houdu(76) = 1.0
Houdu(77) = 1.0
Houdu(78) = 1.0
Houdu(79) = 1.0
Houdu(80) = 1.0
!根据厚度定义实常数
*DO,i,1,80,1
r,i,houdu(i),houdu(i)**3/12,houdu(i)!定义梁单元实常数
*ENDDO

N , 1 , 0 , 0 , 0
N , 2 , -0.487 , 0.017 , 0
N , 3 , -0.972 , 0.066 , 0
N , 4 , -1.447 , 0.148 , 0
N , 5 , -1.926 , 0.264 , 0
N , 6 , -2.391 , 0.411 , 0
N , 7 , -2.844 , 0.59 , 0
N , 8 , -3.266 , 0.832 , 0
N , 9 , -3.625 , 1.161 , 0
N , 10 , -3.904 , 1.559 , 0
N , 11 , -4.099 , 2.006 , 0
N , 12 , -4.254 , 2.468 , 0
N , 13 , -4.378 , 2.939 , 0
N , 14 , -4.471 , 3.418 , 0
N , 15 , -4.53 , 3.902 , 0
N , 16 , -4.557 , 4.388 , 0
N , 17 , -4.552 , 4.876 , 0
N , 18 , -4.513 , 5.362 , 0
N , 19 , -4.442 , 5.844 , 0
N , 20 , -4.338 , 6.32 , 0
N , 21 , -4.203 , 6.788 , 0
N , 22 , -4.037 , 7.247 , 0
N , 23 , -3.84 , 7.692 , 0
N , 24 , -3.613 , 8.124 , 0
N , 25 , -3.35 , 8.534 , 0
N , 26 , -3.04 , 8.91 , 0
N , 27 , -2.688 , 9.247 , 0
N , 28 , -2.3 , 9.541 , 0
N , 29 , -1.879 , 9.787 , 0
N , 30 , -1.432 , 9.982 , 0
N , 31 , -0.966 , 10.123 , 0
N , 32 , -0.486 , 10.209 , 0
N , 33 , 0 , 10.237 , 0
N , 34 , 0.486 , 10.209 , 0
N , 35 , 0.966 , 10.123 , 0
N , 36 , 1.432 , 9.982 , 0
N , 37 , 1.879 , 9.787 , 0
N , 38 , 2.3 , 9.541 , 0
N , 39 , 2.688 , 9.247 , 0
N , 40 , 3.04 , 8.91 , 0
N , 41 , 3.35 , 8.534 , 0
N , 42 , 3.613 , 8.124 , 0
N , 43 , 3.84 , 7.692 , 0
N , 44 , 4.037 , 7.247 , 0
N , 45 , 4.203 , 6.788 , 0
N , 46 , 4.338 , 6.32 , 0
N , 47 , 4.442 , 5.844 , 0
N , 48 , 4.513 , 5.362 , 0
N , 49 , 4.552 , 4.876 , 0
N , 50 , 4.557 , 4.388 , 0
N , 51 , 4.53 , 3.902 , 0
N , 52 , 4.471 , 3.418 , 0
N , 53 , 4.378 , 2.939 , 0
N , 54 , 4.254 , 2.468 , 0
N , 55 , 4.099 , 2.006 , 0
N , 56 , 3.904 , 1.559 , 0
N , 57 , 3.625 , 1.161 , 0
N , 58 , 3.266 , 0.832 , 0
N , 59 , 2.834 , 0.585 , 0
N , 60 , 2.391 , 0.411 , 0
N , 61 , 1.926 , 0.264 , 0
N , 62 , 1.447 , 0.148 , 0
N , 63 , 0.972 , 0.066 , 0
N , 64 , 0.487 , 0.017 , 0
N , 65 , 0 , -1 , 0
N , 66 , -0.555 , -0.981 , 0
N , 67 , -1.108 , -0.924 , 0
N , 68 , -1.649 , -0.832 , 0
N , 69 , -2.195 , -0.699 , 0
N , 70 , -2.725 , -0.531 , 0
N , 71 , -3.23 , -0.333 , 0
N , 72 , -3.857 , 0.025 , 0
N , 73 , -4.377 , 0.501 , 0
N , 74 , -4.781 , 1.079 , 0
N , 75 , -5.035 , 1.655 , 0
N , 76 , -5.212 , 2.181 , 0
N , 77 , -5.353 , 2.717 , 0
N , 78 , -5.458 , 3.262 , 0
N , 79 , -5.526 , 3.813 , 0
N , 80 , -5.557 , 4.366 , 0
N , 81 , -5.551 , 4.921 , 0
N , 82 , -5.507 , 5.469 , 0
N , 83 , -5.426 , 6.023 , 0
N , 84 , -5.308 , 6.565 , 0
N , 85 , -5.154 , 7.098 , 0
N , 86 , -4.964 , 7.62 , 0
N , 87 , -4.74 , 8.127 , 0
N , 88 , -4.482 , 8.618 , 0
N , 89 , -4.158 , 9.123 , 0
N , 90 , -3.773 , 9.59 , 0
N , 91 , -3.337 , 10.009 , 0
N , 92 , -2.854 , 10.373 , 0
N , 93 , -2.332 , 10.678 , 0
N , 94 , -1.778 , 10.92 , 0
N , 95 , -1.199 , 11.096 , 0
N , 96 , -0.604 , 11.202 , 0
N , 97 , 0 , 11.202 , 0
N , 98 , 0.604 , 11.202 , 0
N , 99 , 1.199 , 11.096 , 0
N , 100 , 1.778 , 10.92 , 0
N , 101 , 2.332 , 10.678 , 0
N , 102 , 2.854 , 10.373 , 0
N , 103 , 3.337 , 10.009 , 0
N , 104 , 3.773 , 9.59 , 0
N , 105 , 4.158 , 9.123 , 0
N , 106 , 4.482 , 8.618 , 0
N , 107 , 4.74 , 8.127 , 0
N , 108 , 4.964 , 7.62 , 0
N , 109 , 5.154 , 7.098 , 0
N , 110 , 5.308 , 6.565 , 0
N , 111 , 5.426 , 6.023 , 0
N , 112 , 5.507 , 5.469 , 0
N , 113 , 5.551 , 4.921 , 0
N , 114 , 5.557 , 4.366 , 0
N , 115 , 5.526 , 3.813 , 0
N , 116 , 5.458 , 3.262 , 0
N , 117 , 5.353 , 2.717 , 0
N , 118 , 5.212 , 2.181 , 0
N , 119 , 5.035 , 1.655 , 0
N , 120 , 4.781 , 1.079 , 0
N , 121 , 4.377 , 0.501 , 0
N , 122 , 3.857 , 0.025 , 0
N , 123 , 3.23 , -0.333 , 0
N , 124 , 2.725 , -0.531 , 0
N , 125 , 2.195 , -0.699 , 0
N , 126 , 1.649 , -0.832 , 0
N , 127 , 1.108 , -0.924 , 0
N , 128 , 0.555 , -0.981 , 0
!**********************建立衬砌梁单元1*********
*DO,i,1,63,1
Type,1
Real,i
Mat,1
E,i,i+1
*ENDDO
Type,1
Real,64
Mat,1
E,64,1
!**********************建立围岩单元2*********
!创建围岩单元
*DO,i,1,64,1
Type,2
Real,200
Mat,2
E,i,i+64
*ENDDO
!创建单元组
esel,s,type,,1
cm,e-cq,elem !创建衬砌单元组
esel,s,type,,2
cm,e-wy,elem !创建连杆单元组
SAVE
Nummrg,all
Cmsel,all
!创建荷载单元组
TYPE, 4
MAT, 4
Real,4
ESYS, 0
*DO,I,1,32
E,I,I+1
*ENDDO
ESEL,S,TYPE,,4
eplot
cm,e-hz-z,elem !左部单元
TYPE, 4
MAT, 4
Real,4
ESYS, 0
*DO,I,33,63
E,I,I+1
*ENDDO
E,64,1
ESEL,S,TYPE,,4
eplot
cmsel,u,e-hz-z
cm,e-hz-y,elem !右部单元

esel,s,elem,,144,177,1
cm,e-hz-s,elem !上部单元
!ESEL,S,TYPE,,4
!eplot

esel,s,type,,4,
cm,e-hz-w,elem
ESEL,S,TYPE,,4
eplot
!求衬砌单元节点X、Y的极值
cmsel,s,e-cq
ALLSEL,BELOW,ELEM
cm,n-cq,node
! *get,xmax,node,,mxloc,x
! *get,xmin,node,,mnloc,x
! *get,ymax,node,,mxloc,y
! *get,ymin,node,,mnloc,y
!将连杆外侧节点设为固定端
NSEL,ALL
cmsel,u,n-cq
d,all,all
allsel
eplot
finish
!save,tunnel_model,db
!=================荷载计算部分=================
/solu
SFCUM,PRES,ADD,1,1, !以累加方式加载
/PSF,PRES,NORM,2,0,1 !以箭头显示荷载形式
!加拱部围岩垂直荷载
cmsel,s,e-hz-s
SFE,all,4,PRES,,qq,0,-1 !最后两个参数代表坐标方向，即坐标原点与该点的连线为加载方向

cmsel,s,e-hz-z
sfe,all,4,pres,,eq,1,0

cmsel,s,e-hz-y
sfe,all,4,pres,,eq,-1,0

!/solu
SFGRAD,PRES,0,Y,160,-10000 !sfgrad命令只是定义梯度和起始点
cmsel,s,e-hz-w
SFE,e-hz-w,1,PRES,0, !sf命令来定义起始值,即Y=160处荷载为0，Y=0处荷载为160*10000
!ALLS
!/PSF,PRES,NORM,2,0,1
ALLS
ACEL,0,1,0,
allsel
eplot
!save
ANTYPE,0
NLGEOM,1
NSUBST,50,0,0
TIME,1
/STATUS,SOLU
SOLVE
FINISH
!后处理
/POST1
!创建结果文件
ETAB,STR,SMISC,1
cmsel,s,e-cq
ETAB,MI,SMISC,6
ETAB,MJ,SMISC,12
ETAB,KI,SMISC,10  !为提取结果设置
ETAB,NI,SMISC,1
ETAB,NJ,SMISC,7
ETAB,PI,SMISC,20  !为提取结果设置
ETAB,QI,SMISC,2
ETAB,QJ,SMISC,8
ETAB,SMXI,NMISC,1  !SMaxI
ETAB,SMXJ,NMISC,3  !SMaxJ
ETAB,SMII,NMISC,2 !SMinI
ETAB,SMIJ,NMISC,4 !SMinJ
!显示结果图形并保存图形
plls,MI,MJ,-1 !显示并保存弯距图
/ui,copy,save,jpeg,full,color,reverse,portrait,yes,100 !保存弯矩图
plls,NI,NJ,-1 !显示并保存轴力图
/ui,copy,save,jpeg,full,color,reverse,portrait,yes,100
plls,QI,QJ,-1 !显示并保存剪力图（可求和值）
/ui,copy,save,jpeg,full,color,reverse,portrait,yes,100
plls,SMXI,SMXJ,1 !显示并保存剪力图（不可求和值）
/ui,copy,save,jpeg,full,color,reverse,portrait,yes,100
plls,SMII,SMIJ,-1 !显示并保存剪力图
/ui,copy,save,jpeg,full,color,reverse,portrait,yes,100
PLNSOL, U,SUM, 0,1.0
/ui,copy,save,jpeg,full,color,reverse,portrait,yes,100
!输入结构内力至文件nl-gk2.out
/output,nl-gk2,out
PRETAB,NI,NJ,MI,MJ,QI,QJ,IK,JK
/output

[img][img][/img][/img]

cj2006n · 发表于 2009-9-9 10:48:16

各位应该把模型图片提供出来参考一下，比较直观！

wywamin09 · 发表于 2010-3-25 14:45:06

好好学习了

账号		自动登录	找回密码
密码			注册

[共建]＜ANSYS命令流实例库＞敬请您的加盟

回复 6# 的帖子

实体单元后处理求内力

小小建议！

顶

一个模态分析的实例！

本帖子中包含更多资源

热分析实例（原创）

本帖子中包含更多资源